dev-python/pysvn: Python 3.10 + EAPI 8

Signed-off-by: Sebastian Pipping <sping@gentoo.org>
Package-Manager: Portage-3.0.30, Repoman-3.0.3

1 files changed, 62 insertions, 0 deletions

diff --git a/dev-python/pysvn/pysvn-1.9.15-r1.ebuild b/dev-python/pysvn/pysvn-1.9.15-r1.ebuild
new file mode 100644
index 000000000000..fb4f890e42e8
--- /dev/null
+++ b/dev-python/pysvn/pysvn-1.9.15-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+DISTUTILS_IN_SOURCE_BUILD=true
+DISTUTILS_USE_SETUPTOOLS=bdepend  # see setup.py
+inherit distutils-r1 toolchain-funcs
+
+DESCRIPTION="Object-oriented python bindings for subversion"
+HOMEPAGE="https://pysvn.sourceforge.io/"
+SRC_URI="mirror://sourceforge/project/pysvn/pysvn/V${PV}/${P}.tar.gz"
+
+LICENSE="Apache-1.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-solaris"
+IUSE="doc examples"
+
+DEPEND="
+	>=dev-python/pycxx-7.0.2[${PYTHON_USEDEP}]
+	>=dev-vcs/subversion-1.9"
+RDEPEND="${DEPEND}"
+
+python_prepare_all() {
+	# Don't use internal copy of dev-python/pycxx.
+	rm -r Import || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_configure() {
+	cd Source || die
+	CC="$(tc-getCC)" CCC="$(tc-getCXX)" \
+		esetup.py configure
+}
+
+python_compile() {
+	cd Source || die
+	emake
+}
+
+python_test() {
+	cd Tests || die
+	emake
+}
+
+python_install() {
+	cd Source || die
+	python_domodule pysvn
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( Docs/. )
+	if use examples; then
+		docinto examples
+		dodoc -r Examples/Client/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+}