dev-util/gtk-doc: Version bump to 1.33.2

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 111 insertions, 0 deletions

diff --git a/dev-util/gtk-doc/Manifest b/dev-util/gtk-doc/Manifest
index 380dd096304f..064d9a83b6f9 100644
--- a/dev-util/gtk-doc/Manifest
+++ b/dev-util/gtk-doc/Manifest
@@ -1 +1,2 @@
 DIST gtk-doc-1.33.1.tar.xz 768896 BLAKE2B 0d6cc32611618669aac4045942497a404f4d3ed703341cce56efefba439eb8595877297b76085c6a57d3d76710257153040b8f895d6dd6381502e852e6b82e93 SHA512 18620f0164382849980938103a9243abc35ea5a2628258f00e096e16a698b598d0c7fe80a1739fc689217c59a648c728a014bc672a92346c65768ebf89675b90
+DIST gtk-doc-1.33.2.tar.xz 507852 BLAKE2B dea3030060ecec89433fe3783dfacc2f58373780c49560a48ab1a32bedfe888692183de8396c92414255e4c8f537358cbc373fd307638ab8e7dbfd9ae44de58f SHA512 f50f68ab6b4bc59f55e84b49c1481f05700171cbf79eca9ba8f3a142a30a4ba88fe096983ebb8d117a9ef8bcea40934674096683d956f5c54cae457d31f651ab
diff --git a/dev-util/gtk-doc/gtk-doc-1.33.2.ebuild b/dev-util/gtk-doc/gtk-doc-1.33.2.ebuild
new file mode 100644
index 000000000000..df6e92cd3086
--- /dev/null
+++ b/dev-util/gtk-doc/gtk-doc-1.33.2.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit elisp-common gnome.org meson python-single-r1 readme.gentoo-r1
+
+DESCRIPTION="GTK+ Documentation Generator"
+HOMEPAGE="https://wiki.gnome.org/DocumentationProject/GtkDoc"
+
+LICENSE="GPL-2 FDL-1.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~sparc-solaris ~x64-solaris"
+
+IUSE="emacs test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/glib-2.38:2
+	dev-libs/libxslt
+	>=dev-libs/libxml2-2.3.6:2
+	~app-text/docbook-xml-dtd-4.3
+	app-text/docbook-xsl-stylesheets
+	~app-text/docbook-sgml-dtd-3.0
+	>=app-text/docbook-dsssl-stylesheets-1.40
+	emacs? ( >=app-editors/emacs-23.1:* )
+	$(python_gen_cond_dep '
+		dev-python/pygments[${PYTHON_MULTI_USEDEP}]
+	')
+"
+DEPEND="${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/parameterized[${PYTHON_USEDEP}]
+		')
+	)
+"
+BDEPEND="
+	~dev-util/gtk-doc-am-${PV}
+	dev-util/itstool
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	# Remove global Emacs keybindings, bug #184588
+	"${FILESDIR}"/${PN}-1.8-emacs-keybindings.patch
+)
+
+pkg_setup() {
+	DOC_CONTENTS="gtk-doc does no longer define global key bindings for Emacs.
+		You may set your own key bindings for \"gtk-doc-insert\" and
+		\"gtk-doc-insert-section\" in your ~/.emacs file."
+	SITEFILE=61${PN}-gentoo.el
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# Requires the unpackaged Python "anytree" module
+	sed -i -e '/mkhtml2/d' "${S}"/tests/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dautotools_support=true
+		-Dcmake_support=true
+		-Dyelp_manual=true
+		$(meson_use test tests)
+	)
+	meson_src_configure
+}
+
+src_compile() {
+	meson_src_compile
+	use emacs && elisp-compile tools/gtk-doc.el
+}
+
+src_install() {
+	meson_src_install
+
+	# The meson build system configures the shebangs to the temporary python
+	# used during the build. We need to fix it.
+	sed -i -e 's:^#!.*python3:#!/usr/bin/env python3:' "${ED}"/usr/bin/* || die
+	python_fix_shebang "${ED}"/usr/bin
+
+	# Don't install this file, it's in gtk-doc-am now
+	rm "${ED}"/usr/share/aclocal/gtk-doc.m4 || die "failed to remove gtk-doc.m4"
+	rmdir "${ED}"/usr/share/aclocal || die
+
+	if use emacs; then
+		elisp-install ${PN} tools/gtk-doc.el*
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+		readme.gentoo_create_doc
+	fi
+}
+
+pkg_postinst() {
+	if use emacs; then
+		elisp-site-regen
+		readme.gentoo_print_elog
+	fi
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}