lxde-base/lxsession/lxsession-0.4.9.2-r3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/lxde-base/lxsession/lxsession-0.4.9.2-r3.ebuild,v 1.2 2014/03/13 20:06:32 nullishzero Exp $

EAPI=5

VALA_MIN_API_VERSION="0.14"
VALA_MAX_API_VERSION="0.22"

inherit vala autotools eutils

DESCRIPTION="LXDE session manager (lite version)"
HOMEPAGE="http://lxde.sf.net/"
SRC_URI="mirror://sourceforge/lxde/${P}.tar.gz"

LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~arm ~ppc ~x86 ~arm-linux ~x86-linux"
SLOT="0"
# upower USE flag is enabled by default in the desktop profile
IUSE="nls upower"

COMMON_DEPEND="dev-libs/glib:2
	dev-libs/libgee:0
	dev-libs/dbus-glib
	lxde-base/lxde-common
	sys-auth/polkit
	x11-libs/gtk+:2
	x11-libs/libX11
	sys-apps/dbus"
RDEPEND="${COMMON_DEPEND}
	!lxde-base/lxsession-edit
	sys-apps/lsb-release
	upower? ( sys-power/upower )"
DEPEND="${COMMON_DEPEND}
	$(vala_depend)
	dev-util/intltool
	sys-devel/gettext
	virtual/pkgconfig
	x11-proto/xproto"

DOCS="AUTHORS ChangeLog README"

src_prepare() {
	# bug #488082
	epatch "${FILESDIR}"/${P}-makefile.patch

	# bug #497100
	epatch "${FILESDIR}"/${P}-configure.patch

	# bug #496880
	epatch "${FILESDIR}"/${P}-fix-logind-dbus-calls.patch

	eautoreconf
}

src_configure() {
	# dbus is used for restart/shutdown (CK, logind?), and suspend/hibernate (UPower)
	econf \
		$(use_enable nls)
}