1 files changed, 47 insertions, 0 deletions
diff --git a/net-misc/sslh/sslh-1.13-r1.ebuild b/net-misc/sslh/sslh-1.13-r1.ebuild
new file mode 100644
index 000000000000..baefb1889aba
--- /dev/null
+++ b/net-misc/sslh/sslh-1.13-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/sslh/sslh-1.13-r1.ebuild,v 1.1 2012/07/11 15:47:57 kensington Exp $
+
+EAPI=4
+
+inherit toolchain-funcs
+
+DESCRIPTION="SSLH lets one accept both HTTPS and SSH connections on the same port"
+HOMEPAGE="http://www.rutschle.net/tech/sslh.shtml"
+SRC_URI="http://www.rutschle.net/tech/${P}b.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="tcpd"
+
+RDEPEND="tcpd? ( sys-apps/tcp-wrappers )
+	dev-libs/libconfig"
+DEPEND="${RDEPEND}
+	dev-lang/perl"
+
+RESTRICT="test"
+
+src_prepare() {
+	sed -i \
+		-e '/strip sslh/d' \
+		-e '/^LIBS=/s:$: $(LDFLAGS):' \
+		-e '/^CFLAGS=/d' \
+		Makefile || die
+}
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)" \
+		USELIBWRAP=$(usev tcpd)
+}
+
+src_install() {
+	dobin sslh-{fork,select}
+	dosym sslh-fork /usr/bin/sslh
+	doman sslh.8.gz
+	dodoc ChangeLog README
+
+	newinitd "${FILESDIR}"/sslh.init.d-2 sslh
+	newconfd "${FILESDIR}"/sslh.conf.d-2 sslh
+}