dev-util/rr: add 5.7.0

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 82 insertions, 0 deletions

diff --git a/dev-util/rr/Manifest b/dev-util/rr/Manifest
index a42888a658a6..5908e870ed7e 100644
--- a/dev-util/rr/Manifest
+++ b/dev-util/rr/Manifest
@@ -1 +1,2 @@
 DIST mozilla-rr-5.6.0.tar.gz 1579320 BLAKE2B 14ea99c4486c72db844b5cad3f0c300d7bf5d49449e7080ed0484f89022be6d9b7f81b3808b65f59028a5256a6b3f6508729d5b7e8f3f45d8353ceb7ae2a577a SHA512 4b5ef65b6c6a4b62fc72949b4541aaf608f6133ea0b6c2e529a8eed725e6a0b5186f20ed60b210821e6929410e1f21723840eacfdc85bf12c87703e7ebf5f9a7
+DIST mozilla-rr-5.7.0.tar.gz 1688069 BLAKE2B 613196a441b8c384765403838d4c89248eeb85af203b596ff01610fe65c62650cbeb7f8bde4c97ac4bb65f2bdcf7caa605ca1b6cb2f8f36b0355d816ed39a4f1 SHA512 e0e45f47a5f1de9e0e3f982e9eb5565699189ed23c52de03bf68b8215e7b8ac267619c04495c19e75a55aa8e0face08b9bb6c7f325650384c10a719c17ecf576
diff --git a/dev-util/rr/rr-5.7.0.ebuild b/dev-util/rr/rr-5.7.0.ebuild
new file mode 100644
index 000000000000..4cf7e880d27f
--- /dev/null
+++ b/dev-util/rr/rr-5.7.0.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+CMAKE_BUILD_TYPE=Release
+
+inherit cmake linux-info python-single-r1
+
+DESCRIPTION="Record and Replay Framework"
+HOMEPAGE="https://rr-project.org/"
+SRC_URI="https://github.com/rr-debugger/${PN}/archive/${PV}.tar.gz -> mozilla-${P}.tar.gz"
+
+LICENSE="MIT BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="multilib test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+	${PYTHON_DEPS}
+	dev-libs/capnproto:=
+	sys-libs/zlib:=
+"
+RDEPEND="
+	${DEPEND}
+	sys-devel/gdb[xml]
+"
+# Add all the deps needed only at build/test time.
+DEPEND+="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/pexpect[${PYTHON_USEDEP}]
+		')
+		sys-devel/gdb[xml]
+	)"
+
+QA_FLAGS_IGNORED="
+	usr/lib.*/rr/librrpage.so
+	usr/lib.*/rr/librrpage_32.so
+"
+
+RESTRICT="test" # toolchain and kernel version dependent
+
+pkg_setup() {
+	if use kernel_linux; then
+		CONFIG_CHECK="SECCOMP"
+		linux-info_pkg_setup
+	fi
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	sed -i 's:-Werror::' CMakeLists.txt || die #609192
+}
+
+src_test() {
+	if has usersandbox ${FEATURES} ; then
+		ewarn "Test suite fails under FEATURES=usersandbox (bug #632394). Skipping."
+		return 0
+	fi
+
+	cmake_src_test
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTS=$(usex test)
+		-Ddisable32bit=$(usex !multilib) #636786
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	python_fix_shebang "${ED}"/usr/bin/rr-collect-symbols.py
+}