dev-db/pgagent: Fix pthread linking

Bug: https://bugs.gentoo.org/688472
Package-Manager: Portage-2.3.84, Repoman-2.3.16
Signed-off-by: Aaron W. Swenson <titanofold@gentoo.org>

1 files changed, 55 insertions, 0 deletions

diff --git a/dev-db/pgagent/pgagent-4.0.0-r1.ebuild b/dev-db/pgagent/pgagent-4.0.0-r1.ebuild
new file mode 100644
index 000000000000..fe9014a136f6
--- /dev/null
+++ b/dev-db/pgagent/pgagent-4.0.0-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+CMAKE_IN_SOURCE_BUILD=1
+
+inherit cmake-utils user
+
+MY_PN=${PN/a/A}
+
+KEYWORDS="~amd64 ~x86"
+
+DESCRIPTION="${MY_PN} is a job scheduler for PostgreSQL"
+HOMEPAGE="https://www.pgadmin.org/download/pgagent-source-code/"
+SRC_URI="https://ftp.postgresql.org/pub/pgadmin/${PN}/${MY_PN}-${PV}-Source.tar.gz"
+
+LICENSE="POSTGRESQL GPL-2"
+SLOT="0"
+
+RDEPEND="dev-db/postgresql:*
+		dev-libs/boost
+"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${MY_PN}-${PV}-Source"
+
+PATCHES=( "${FILESDIR}"/pgagent-4.0.0-pthreads-linking.patch )
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	sed -e "s:share):share/${P}):" \
+		-i CMakeLists.txt || die "failed to patch CMakeLists.txt"
+}
+
+src_configure() {
+	mycmakeargs=( "-DSTATIC_BUILD:BOOLEAN=FALSE"
+				   )
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	newinitd "${FILESDIR}/pgagent.initd-r1" "${PN}"
+	newconfd "${FILESDIR}/pgagent.confd" "${PN}"
+
+	rm "${ED}"/usr/{LICENSE,README} || die "failed to remove useless docs"
+}
+
+pkg_preinst() {
+	# This user needs a real shell, and the daemon will use the
+	# ~/.pgpass file from its home directory.
+	enewuser pgagent -1 /bin/bash /home/pgagent
+}