app-misc/mosquitto: Version bump to 2.0.11

Signed-off-by: Matt Turner <mattst88@gentoo.org>

1 files changed, 123 insertions, 0 deletions

diff --git a/app-misc/mosquitto/mosquitto-2.0.11.ebuild b/app-misc/mosquitto/mosquitto-2.0.11.ebuild
new file mode 100644
index 000000000000..7e129f60e2c1
--- /dev/null
+++ b/app-misc/mosquitto/mosquitto-2.0.11.ebuild
@@ -0,0 +1,123 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit python-any-r1 systemd toolchain-funcs
+
+DESCRIPTION="An Open Source MQTT v3 Broker"
+HOMEPAGE="https://mosquitto.org/ https://github.com/eclipse/mosquitto"
+SRC_URI="https://mosquitto.org/files/source/${P}.tar.gz"
+
+LICENSE="EPL-1.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="bridge examples +persistence +srv ssl tcpd test websockets"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="test? ( bridge )"
+
+RDEPEND="
+	acct-user/mosquitto
+	acct-group/mosquitto
+	dev-libs/cJSON:=
+	srv? ( net-dns/c-ares:= )
+	ssl? (
+		dev-libs/openssl:0=
+	)
+	tcpd? ( sys-apps/tcp-wrappers )"
+
+DEPEND="${PYTHON_DEPS}
+	${RDEPEND}
+	test? ( dev-util/cunit )
+	websockets? ( net-libs/libwebsockets[lejp] )"
+
+_emake() {
+	local LIBDIR=$(get_libdir)
+	emake \
+		CC="$(tc-getCC)" \
+		CLIENT_LDFLAGS="${LDFLAGS}" \
+		LIB_SUFFIX="${LIBDIR:3}" \
+		WITH_BRIDGE="$(usex bridge)" \
+		WITH_PERSISTENCE="$(usex persistence)" \
+		WITH_SRV="$(usex srv)" \
+		WITH_TLS="$(usex ssl)" \
+		WITH_WEBSOCKETS="$(usex websockets)" \
+		WITH_WRAP="$(usex tcpd)" \
+		"$@"
+}
+
+src_prepare() {
+	default
+	if use persistence; then
+		sed -i -e "/^#autosave_interval/s|^#||" \
+			-e "s|^#persistence false$|persistence true|" \
+			-e "/^#persistence_file/s|^#||" \
+			-e "s|#persistence_location|persistence_location /var/lib/mosquitto/|" \
+			mosquitto.conf || die
+	fi
+
+	# Remove prestripping
+	sed -i -e 's/-s --strip-program=${CROSS_COMPILE}${STRIP}//'\
+		client/Makefile lib/cpp/Makefile src/Makefile lib/Makefile || die
+
+	# Remove failing tests
+	sed -i -e '/02-subpub-qos1-bad-pubcomp.py/d' \
+		-e '/02-subpub-qos1-bad-pubrec.py/d' \
+		-e '/02-subpub-qos2-bad-puback-1.py/d' \
+		-e '/02-subpub-qos2-bad-puback-2.py/d' \
+		-e '/02-subpub-qos2-bad-pubcomp.py/d' \
+		test/broker/Makefile || die
+	sed -i -e '/02-subscribe-qos1-async2.test/d' \
+		test/lib/Makefile || die
+
+	# Extend test timeout to prevent spurious failures
+	sed -i -e 's/SUB_TIMEOUT=1/SUB_TIMEOUT=3/' \
+		test/client/test.sh || die
+
+	python_setup
+	python_fix_shebang test
+}
+
+src_compile() {
+	_emake
+}
+
+src_test() {
+	_emake test
+}
+
+src_install() {
+	_emake DESTDIR="${D}" prefix=/usr install
+	keepdir /var/lib/mosquitto
+	fowners mosquitto:mosquitto /var/lib/mosquitto
+	dodoc README.md CONTRIBUTING.md ChangeLog.txt
+	doinitd "${FILESDIR}"/mosquitto
+	insinto /etc/mosquitto
+	doins mosquitto.conf
+	insinto /usr/share/mosquitto
+	doins misc/letsencrypt/mosquitto-copy.sh
+	systemd_dounit "${FILESDIR}/mosquitto.service"
+
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		dodoc -r examples
+	fi
+}
+
+pkg_postinst() {
+	for v in ${REPLACING_VERSIONS}; do
+		if [[ $(ver_cut 1 "$v") -lt 2 ]]; then
+			elog
+			elog "Please read the migration guide at:"
+			elog "https://mosquitto.org/documentation/migrating-to-2-0/"
+			elog
+			elog "If you use Lets Encrypt TLS certificates, take note of"
+			elog "the changes required to run the daemon as the unprivileged"
+			elog "mosquitto user. The mosquitto-copy.sh script has been"
+			elog "installed to /usr/share/mosquitto/ for your convenience."
+			elog
+		fi
+	done
+}