dev-python/pymediainfo: bump to 3.0, make pytest verbose

Package-Manager: Portage-2.3.51, Repoman-2.3.12
Signed-off-by: Louis Sautier <sbraz@gentoo.org>

1 files changed, 48 insertions, 0 deletions

diff --git a/dev-python/pymediainfo/pymediainfo-3.0.ebuild b/dev-python/pymediainfo/pymediainfo-3.0.ebuild
new file mode 100644
index 000000000000..ea072cab56c1
--- /dev/null
+++ b/dev-python/pymediainfo/pymediainfo-3.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{4,5,6,7}} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="A wrapper around the mediainfo library"
+HOMEPAGE="https://github.com/sbraz/pymediainfo"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	media-libs/libmediainfo
+"
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/alabaster[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		${RDEPEND}
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	# Skip a test which requires network access
+	pytest -vv tests/test_pymediainfo.py -k "not MediaInfoURLTest" \
+		|| die "tests failed with ${EPYTHON}"
+}