sci-libs/indilib/indilib-0.7.2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/indilib/indilib-0.7.2.ebuild,v 1.6 2011/10/30 15:47:38 ssuominen Exp $

EAPI=3

MY_P="lib${PN/lib/}_${PV}"

inherit cmake-utils eutils

DESCRIPTION="INDI Astronomical Control Protocol library"
HOMEPAGE="http://indi.sourceforge.net/index.php/Main_Page"
SRC_URI="mirror://sourceforge/${PN/lib/}/${MY_P}.tar.gz"

LICENSE="LGPL-2"
SLOT="0"
KEYWORDS="amd64 ~hppa ppc ppc64 x86"
IUSE="fits nova usb v4l"

# libfli: not in portage
# fli? ( >=sci-libs/fli-1.71 )
RDEPEND="
	sys-libs/zlib
	fits? ( >=sci-libs/cfitsio-3.140 )
	nova? ( >=sci-libs/libnova-0.12.1 )
	usb? ( virtual/libusb:0 )
"
DEPEND="${RDEPEND}
	v4l? ( >=sys-kernel/linux-headers-2.6 )
"

PATCHES=(
	"${FILESDIR}/0.6.2-fix_fits_harddep.patch"
	"${FILESDIR}/0.6.2-fix_symlinks.patch"
	"${FILESDIR}/${PV}-fix_pkgconfig.patch"
	"${FILESDIR}/${PV}-fix_linking_pthread.patch"
)

S="${WORKDIR}/${MY_P/_/-}"

src_prepare() {
	base_src_prepare

	# fix multilib
	sed -i \
		-e "s:\${LIB_POSTFIX}:\${LIB_SUFFIX}:g" \
		CMakeLists.txt || die "sed failed"
}

src_configure() {
	mycmakeargs="${mycmakeargs}
		$(cmake-utils_use_with usb)
		$(cmake-utils_use_with fits CFITSIO)
		$(cmake-utils_use_with nova)
	"
	cmake-utils_src_configure
}