x11-misc/xlockmore/xlockmore-5.18.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/xlockmore/xlockmore-5.18.ebuild,v 1.2 2005/06/14 03:56:29 smithj Exp $

inherit gnuconfig eutils pam

IUSE="nas esd motif opengl truetype gtk pam"

DESCRIPTION="Just another screensaver application for X"
SRC_URI="http://ftp.tux.org/pub/tux/bagleyd/${PN}/${P}.tar.bz2"
HOMEPAGE="http://www.tux.org/~bagleyd/xlockmore.html"

SLOT="0"
LICENSE="BSD"
KEYWORDS="~x86 ~sparc ~amd64 ~ppc ~ppc64"

DEPEND="virtual/x11
	media-libs/freetype
	opengl? ( virtual/opengl )
	pam? ( virtual/pam )
	nas? ( media-libs/nas )
	esd? ( media-sound/esound )
	motif? ( x11-libs/openmotif )
	gtk? ( =x11-libs/gtk+-1.2* )"

src_compile() {

	local myconf
	use pam || myconf="${myconf} --enable-xlockrc"

	use opengl || myconf="${myconf} --without-opengl --without-gltt --without-mesa"

	econf \
		--sharedstatedir=${D}/usr/share/xlockmore \
		--enable-vtlock \
		$(use_enable pam) \
		$(use_with truetype ttf) \
		$(use_with gtk) \
		$(use_with motif) \
		$(use_with esd esound) \
		$(use_with nas) \
		${myconf} \
		|| die "econf failed"

	emake || die "Make failed"

}

src_install() {
	einstall \
		xapploaddir=${D}/etc/X11/app-defaults \
		mandir=${D}/usr/share/man/man1 \
		|| die "einstall failed"

	#Install pam.d file and unset setuid root
	pamd_mimic_system xlock auth
	use pam && chmod 755 ${D}/usr/bin/xlock

	insinto /usr/share/xlockmore/sounds
	doins sounds/*

	dodoc docs/* README
	dohtml docs/*.html
	rm ${D}/usr/share/doc/${PF}/*.html.gz
}