Rename dev-python/{jupyter_server → jupyter-server}

Signed-off-by: Michał Górny <mgorny@gentoo.org>

4 files changed, 115 insertions, 0 deletions

diff --git a/dev-python/jupyter-server/Manifest b/dev-python/jupyter-server/Manifest
new file mode 100644
index 000000000000..cc3d08ee89ad
--- /dev/null
+++ b/dev-python/jupyter-server/Manifest
@@ -0,0 +1 @@
+DIST jupyter_server-2.4.0.tar.gz 693740 BLAKE2B c50a06f1ebe1479c126c2a10ac7f58f012f97f8d565f1705b5d8080ff854a387a6bbcba65785652988a1adc3575009ea0b68e48b7cda8bbd89b5208e1a6d0612 SHA512 c5ceb6caa37c6d8bb5b3026f450bdfc92c37cb5a350541fa35764eeb33007918b2aa55b41108703477efe68f7d5e4f4ba3fea51cd203f3f3c0b74ba3bed6e1c5
diff --git a/dev-python/jupyter-server/files/jupyter-server-2.0.1-skip-npm.patch b/dev-python/jupyter-server/files/jupyter-server-2.0.1-skip-npm.patch
new file mode 100644
index 000000000000..f7b484e020b6
--- /dev/null
+++ b/dev-python/jupyter-server/files/jupyter-server-2.0.1-skip-npm.patch
@@ -0,0 +1,22 @@
+diff --git a/pyproject.toml b/pyproject.toml
+index a23f5e1..203f47f 100644
+--- a/pyproject.toml
++++ b/pyproject.toml
+@@ -140,17 +140,6 @@ validate-bump = false
+ [tool.hatch.build]
+ artifacts = ["jupyter_server/static/style"]
+
+-[tool.hatch.build.hooks.jupyter-builder]
+-dependencies = ["hatch-jupyter-builder>=0.8.1"]
+-build-function = "hatch_jupyter_builder.npm_builder"
+-ensured-targets = [
+-  "jupyter_server/static/style/bootstrap.min.css",
+-  "jupyter_server/static/style/bootstrap-theme.min.css"
+-]
+-skip-if-exists = ["jupyter_server/static/style/bootstrap.min.css"]
+-install-pre-commit-hook = true
+-optional-editable-build = true
+-
+ [tool.black]
+ line-length = 100
+ target-version = ["py38"]
diff --git a/dev-python/jupyter-server/jupyter-server-2.4.0.ebuild b/dev-python/jupyter-server/jupyter-server-2.4.0.ebuild
new file mode 100644
index 000000000000..933e62cbd6cb
--- /dev/null
+++ b/dev-python/jupyter-server/jupyter-server-2.4.0.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Core services, APIs, and REST endpoints to Jupyter web applications"
+HOMEPAGE="
+	https://jupyter.org/
+	https://github.com/jupyter-server/jupyter_server/
+	https://pypi.org/project/jupyter-server/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 arm arm64 hppa ~ia64 ~loong ppc ppc64 ~riscv ~s390 sparc x86"
+
+RDEPEND="
+	>=dev-python/anyio-3.1.0[${PYTHON_USEDEP}]
+	dev-python/argon2-cffi[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_client-7.4.4[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_core-5.1.0[${PYTHON_USEDEP}]
+	dev-python/jupyter-server-terminals[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_events-0.4.0[${PYTHON_USEDEP}]
+	>=dev-python/nbconvert-6.4.4[${PYTHON_USEDEP}]
+	>=dev-python/nbformat-5.3.0[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/prometheus_client[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-24[${PYTHON_USEDEP}]
+	dev-python/send2trash[${PYTHON_USEDEP}]
+	>=dev-python/terminado-0.8.3[${PYTHON_USEDEP}]
+	>=dev-python/tornado-6.2[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.6.0[${PYTHON_USEDEP}]
+	dev-python/websocket-client[${PYTHON_USEDEP}]
+
+"
+BDEPEND="
+	test? (
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/pytest-console-scripts[${PYTHON_USEDEP}]
+		dev-python/pytest_jupyter[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/pytest-tornasync[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# This fails if your terminal is zsh (and maybe other non-bash as well?)
+	tests/test_terminal.py
+	# Fails because above is ignored
+	tests/auth/test_authorizer.py
+	# Fails with additional extensions installed
+	tests/extension/test_app.py::test_stop_extension
+)
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.0.1-skip-npm.patch"
+)
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest \
+		-p pytest_tornasync.plugin \
+		-p jupyter_server.pytest_plugin \
+		-p pytest_console_scripts \
+		-p pytest_timeout
+}
diff --git a/dev-python/jupyter-server/metadata.xml b/dev-python/jupyter-server/metadata.xml
new file mode 100644
index 000000000000..7e3ab0d6de84
--- /dev/null
+++ b/dev-python/jupyter-server/metadata.xml
@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>sci@gentoo.org</email>
+    <name>Gentoo Science Project</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <stabilize-allarches/>
+  <upstream>
+    <remote-id type="pypi">jupyter-server</remote-id>
+    <remote-id type="github">jupyter-server/jupyter_server</remote-id>
+  </upstream>
+</pkgmetadata>