dev-util/dput-ng: initial ebuild version - 1.10

Package will be maintained by Yuri Konotopov <ykonotopov@gmail.com>
via Proxy Maintainers Project.
Closes: https://github.com/gentoo/gentoo/pull/1465

Signed-off-by: Ian Delaney <idella4@gentoo.org>

3 files changed, 103 insertions, 0 deletions

diff --git a/dev-util/dput-ng/Manifest b/dev-util/dput-ng/Manifest
new file mode 100644
index 000000000000..6da3f97ca6cb
--- /dev/null
+++ b/dev-util/dput-ng/Manifest
@@ -0,0 +1 @@
+DIST dput-ng_1.10.tar.xz 82608 SHA256 20c879b47cf35adc7aa52ed0e0bc790b7ae4c29aa8e8cb9fbcc73c1467579f7a SHA512 4a883350e7a0b47c121b752d1e0ab1470924319ef895f55742fc4d8f8a0cb3a0ab4ae18d54495ebc9229b0cbf18fa375848fcdcd2431ee1f66bff6433b9a3b08 WHIRLPOOL 153eb6314926272fac45fb15054232e6ab74f8464a336893dff6555d610e7a0d1b004b3f27c6361ff91ef6f0885de51695fd07a2c2764434c0549f876e742f6d
diff --git a/dev-util/dput-ng/dput-ng-1.10.ebuild b/dev-util/dput-ng/dput-ng-1.10.ebuild
new file mode 100644
index 000000000000..cdfed677039a
--- /dev/null
+++ b/dev-util/dput-ng/dput-ng-1.10.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+DISTUTILS_SINGLE_IMPL=1
+
+inherit bash-completion-r1 distutils-r1
+
+DESCRIPTION="Next generation Debian package upload tool"
+HOMEPAGE="https://people.debian.org/~paultag/dput-ng/"
+SRC_URI="mirror://debian/pool/main/d/${PN}/${PN}_${PV}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="
+	dev-python/python-debian[${PYTHON_USEDEP}]
+	dev-python/paramiko[${PYTHON_USEDEP}]
+	dev-util/distro-info[python,${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	app-text/asciidoc
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/python-debian[${PYTHON_USEDEP}]
+	)"
+
+RESTRICT="test"
+
+S="${WORKDIR}/${PN/-/}"
+
+src_compile() {
+	distutils-r1_src_compile
+
+	mkdir man || die
+	for file in docs/man/*.man; do
+		a2x --doctype manpage --format manpage -D man \
+			"${file}" || die
+	done
+}
+
+src_install() {
+	local DPUT_BINARIES=( dcut dirt dput )
+	local DPUT_ETC=( metas profiles )
+	local DPUT_SHARE=(
+		codenames
+		commands
+		hooks
+		interfaces
+		schemas
+		uploaders
+	)
+
+	distutils-r1_src_install
+
+	for binary in ${DPUT_BINARIES[@]}; do
+		dobin bin/"${binary}"
+	done
+	python_fix_shebang "${D}"/usr/bin
+
+	insinto /etc/dput.d
+	for dir in ${DPUT_ETC[@]}; do
+		doins -r skel/"${dir}"
+	done
+
+	insinto /usr/share/"${PN}"
+	for dir in ${DPUT_SHARE[@]}; do
+		doins -r skel/"${dir}"
+	done
+
+	insinto /usr/share/man/man5
+	doins man/dput.cf.5
+	rm man/dput.cf.5 || die
+
+	for file in man/*; do
+		doman "${file}"
+	done
+
+	newbashcomp debian/"${PN}".bash-completion dput
+}
+
+python_test() {
+	# test_configs.py failing
+	# https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=824652
+	nosetests || die "Tests failed under ${EPYTHON}"
+}
diff --git a/dev-util/dput-ng/metadata.xml b/dev-util/dput-ng/metadata.xml
new file mode 100644
index 000000000000..bf1c5c247da3
--- /dev/null
+++ b/dev-util/dput-ng/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>ykonotopov@gmail.com</email>
+		<name>Yuri Konotopov</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+</pkgmetadata>