dev-scheme/cyclone/cyclone-9999.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

# Cyclone is a self-hosting Scheme to C compiler
# cyclone-bootstrap is the Cyclone SOURCE transpired by it to C

EAPI=7

inherit flag-o-matic

DESCRIPTION="Scheme R7RS to C compiler"
HOMEPAGE="http://justinethier.github.io/cyclone/"

if [[ "${PV}" == *9999* ]]; then
	inherit git-r3
	EGIT_REPO_URI="https://github.com/justinethier/${PN}-bootstrap.git"
else
	SRC_URI="https://github.com/justinethier/${PN}-bootstrap/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
	KEYWORDS="~amd64"
	S="${WORKDIR}/${PN}-bootstrap-${PV}"
fi

LICENSE="MIT"
SLOT="0"

DEPEND="
	dev-libs/concurrencykit
"
RDEPEND="
	${DEPEND}
"

src_configure() {
	append-cflags -fPIC -rdynamic -Iinclude
	append-ldflags -L. -Wl,--export-dynamic
	tc-export CC
}

src_test() {
	emake test LDFLAGS=""
}

src_install() {
	einstalldocs

	emake PREFIX="/usr" DESTDIR="${D}" install
}