dev-python/aiohttp-jinja2: new package

Package-Manager: Portage-2.3.40, Repoman-2.3.9

1 files changed, 51 insertions, 0 deletions

diff --git a/dev-python/aiohttp-jinja2/aiohttp-jinja2-0.15.0.ebuild b/dev-python/aiohttp-jinja2/aiohttp-jinja2-0.15.0.ebuild
new file mode 100644
index 000000000000..9e58af359e8c
--- /dev/null
+++ b/dev-python/aiohttp-jinja2/aiohttp-jinja2-0.15.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python3_{4,5,6} )
+
+inherit distutils-r1
+
+DESCRIPTION="jinja2 template renderer for aiohttp.web"
+HOMEPAGE="https://github.com/aio-libs/aiohttp-jinja2"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	>=dev-python/aiohttp-2.3.9[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.10[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		>=dev-python/alabaster-0.6.2[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		>=dev-python/pytest-3.2.2[${PYTHON_USEDEP}]
+		>=dev-python/pytest-aiohttp-0.3.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-capturelog-0.7[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( CHANGES.txt README.rst )
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	py.test -v tests || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+
+	distutils-r1_python_install_all
+}