dev-libs/appstream: 0.14.6 version bump

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 78 insertions, 0 deletions

diff --git a/dev-libs/appstream/Manifest b/dev-libs/appstream/Manifest
index e3a5232bebc5..dd57b3a27bb3 100644
--- a/dev-libs/appstream/Manifest
+++ b/dev-libs/appstream/Manifest
@@ -1 +1,2 @@
 DIST AppStream-0.14.5.tar.xz 2344820 BLAKE2B 714f7004db7579fb293c68e8574f0ebb8cea230e090edbaf459e6e2e0833656d7dd6372bd55c39c5e0b665117015c768990ac8b182a51219823c9cf90360263d SHA512 3f2fff8ee98a5689534802136b9fc8368422ce73c72458924b49beeb5b01170dadf25308bee692cfbc0b0a6cd4b3ee3047e46668a1b76a16b23faec4bf8ae78c
+DIST AppStream-0.14.6.tar.xz 2403088 BLAKE2B 1eb85601c1782fc47ff21983517f301dc9493fb60347cfe8072c277cc4415e80bf6c11a93db80b6d7fe1eeda7ff1fa414fd10ce7ef0d7379b415326407d805b8 SHA512 810aa7427df50793f4bed27cc3cb5b72c156f0c582f241e06131aa8eabe82d59c8ac0bcc37a22877f7a19ac4640a9a831f8b567ce3e2d26a41ce999515affdb0
diff --git a/dev-libs/appstream/appstream-0.14.6.ebuild b/dev-libs/appstream/appstream-0.14.6.ebuild
new file mode 100644
index 000000000000..0354ce9412b7
--- /dev/null
+++ b/dev-libs/appstream/appstream-0.14.6.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson xdg-utils
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/ximion/${PN}"
+else
+	SRC_URI="https://www.freedesktop.org/software/appstream/releases/AppStream-${PV}.tar.xz"
+	S="${WORKDIR}/AppStream-${PV}"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+fi
+
+DESCRIPTION="Cross-distro effort for providing metadata for software in the Linux ecosystem"
+HOMEPAGE="https://www.freedesktop.org/wiki/Distributions/AppStream/"
+
+LICENSE="LGPL-2.1+ GPL-2+"
+# check as_api_level
+SLOT="0/4"
+IUSE="apt doc +introspection qt5 test"
+RESTRICT="test" # bug 691962
+
+RDEPEND="
+	dev-db/lmdb:=
+	>=dev-libs/glib-2.58:2
+	dev-libs/libxml2:2
+	dev-libs/libyaml
+	dev-libs/snowball-stemmer:=
+	net-misc/curl
+	introspection? ( >=dev-libs/gobject-introspection-1.56:= )
+	qt5? ( dev-qt/qtcore:5 )
+"
+DEPEND="${RDEPEND}
+	test? ( qt5? ( dev-qt/qttest:5 ) )
+"
+BDEPEND="
+	dev-libs/appstream-glib
+	dev-libs/libxslt
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	doc? ( app-text/docbook-xml-dtd:4.5 )
+	test? ( dev-qt/linguist-tools:5 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.14.3-disable-Werror-flags.patch # bug 733774
+)
+
+src_prepare() {
+	default
+	sed -e "/^as_doc_target_dir/s/appstream/${PF}/" -i docs/meson.build || die
+	if ! use test; then
+		sed -e "/^subdir.*tests/s/^/#DONT /" -i {,qt/}meson.build || die # bug 675944
+	fi
+}
+
+src_configure() {
+	xdg_environment_reset
+
+	local emesonargs=(
+		-Dapidocs=false
+		-Ddocs=false
+		-Dcompose=false
+		-Dmaintainer=false
+		-Dstemming=true
+		-Dvapi=false
+		-Dapt-support=$(usex apt true false)
+		-Dinstall-docs=$(usex doc true false)
+		-Dgir=$(usex introspection true false)
+		-Dqt=$(usex qt5 true false)
+	)
+
+	meson_src_configure
+}