dev-ml/pomap/pomap-2.9.8.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ml/pomap/pomap-2.9.8.ebuild,v 1.4 2009/06/21 12:51:47 aballier Exp $

EAPI="1"

inherit findlib eutils

DESCRIPTION="Partially Ordered Map ADT for O'Caml"
HOMEPAGE="http://www.ocaml.info/home/ocaml_sources.html"
LICENSE="LGPL-2.1"
RDEPEND=">=dev-lang/ocaml-3.06"
DEPEND="${RDEPEND}"
SRC_URI="http://www.ocaml.info/ocaml_sources/${P}.tar.bz2"

SLOT="0"
KEYWORDS="amd64 ppc x86"
IUSE="examples +ocamlopt"

pkg_setup() {
	if use ocamlopt && ! built_with_use --missing true dev-lang/ocaml ocamlopt; then
		eerror "In order to build ${PN} with native code support from ocaml"
		eerror "You first need to have a native code ocaml compiler."
		eerror "You need to install dev-lang/ocaml with ocamlopt useflag on."
		die "Please install ocaml with ocamlopt useflag"
	fi
}

src_compile() {
	cd "${S}/lib"
	emake -j1 byte-code-library || die "failed to build byte code library"
	if use ocamlopt; then
		emake -j1 native-code-library || die "failed to built nativde code library"
	fi
}

src_install () {
	use ocamlopt || export OCAMLFIND_INSTFLAGS="-optional"
	findlib_src_install

	# install documentation
	dodoc README VERSION Changes

	#install examples
	if use examples; then
		insinto /usr/share/doc/${PF}
		doins -r examples
	fi
}