dev-lua/luaexpat/luaexpat-1.3.0-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lua/luaexpat/luaexpat-1.3.0-r1.ebuild,v 1.1 2014/06/15 13:38:03 mgorny Exp $

EAPI=5

inherit multilib toolchain-funcs flag-o-matic eutils multilib-minimal

DESCRIPTION="LuaExpat is a SAX XML parser based on the Expat library"
HOMEPAGE="http://www.keplerproject.org/luaexpat/"
SRC_URI="http://matthewwild.co.uk/projects/${PN}/${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE=""

RDEPEND=">=dev-lang/lua-5.1[deprecated,${MULTILIB_USEDEP}]
	dev-libs/expat[${MULTILIB_USEDEP}]"
DEPEND="${RDEPEND}
	virtual/pkgconfig[${MULTILIB_USEDEP}]"

src_prepare() {
	multilib_copy_sources

	append-flags -fPIC
}

multilib_src_compile() {
	emake \
		CFLAGS="${CFLAGS}" \
		LDFLAGS="${LDFLAGS}" \
		CC="$(tc-getCC)" \
		LD="$(tc-getCC) -shared" \
		LUA_LDIR="$($(tc-getPKG_CONFIG) --variable INSTALL_LMOD lua)" \
		LUA_CDIR="$($(tc-getPKG_CONFIG) --variable INSTALL_CMOD lua)" \
		LUA_INC="-I$($(tc-getPKG_CONFIG) --variable INSTALL_INC lua)"
}

multilib_src_install() {
	emake \
		DESTDIR="${D}" \
		LUA_LDIR="$($(tc-getPKG_CONFIG) --variable INSTALL_LMOD lua)" \
		LUA_CDIR="$($(tc-getPKG_CONFIG) --variable INSTALL_CMOD lua)" \
		LUA_INC="-I$($(tc-getPKG_CONFIG) --variable INSTALL_INC lua)" \
		install
}

multilib_src_install_all() {
	dodoc README
	dohtml -r doc/*
}