blob: ba126e401a7f104cfe8a74b71f3485c25055b0a3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools findlib toolchain-funcs
DESCRIPTION="Metrics plugin for frama-c"
HOMEPAGE="https://frama-c.com"
NAME="Vanadium"
SRC_URI="https://frama-c.com/download/frama-c-${PV}-${NAME}.tar.gz"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64"
IUSE="gtk +ocamlopt"
RESTRICT="strip"
RDEPEND="~sci-mathematics/frama-c-${PV}:=[gtk?,ocamlopt?]
~sci-mathematics/frama-c-eva-${PV}:=[gtk?,ocamlopt?]"
DEPEND="${RDEPEND}"
S="${WORKDIR}/frama-c-${PV}-${NAME}"
src_prepare() {
mv configure.in configure.ac || die
sed -i 's/configure\.in/configure.ac/g' Makefile.generating Makefile || die
touch config_file || die
eautoreconf
eapply_user
}
src_configure() {
econf \
--disable-landmarks \
--with-no-plugin \
$(use_enable gtk gui) \
--enable-metrics \
--enable-callgraph \
--enable-eva \
--enable-server
printf 'include share/Makefile.config\n' > src/plugins/metrics/Makefile || die
sed -e '/^# *Metrics/bl;d' -e ':l' -e '/^\$(eval/Q;n;bl' < Makefile >> src/plugins/metrics/Makefile || die
printf 'include share/Makefile.dynamic\n' >> src/plugins/metrics/Makefile || die
export FRAMAC_SHARE="${ESYSROOT}/usr/share/frama-c"
export FRAMAC_LIBDIR="${EPREFIX}/usr/$(get_libdir)/frama-c"
}
src_compile() {
tc-export AR
emake -f src/plugins/metrics/Makefile FRAMAC_SHARE="${FRAMAC_SHARE}" FRAMAC_LIBDIR="${FRAMAC_LIBDIR}"
}
src_install() {
emake -f src/plugins/metrics/Makefile FRAMAC_SHARE="${FRAMAC_SHARE}" FRAMAC_LIBDIR="${FRAMAC_LIBDIR}" DESTDIR="${ED}" install
}
|
GitWeb
