media-libs/libdts/libdts-0.0.2-r3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libdts/libdts-0.0.2-r3.ebuild,v 1.7 2005/10/31 15:58:11 flameeyes Exp $

inherit eutils autotools

DESCRIPTION="library for decoding DTS Coherent Acoustics streams used in DVD"
HOMEPAGE="http://www.videolan.org/dtsdec.html"
SRC_URI="http://www.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 sparc x86"
IUSE="oss debug"
RESTRICT="test"

RDEPEND="virtual/libc"
DEPEND="${RDEPEND}
	sys-devel/libtool
	=sys-devel/automake-1.7*
	>=sys-devel/autoconf-2.52d-r1"

src_unpack() {
	unpack ${A}
	if use ppc ; then
		# For some reason, ppc isn't properly using -fPIC... this
		# patch is broken, but makes it "work" on ppc.  If someone
		# will get me access, I'll fix it... --eradicator
		# Bug #98494
		epatch ${FILESDIR}/${P}-libtool2.patch
	else
		epatch ${FILESDIR}/${P}-libtool.patch
	fi
	epatch ${FILESDIR}/${P}-freebsd.patch

	cd ${S}
	eautoreconf
}

src_compile() {
	econf $(use_enable oss) $(use_enable debug)
	emake || die "emake failed"
}

src_install() {
	make DESTDIR="${D}" install || die
	dodoc AUTHORS ChangeLog NEWS README TODO doc/libdts.txt
}