dev-ruby/jeweler/jeweler-1.8.6.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ruby/jeweler/jeweler-1.8.6.ebuild,v 1.1 2013/07/17 07:18:33 graaff Exp $

EAPI=5
USE_RUBY="ruby18 ruby19"

RUBY_FAKEGEM_TASK_DOC="-Ilib yard"
RUBY_FAKEGEM_DOCDIR="doc"

# Tests and features also need the same set of dependencies present.
RUBY_FAKEGEM_TASK_TEST=""

RUBY_FAKEGEM_EXTRADOC="ChangeLog.markdown README.markdown"

RUBY_FAKEGEM_GEMSPEC="jeweler.gemspec"

inherit ruby-fakegem

DESCRIPTION="Rake tasks for managing gems and versioning and a generator for creating a new project"
HOMEPAGE="http://wiki.github.com/technicalpickles/jeweler"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
IUSE=""

ruby_add_bdepend "doc? ( dev-ruby/yard )"

ruby_add_rdepend "dev-ruby/bundler dev-ruby/nokogiri dev-ruby/highline dev-ruby/rdoc dev-ruby/builder dev-ruby/rake"

# We do not depend on all runtime dependencies since the usage of jeweler in
# Rakefile's does not require this. However, the generator does, but it
# depends on gems that are obsolete and not supported in Gentoo.

all_ruby_prepare() {
	# Remove bundler support.
	rm Gemfile || die
	sed -i -e '/bundler/d' -e '/Bundler.setup/d' Rakefile test/test_helper.rb features/support/env.rb || die

	# Remove (currently) unused targets from the Rakefile that require
	# additional dependencies.
	sed -i -e '/rcov/,$d' Rakefile || die

	# Remove a runtime dependency that we can't satisfy.
	sed -i -e '/github_api/d' jeweler.gemspec || die
}