Merge updates from master

13 files changed, 212 insertions, 87 deletions

diff --git a/games-action/trine-bin/metadata.xml b/games-action/trine-bin/metadata.xml
deleted file mode 100644
index 78274e0fa550..000000000000
--- a/games-action/trine-bin/metadata.xml
+++ /dev/null
@@ -1,8 +0,0 @@
-<?xml version="1.0" encoding="UTF-8"?>
-<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
-<pkgmetadata>
-<maintainer type="project">
-	<email>games@gentoo.org</email>
-	<name>Gentoo Games Project</name>
-</maintainer>
-</pkgmetadata>
diff --git a/games-action/trine-bin/trine-bin-1.08-r2.ebuild b/games-action/trine-bin/trine-bin-1.08-r2.ebuild
deleted file mode 100644
index 99503c9efac8..000000000000
--- a/games-action/trine-bin/trine-bin-1.08-r2.ebuild
+++ /dev/null
@@ -1,77 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit desktop eutils unpacker
-
-DESCRIPTION="A physics-based action game with character-dependent solutions to challenges"
-HOMEPAGE="http://trine-thegame.com/"
-SRC_URI="TrineUpdate4.64.run"
-
-LICENSE="frozenbyte-eula"
-SLOT="0"
-KEYWORDS="-* ~amd64 ~x86"
-RESTRICT="fetch strip"
-
-DEPEND="
-	app-admin/chrpath
-	app-arch/unzip
-"
-
-RDEPEND="
-	dev-libs/glib:2
-	dev-libs/libx86
-	gnome-base/libglade:2.0
-	media-libs/libogg
-	media-libs/libpng:1.2
-	>=media-libs/libsdl-1.2[opengl,sound,video]
-	>=media-libs/libvorbis-1.3
-	>=media-libs/openal-1.15
-	>=media-libs/tiff-3.9:3
-	>=sys-devel/gcc-4.3.0
-	>=sys-libs/glibc-2.4
-	virtual/jpeg:62
-	x11-libs/gtk+:2
-"
-
-S="${WORKDIR}"
-d="/opt/${PN}"
-QA_PREBUILT="*"
-
-pkg_nofetch() {
-	einfo "Fetch ${SRC_URI} and put it into ${DISTDIR}"
-	einfo "See http://www.humblebundle.com/ for more info."
-}
-
-src_unpack() {
-	unpack_zip ${A}
-}
-
-src_prepare() {
-	default
-	rm -v lib*/lib{gcc_s,jpeg,m,ogg,openal,png*,rt,SDL*,selinux,stdc++,tiff,vorbis*}.* || die
-	chrpath --replace "${EPREFIX}${d}"/lib trine-{bin,launcher}$(usex x86 32 64) || die
-}
-
-src_install() {
-	local b bb
-	local sfx=$(usex x86 32 64)
-
-	doicon Trine.xpm
-	for b in bin launcher ; do
-		bb="trine-${b}"
-		exeinto ${d}
-		newexe ${bb}${sfx} ${bb}
-		make_wrapper ${bb} "./${bb}" "${d}"
-		make_desktop_entry ${bb} "Trine ${b}" Trine
-	done
-
-	exeinto ${d}/lib
-	doexe lib${sfx}/*
-
-	insinto ${d}
-	doins -r binds config data dev profiles *.fbz *.glade trine-logo.png
-
-	dodoc Trine_Manual_linux.pdf Trine_updates.txt
-}
diff --git a/games-action/trine-enchanted-edition/Manifest b/games-action/trine-enchanted-edition/Manifest
new file mode 100644
index 000000000000..5c5f1cb6ae9d
--- /dev/null
+++ b/games-action/trine-enchanted-edition/Manifest
@@ -0,0 +1 @@
+DIST trine_enchanted_edition_v2_12_build_508_humble_linux_full.zip 1226749814 BLAKE2B 9803f78279bcf83a2a54f25e2498664b73ba1c0ae5c540bb4479345ae05495cc11527937876fb7c9dbb34d05dbbdb4575cc6c1899923c782ff67ea23bd2cfac9 SHA512 e883763efe89f09a84c2896bfd0a9a13319dd14bb840e67f1812a0bab45bcab7a144f4c9399194e5aabad0435e350c6a903a542c9101a37c602855ebd0884d9d
diff --git a/games-action/trine-enchanted-edition/metadata.xml b/games-action/trine-enchanted-edition/metadata.xml
new file mode 100644
index 000000000000..b26a6baa4124
--- /dev/null
+++ b/games-action/trine-enchanted-edition/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>games@gentoo.org</email>
+		<name>Gentoo Games Project</name>
+	</maintainer>
+	<use>
+		<flag name="launcher">Install GTK+ launcher</flag>
+	</use>
+</pkgmetadata>
diff --git a/games-action/trine-enchanted-edition/trine-enchanted-edition-2.12.508.ebuild b/games-action/trine-enchanted-edition/trine-enchanted-edition-2.12.508.ebuild
new file mode 100644
index 000000000000..87871dfbf505
--- /dev/null
+++ b/games-action/trine-enchanted-edition/trine-enchanted-edition-2.12.508.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit desktop eutils gnome2-utils
+
+MY_P="${PV//./_}"
+MY_P="${PN//-/_}_v${MY_P%_*}_build_${MY_P##*_}"
+MY_PN="Trine Enchanted Edition"
+
+DESCRIPTION="The original sidescrolling action platformer under the Trine 2 engine"
+HOMEPAGE="https://www.frozenbyte.com/games/trine-enchanted-edition"
+SRC_URI="${MY_P}_humble_linux_full.zip"
+LICENSE="all-rights-reserved"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+IUSE="+launcher"
+RESTRICT="bindist fetch splitdebug"
+
+QA_PREBUILT="opt/${PN}/${PN}*"
+
+DEPEND="app-arch/unzip"
+
+# SDL 1.3 is bundled but the game appears to be statically linked
+# against SDL 2.0.3. This is unfortunate as there are bugs. For example,
+# it doesn't respect the DISPLAY variable under Zaphod mode.
+
+RDEPEND="
+	media-gfx/nvidia-cg-toolkit[abi_x86_32]
+	media-libs/alsa-lib[abi_x86_32]
+	media-libs/freetype:2[abi_x86_32]
+	media-libs/libogg[abi_x86_32]
+	>=media-libs/libvorbis-1.3[abi_x86_32]
+	>=media-libs/openal-1.15[abi_x86_32]
+	sys-libs/zlib[abi_x86_32]
+	virtual/glu[abi_x86_32]
+	virtual/opengl[abi_x86_32]
+	launcher? (
+		dev-libs/glib:2[abi_x86_32]
+		media-libs/libpng:1.2[abi_x86_32]
+		x11-libs/gdk-pixbuf:2[abi_x86_32,X]
+		x11-libs/gtk+:2[abi_x86_32]
+		x11-libs/libX11[abi_x86_32]
+		x11-libs/pango[abi_x86_32,X]
+	)"
+
+S="${WORKDIR}/linux/_enchanted_edition_"
+
+pkg_nofetch() {
+	einfo "Please buy and download ${SRC_URI} from:"
+	einfo "  https://www.humblebundle.com/store/${PN}"
+	einfo "and move it to your distfiles directory."
+}
+
+src_install() {
+	local dir=/opt/${PN}
+
+	insinto "${dir}"
+	doins -r *.fbq data
+
+	exeinto "${dir}"
+	newexe bin/trine1_linux_32bit ${PN}
+
+	make_wrapper ${PN} ./${PN} "${dir}"
+	make_desktop_entry ${PN} "${MY_PN}"
+
+	if use launcher ; then
+		exeinto "${dir}"
+		newexe bin/trine1_linux_launcher_32bit ${PN}-launcher
+
+		make_wrapper ${PN}-launcher ./${PN}-launcher "${dir}"
+		make_desktop_entry ${PN}-launcher "${MY_PN} (launcher)"
+
+		# Launcher binary has hardcoded the game path.
+		dosym ../${PN} "${dir}"/bin/trine1_bin_starter.sh
+	fi
+
+	newicon -s 64 trine1.png ${PN}.png
+	dodoc readme_changelog.txt
+}
+
+pkg_preinst() { gnome2_icon_savelist; }
+pkg_postinst() { gnome2_icon_cache_update; }
+pkg_postrm() { gnome2_icon_cache_update; }
diff --git a/games-action/trine-bin/Manifest b/games-action/trine/Manifest
index dd34b082ffeb..dd34b082ffeb 100644
--- a/games-action/trine-bin/Manifest
+++ b/games-action/trine/Manifest
diff --git a/games-action/trine/metadata.xml b/games-action/trine/metadata.xml
new file mode 100644
index 000000000000..b26a6baa4124
--- /dev/null
+++ b/games-action/trine/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>games@gentoo.org</email>
+		<name>Gentoo Games Project</name>
+	</maintainer>
+	<use>
+		<flag name="launcher">Install GTK+ launcher</flag>
+	</use>
+</pkgmetadata>
diff --git a/games-action/trine/trine-1.08-r3.ebuild b/games-action/trine/trine-1.08-r3.ebuild
new file mode 100644
index 000000000000..f9b9673cdd45
--- /dev/null
+++ b/games-action/trine/trine-1.08-r3.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit desktop eutils gnome2-utils unpacker
+
+DESCRIPTION="A physics-based action game with character-dependent solutions to challenges"
+HOMEPAGE="https://www.frozenbyte.com/games/trine-enchanted-edition"
+SRC_URI="TrineUpdate4.64.run"
+LICENSE="frozenbyte-eula"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+IUSE="+launcher"
+RESTRICT="bindist fetch strip"
+
+QA_PREBUILT="opt/${PN}/${PN}*
+	opt/${PN}/lib/*"
+
+DEPEND="
+	app-admin/chrpath
+	app-arch/unzip
+"
+
+RDEPEND="
+	media-gfx/nvidia-cg-toolkit
+	>=media-libs/libsdl-1.2[opengl,video]
+	>=media-libs/sdl-image-1.2
+	>=media-libs/sdl-ttf-2.0
+	>=media-libs/libvorbis-1.3
+	>=media-libs/openal-1.15
+	>=sys-devel/gcc-4.3.0
+	>=sys-libs/glibc-2.4
+	sys-libs/zlib
+	x11-libs/gtk+:2
+	launcher? (
+		dev-libs/glib:2
+		gnome-base/libglade:2.0
+	)"
+
+S="${WORKDIR}"
+dir="/opt/${PN}"
+
+pkg_nofetch() {
+	einfo "Fetch ${SRC_URI} and put it into your distfiles directory."
+	einfo "It is no longer available to purchase but you can still download it"
+	einfo "from https://www.humblebundle.com if you bought it previously."
+	einfo "Otherwise install ${CATEGORY}/trine-enchanted-edition instead."
+}
+
+src_unpack() {
+	unpack_zip ${A}
+}
+
+src_prepare() {
+	default
+	use launcher || rm -v lib*/lib{boost*,icu*}.* || die
+	rm -v lib*/lib{Cg*,direct*,fusion*,gcc_s,jpeg,m,ogg,openal,png*,rt,SDL*,selinux,stdc++,tiff,vga,vorbis*}.* || die
+	chrpath --replace "${EPREFIX}${dir}"/lib trine-{bin,launcher}$(usex x86 32 64) || die
+}
+
+src_install() {
+	local sfx=$(usex x86 32 64)
+
+	insinto "${dir}"
+	doins -r binds config data dev profiles *.fbz *.glade trine-logo.png
+
+	exeinto "${dir}/lib"
+	doexe lib${sfx}/*
+
+	exeinto "${dir}"
+	newexe trine-bin${sfx} ${PN}
+
+	make_wrapper ${PN} ./${PN} "${dir}"
+	make_desktop_entry ${PN} "Trine"
+
+	# Compatibility with trine-bin.
+	dosym ${PN} /usr/bin/${PN}-bin
+
+	if use launcher ; then
+		exeinto "${dir}"
+		newexe trine-launcher${sfx} ${PN}-launcher
+
+		dosym {"../..${dir}",/usr/bin}/${PN}-launcher
+		make_desktop_entry ${PN}-launcher "Trine (launcher)"
+
+		# Launcher binary has hardcoded the game path.
+		dosym ${PN} "${dir}"/${PN}-bin
+	fi
+
+	newicon -s 512 Trine.xpm ${PN}.xpm
+	dodoc Trine_Manual_linux.pdf Trine_updates.txt
+}
+
+pkg_preinst() { gnome2_icon_savelist; }
+pkg_postinst() { gnome2_icon_cache_update; }
+pkg_postrm() { gnome2_icon_cache_update; }
diff --git a/profiles/arch/amd64/no-multilib/package.mask b/profiles/arch/amd64/no-multilib/package.mask
index 4ca9e2de3dad..c49832e6640c 100644
--- a/profiles/arch/amd64/no-multilib/package.mask
+++ b/profiles/arch/amd64/no-multilib/package.mask
@@ -61,6 +61,7 @@ games-action/shadowgrounds-survivor-bin
 games-action/solar2
 games-action/spacetripper-demo
 games-action/swordandsworcery
+games-action/trine-enchanted-edition
 games-action/trine2
 games-arcade/aquaria
 games-arcade/barbarian-bin
diff --git a/profiles/default/linux/musl/package.mask b/profiles/default/linux/musl/package.mask
index 303f8b5b4ca2..313dfc4b59a8 100644
--- a/profiles/default/linux/musl/package.mask
+++ b/profiles/default/linux/musl/package.mask
@@ -35,7 +35,8 @@ games-action/shadowgrounds-survivor-bin
 games-action/solar2
 games-action/spacetripper-demo
 games-action/swordandsworcery
-games-action/trine-bin
+games-action/trine
+games-action/trine-enchanted-edition
 games-action/trine2
 games-arcade/aquaria
 games-arcade/barbarian-bin
diff --git a/profiles/default/linux/uclibc/package.mask b/profiles/default/linux/uclibc/package.mask
index f5208eadab27..b94a8ca92688 100644
--- a/profiles/default/linux/uclibc/package.mask
+++ b/profiles/default/linux/uclibc/package.mask
@@ -24,7 +24,7 @@ games-action/descent3
 games-action/descent3-demo
 games-action/shadowgrounds-bin
 games-action/shadowgrounds-survivor-bin
-games-action/trine-bin
+games-action/trine
 games-arcade/marbleblastgold-demo
 games-fps/enemy-territory
 games-fps/enemy-territory-etpro
@@ -79,6 +79,7 @@ games-action/hotline-miami
 games-action/intrusion2
 games-action/solar2
 games-action/swordandsworcery
+games-action/trine-enchanted-edition
 games-action/trine2
 games-arcade/dynamitejack
 games-arcade/thinktanks-demo
diff --git a/profiles/hardened/linux/amd64/no-multilib/package.mask b/profiles/hardened/linux/amd64/no-multilib/package.mask
index cd820bb9b97a..b820b2630d26 100644
--- a/profiles/hardened/linux/amd64/no-multilib/package.mask
+++ b/profiles/hardened/linux/amd64/no-multilib/package.mask
@@ -8,6 +8,7 @@ dev-lang/rebol-bin
 
 games-action/brutal-legend
 games-action/hotline-miami
+games-action/trine-enchanted-edition
 games-action/trine2
 games-action/swordandsworcery
 games-action/beathazardultra
diff --git a/profiles/updates/1Q-2018 b/profiles/updates/1Q-2018
index 9ef13e4e9496..fa4dd25f87d7 100644
--- a/profiles/updates/1Q-2018
+++ b/profiles/updates/1Q-2018
@@ -6,3 +6,4 @@ move app-admin/restart_services app-admin/restart-services
 move dev-libs/purpose kde-frameworks/purpose
 move kde-misc/plasma-applet-redshift-control kde-misc/plasma-redshift-control
 move x11-proto/xorgproto x11-base/xorg-proto
+move games-action/trine-bin games-action/trine