gui-apps/aylurs-gtk-shell: fix dependencies

Closes: https://bugs.gentoo.org/933859
Signed-off-by: Lucio Sauer <watermanpaint@posteo.net>

3 files changed, 75 insertions, 63 deletions

diff --git a/gui-apps/aylurs-gtk-shell/aylurs-gtk-shell-1.8.2-r1.ebuild b/gui-apps/aylurs-gtk-shell/aylurs-gtk-shell-1.8.2-r1.ebuild
new file mode 100644
index 000000000..31984618d
--- /dev/null
+++ b/gui-apps/aylurs-gtk-shell/aylurs-gtk-shell-1.8.2-r1.ebuild
@@ -0,0 +1,75 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PV="v${PV}"
+MY_PN="ags"
+
+inherit meson optfeature
+
+DESCRIPTION="Aylurs's Gtk Shell (AGS), An eww inspired gtk widget system."
+HOMEPAGE="https://github.com/Aylur/ags"
+SRC_URI="
+	https://github.com/Aylur/${MY_PN}/releases/download/${MY_PV}/${MY_PN}-${MY_PV}.tar.gz -> ${P}.tar.gz
+	https://github.com/Aylur/${MY_PN}/releases/download/${MY_PV}/node_modules-${MY_PV}.tar.gz -> node-modules.tar.gz
+"
+S="${WORKDIR}/${MY_PN}"
+BUILD_DIR="${S}/build"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+
+# grep -rEo "gi://.*'" | cut -d : -f 1 --complement | sort -u
+COMMON_DEPEND="
+	>=dev-libs/gjs-1.73.1
+	>=dev-libs/glib-2.56.0:2
+	>=dev-libs/gobject-introspection-1.49.1
+	>=media-libs/libpulse-12.99.3[glib]
+	x11-libs/gtk+:3[introspection]
+	sys-libs/pam
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	gui-libs/gtk-layer-shell[introspection]
+	x11-libs/gdk-pixbuf[introspection]
+	x11-libs/pango[introspection]
+	=x11-libs/cairo-1*[glib]
+"
+# gjs-1.0.pc pulls in xorg-proto via cairo-xlib dep
+DEPEND="
+	${COMMON_DEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="
+	dev-lang/typescript
+	dev-libs/gobject-introspection
+	dev-util/glib-utils
+"
+
+src_prepare() {
+	default
+	mv "${WORKDIR}/node_modules" "${S}"
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dbuild_types="true"
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	elog "ags wont run without a config file (usually in ~/.config/ags)."
+	elog "For example configs visit https://aylur.github.io/ags-docs/"
+	optfeature "battery service" sys-power/upower
+	optfeature "bluetooth service" net-wireless/gnome-bluetooth:3[introspection]
+	optfeature "greetd service" gui-libs/greetd
+	optfeature "cover art caching (MPRIS service)" gnome-base/gvfs
+	optfeature "network service" net-misc/networkmanager[introspection]
+	optfeature "notifications service" x11-libs/libnotify[introspection]
+	optfeature "power profiles service" sys-power/power-profiles-daemon
+	optfeature "system tray service" dev-libs/libdbusmenu[gtk3,introspection]
+	optfeature "Utils.fetch feature" net-libs/libsoup:3.0[introspection]
+}
diff --git a/gui-apps/aylurs-gtk-shell/aylurs-gtk-shell-1.8.2.ebuild b/gui-apps/aylurs-gtk-shell/aylurs-gtk-shell-1.8.2.ebuild
deleted file mode 100644
index 51b26ac2b..000000000
--- a/gui-apps/aylurs-gtk-shell/aylurs-gtk-shell-1.8.2.ebuild
+++ /dev/null
@@ -1,60 +0,0 @@
-# Copyright 2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-MY_PV="v${PV}"
-MY_PN="ags"
-
-inherit meson
-
-DESCRIPTION="Aylurs's Gtk Shell (AGS), An eww inspired gtk widget system."
-HOMEPAGE="https://github.com/Aylur/ags"
-SRC_URI="
-	https://github.com/Aylur/${MY_PN}/releases/download/${MY_PV}/${MY_PN}-${MY_PV}.tar.gz -> ${P}.tar.gz
-	https://github.com/Aylur/${MY_PN}/releases/download/${MY_PV}/node_modules-${MY_PV}.tar.gz -> node-modules.tar.gz
-"
-S="${WORKDIR}/${MY_PN}"
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="~amd64"
-IUSE="upower bluetooth networkmanager tray"
-
-BDEPEND="
-	dev-lang/typescript
-	net-libs/nodejs[npm]
-"
-RDEPEND="
-	dev-libs/gjs
-	x11-libs/gtk+
-	gui-libs/gtk-layer-shell[introspection]
-	dev-libs/gobject-introspection
-	upower? ( sys-power/upower )
-	bluetooth? ( net-wireless/gnome-bluetooth )
-	networkmanager? ( net-misc/networkmanager )
-	tray? ( dev-libs/libdbusmenu[gtk3] )
-"
-
-DEPEND="
-	${RDEPEND}
-"
-
-BUILD_DIR="${S}/build"
-
-src_prepare() {
-	default
-	mv "${WORKDIR}/node_modules" "${S}"
-}
-
-src_configure() {
-	local emesonargs=(
-		-Dbuild_types="true"
-	)
-	meson_src_configure
-}
-
-pkg_postinst() {
-	elog "ags wont run without a config file (usually in ~/.config/ags)."
-	elog "For example configs visit https://aylur.github.io/ags-docs/"
-}
diff --git a/gui-apps/aylurs-gtk-shell/metadata.xml b/gui-apps/aylurs-gtk-shell/metadata.xml
index 2c3699583..b6d8f9861 100644
--- a/gui-apps/aylurs-gtk-shell/metadata.xml
+++ b/gui-apps/aylurs-gtk-shell/metadata.xml
@@ -5,9 +5,6 @@
 		<email>chinh4thepro@gmail.com</email>
 		<name>Vincent Phan</name>
 	</maintainer>
-	<use>
-		<flag name="tray">Enable support for tray</flag>
-	</use>
 	<upstream>
 		<remote-id type="github">Aylur/ags</remote-id>
 	</upstream>