app-admin/salt: drop 3006.0

Signed-off-by: Patrick McLean <chutzpah@gentoo.org>

2 files changed, 0 insertions, 227 deletions

diff --git a/app-admin/salt/Manifest b/app-admin/salt/Manifest
index f256d9efecc8..d2389951b10d 100644
--- a/app-admin/salt/Manifest
+++ b/app-admin/salt/Manifest
@@ -1,3 +1,2 @@
 DIST salt-3005.1.tar.gz 17914349 BLAKE2B 697c2068bf119e4a19f92a86ce880fec9375c10ba549cdcdd2182cfeaacce31c7bc4c4c91e1a609906b4c5373bb5e3120e0db47ede5b45ee20942d7b2d201e64 SHA512 391f995f0129f3d7104a0eea4fd83b18aa6ecae0fd7a2c77c1154e24b0bcd52cef4b63db12597c85737bb33ddf605e0c23370cef3bf47f9ea85af5b77d74dc50
-DIST salt-3006.0.tar.gz 20377846 BLAKE2B d39a55676f6bc5f70a558684811dd6175b633ceb5b73f4e95bd0137e7a507456f2e77099c05aca082591b9bdff1948632adc9f141e2f8ad26c4bfedd98af3d15 SHA512 999e2eb362607e1a8a0636c3bfa305fb070a5df309b837975a03a0bf02d25e4678eae38e8a1a356ea857a6d81cbb68aeb9f903a55dd221c7485d2f22b309dd77
 DIST salt-3006.2.tar.gz 20411634 BLAKE2B dff474017918ef3ee0031856a2739282077205d8c2589809a91e5f1c3741cb26d2bd2458734ea4d3533118c881851dfd853f4ba4f1c631e7db28e95bc1b6f7f8 SHA512 2626cb5beb1b30fc63f554f5804f0d9b7e36b7c569c5f9049e5f5ac5a413e9d99a98b3d91089683338e3d3890ec973dff80782b4e41acb291872e45084fd2546
diff --git a/app-admin/salt/salt-3006.0.ebuild b/app-admin/salt/salt-3006.0.ebuild
deleted file mode 100644
index 5e8c420c6cdc..000000000000
--- a/app-admin/salt/salt-3006.0.ebuild
+++ /dev/null
@@ -1,226 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-PYTHON_COMPAT=( python3_10 )
-
-DISTUTILS_USE_PEP517=setuptools
-inherit systemd distutils-r1
-
-DESCRIPTION="Salt is a remote execution and configuration manager"
-HOMEPAGE="https://www.saltstack.com/resources/community/
-	https://github.com/saltstack"
-
-if [[ ${PV} == 9999* ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/${PN}stack/${PN}.git"
-	EGIT_BRANCH="develop"
-else
-	inherit pypi
-	KEYWORDS="~amd64 ~riscv ~x86"
-fi
-
-LICENSE="Apache-2.0"
-SLOT="0"
-IUSE="
-	cheetah cherrypy ldap libcloud libvirt genshi gnupg keyring mako
-	mongodb neutron	nova openssl portage profile redis selinux test raet
-	+zeromq vim-syntax
-"
-
-RDEPEND="
-	sys-apps/pciutils
-	>=dev-python/distro-1.5[${PYTHON_USEDEP}]
-	>=dev-python/jinja-3.1.2[${PYTHON_USEDEP}]
-	dev-python/jmespath[${PYTHON_USEDEP}]
-	dev-python/libnacl[${PYTHON_USEDEP}]
-	dev-python/looseversion[${PYTHON_USEDEP}]
-	>=dev-python/msgpack-1.0.0[${PYTHON_USEDEP}]
-	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
-	>=dev-python/psutil-5.0.0[${PYTHON_USEDEP}]
-	>=dev-python/pycryptodome-3.9.8[${PYTHON_USEDEP}]
-	dev-python/pyyaml[${PYTHON_USEDEP}]
-	>=dev-python/markupsafe-2.1.2[${PYTHON_USEDEP}]
-	>=dev-python/requests-1.0.0[${PYTHON_USEDEP}]
-	dev-python/setuptools[${PYTHON_USEDEP}]
-	dev-python/tomli[${PYTHON_USEDEP}]
-	dev-python/watchdog[${PYTHON_USEDEP}]
-	libcloud? (
-		dev-python/aiohttp[${PYTHON_USEDEP}]
-		dev-python/aiosignal[${PYTHON_USEDEP}]
-		>=dev-python/apache-libcloud-2.5.0[${PYTHON_USEDEP}]
-		dev-python/async-timeout[${PYTHON_USEDEP}]
-	)
-	mako? ( dev-python/mako[${PYTHON_USEDEP}] )
-	ldap? ( dev-python/python-ldap[${PYTHON_USEDEP}] )
-	libvirt? (
-		dev-python/libvirt-python[${PYTHON_USEDEP}]
-	)
-	openssl? (
-		dev-libs/openssl:0=[-bindist(-)]
-		dev-python/pyopenssl[${PYTHON_USEDEP}]
-	)
-	raet? (
-		>=dev-python/libnacl-1.0.0[${PYTHON_USEDEP}]
-		>=dev-python/ioflo-1.1.7[${PYTHON_USEDEP}]
-		>=dev-python/raet-0.6.0[${PYTHON_USEDEP}]
-	)
-	cherrypy? ( >=dev-python/cherrypy-3.2.2[${PYTHON_USEDEP}] )
-	cheetah? ( >=dev-python/cheetah3-3.2.2[${PYTHON_USEDEP}] )
-	genshi? ( dev-python/genshi[${PYTHON_USEDEP}] )
-	mongodb? ( dev-python/pymongo[${PYTHON_USEDEP}] )
-	portage? ( sys-apps/portage[${PYTHON_USEDEP}] )
-	keyring? ( dev-python/keyring[${PYTHON_USEDEP}] )
-	redis? ( dev-python/redis[${PYTHON_USEDEP}] )
-	selinux? ( sec-policy/selinux-salt )
-	nova? (
-		>=dev-python/python-novaclient-2.17.0[${PYTHON_USEDEP}]
-	)
-	neutron? (
-		>=dev-python/python-neutronclient-2.3.6[${PYTHON_USEDEP}]
-	)
-	gnupg? ( dev-python/python-gnupg[${PYTHON_USEDEP}] )
-	profile? ( dev-python/yappi[${PYTHON_USEDEP}] )
-	vim-syntax? ( app-vim/salt-vim )
-	zeromq? ( >=dev-python/pyzmq-19.0.0[${PYTHON_USEDEP}] )
-"
-BDEPEND="
-	dev-python/build[${PYTHON_USEDEP}]
-	test? (
-		${RDEPEND}
-		dev-python/apache-libcloud[${PYTHON_USEDEP}]
-		>=dev-python/boto-2.32.1[${PYTHON_USEDEP}]
-		>=dev-python/certifi-2022.12.07[${PYTHON_USEDEP}]
-		dev-python/cherrypy[${PYTHON_USEDEP}]
-		>=dev-python/jsonschema-3.0[${PYTHON_USEDEP}]
-		dev-python/mako[${PYTHON_USEDEP}]
-		>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
-		>=dev-python/moto-2.0.0[${PYTHON_USEDEP}]
-		dev-python/passlib[${PYTHON_USEDEP}]
-		dev-python/bcrypt[${PYTHON_USEDEP}]
-		dev-python/pip[${PYTHON_USEDEP}]
-		>=dev-python/pyopenssl-23.0.0[${PYTHON_USEDEP}]
-		>=dev-python/pytest-7.2.0[${PYTHON_USEDEP}]
-		>=dev-python/pytest-salt-factories-1.0.0_rc21[${PYTHON_USEDEP}]
-		dev-python/pytest-tempdir[${PYTHON_USEDEP}]
-		dev-python/pytest-helpers-namespace[${PYTHON_USEDEP}]
-		dev-python/pytest-subtests[${PYTHON_USEDEP}]
-		dev-python/pytest-shell-utilities[${PYTHON_USEDEP}]
-		dev-python/pytest-skip-markers[${PYTHON_USEDEP}]
-		dev-python/pytest-system-statistics[${PYTHON_USEDEP}]
-		dev-python/pytest-custom-exit-code[${PYTHON_USEDEP}]
-		dev-python/flaky[${PYTHON_USEDEP}]
-		net-dns/bind-tools
-		>=dev-python/virtualenv-20.3.0[${PYTHON_USEDEP}]
-		dev-util/yamllint[${PYTHON_USEDEP}]
-		!x86? ( >=dev-python/boto3-1.21.46[${PYTHON_USEDEP}] )
-	)
-"
-
-DOCS=( README.rst AUTHORS )
-
-REQUIRED_USE="|| ( raet zeromq )
-	test? ( cheetah genshi )"
-RESTRICT="!test? ( test ) x86? ( test )"
-
-PATCHES=(
-	"${FILESDIR}/salt-3003-gentoolkit-revdep.patch"
-	"${FILESDIR}/salt-3005.1-no-entry-points.patch"
-	"${FILESDIR}/salt-3006-skip-tests-that-oom-machine.patch"
-	"${FILESDIR}/salt-3006-tests.patch"
-)
-
-python_prepare_all() {
-	# remove tests with external dependencies that may not be available, and
-	# tests that don't work in sandbox
-	rm tests/unit/{test_{zypp_plugins,module_names},utils/test_extend}.py || die
-	rm tests/unit/modules/test_boto_{vpc,secgroup,elb}.py || die
-	rm tests/unit/states/test_boto_vpc.py || die
-
-	#rm tests/support/gitfs.py || die
-	rm tests/pytests/functional/transport/server/test_req_channel.py || die
-	rm tests/pytests/functional/utils/test_async_event_publisher.py || die
-	rm tests/pytests/functional/runners/test_winrepo.py || die
-	rm tests/unit/netapi/rest_tornado/test_saltnado.py || die
-
-	# tests that require network access
-	rm tests/unit/{states,modules}/test_zcbuildout.py || die
-	rm -r tests/integration/cloud || die
-	rm -r tests/kitchen/tests/wordpress/tests || die
-	rm tests/kitchen/test_kitchen.py || die
-	rm tests/unit/modules/test_network.py || die
-	rm tests/pytests/functional/modules/test_pip.py || die
-	rm tests/pytests/unit/client/ssh/test_ssh.py || die
-	rm -r tests/pytests/{integration,functional}/netapi tests/integration/netapi || die
-
-	# tests require root access
-	rm tests/integration/pillar/test_git_pillar.py || die
-	rm tests/integration/states/test_supervisord.py || die
-
-	# removes contextvars, see bug: https://bugs.gentoo.org/799431
-	sed -i '/^contextvars/d' requirements/base.txt || die
-
-	# make sure pkg_resources doesn't bomb because pycrypto isn't installed
-	find "${S}" -name '*.txt' -print0 | xargs -0 sed -e '/pycrypto>/ d ; /pycryptodomex/ d' -i || die
-	# pycryptodome rather than pycryptodomex
-	find "${S}" -name '*.py' -print0 | xargs -0 -- sed -i -e 's:Cryptodome:Crypto:g' -- || die
-
-	distutils-r1_python_prepare_all
-}
-
-python_install_all() {
-	local svc
-	USE_SETUPTOOLS=1 distutils-r1_python_install_all
-
-	for svc in minion master syndic api; do
-		newinitd "${FILESDIR}"/${svc}-initd-5 salt-${svc}
-		newconfd "${FILESDIR}"/${svc}-confd-1 salt-${svc}
-		systemd_dounit "${FILESDIR}"/salt-${svc}.service
-	done
-
-	insinto /etc/${PN}
-	doins -r conf/*
-}
-
-python_test() {
-	# testsuite likes lots of files
-	ulimit -n 4096 || die
-
-	local -a disable_tests=(
-		# doesn't like the distutils warning
-		batch_retcode
-		multiple_modules_in_batch
-		# hangs indefinitely
-		master_type_disable
-		# needs root
-		runas_env_sudo_group
-		# don't like sandbox
-		split_multibyte_characters_{shiftjis,unicode}
-		log_sanitize
-		run_with_pre_flight_args
-		compile_template_str_mkstemp_cleanup
-		sync_with_handlers
-		deferred_write_on_flush
-		call_apt_dpkg_lock
-		enforce_nice_config
-		config_validation
-	)
-
-	local textexpr
-	testexpr=$(printf 'not %s and ' "${disable_tests[@]}")
-
-	# ${T} is too long a path for the tests to work
-	local TMPDIR
-	TMPDIR="$(mktemp --directory --tmpdir=/tmp ${PN}-XXXX)" || die
-	(
-		export TMPDIR
-		cleanup() { rm -rf "${TMPDIR}" || die; }
-
-		trap cleanup EXIT
-
-		addwrite "${TMPDIR}"
-
-		USE_SETUPTOOLS=1 NO_INTERNET=1 SHELL="/bin/bash" \
-			epytest  -k "${testexpr%and }" -x
-	)
-}