1 files changed, 64 insertions, 0 deletions
diff --git a/games-roguelike/scourge/scourge-0.15.ebuild b/games-roguelike/scourge/scourge-0.15.ebuild
new file mode 100644
index 000000000000..c8eb052fbaa5
--- /dev/null
+++ b/games-roguelike/scourge/scourge-0.15.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-roguelike/scourge/scourge-0.15.ebuild,v 1.1 2006/09/29 18:15:03 nyhm Exp $
+
+inherit eutils wxwidgets games
+
+DESCRIPTION="A rogue-like adventure game to eliminate pests"
+HOMEPAGE="http://scourge.sourceforge.net/"
+SRC_URI="mirror://sourceforge/scourge/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="editor"
+
+DEPEND="x11-libs/libXmu
+	x11-libs/libXi
+	virtual/glu
+	virtual/opengl
+	>=media-libs/freetype-2
+	>=media-libs/libsdl-1.2
+	media-libs/sdl-net
+	media-libs/sdl-mixer
+	editor? ( >=x11-libs/wxGTK-2.6 )"
+
+S=${WORKDIR}/${P}/${PN}
+
+pkg_setup() {
+	games_pkg_setup
+	if use editor ; then
+		WX_GTK_VER="2.6" need-wxwidgets gtk2 \
+		|| die "You need to emerge wxGTK with USE='X'"
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	if use editor ; then
+		sed -i \
+			-e "/WXWIDGET_CFLAGS/s:wx-config:${WX_CONFIG}:" \
+			-e "/WXWIDGET_LIBS/s:wx-config:${WX_CONFIG}:" \
+			configure || die "sed failed"
+	fi
+}
+
+src_compile() {
+	egamesconf \
+		--with-data-dir="${GAMES_DATADIR}/${PN}" \
+		$(use_enable editor) \
+		|| die
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	use editor && mv "${D}/${GAMES_BINDIR}"/{tools,${PN}-tools}
+	insinto "${GAMES_DATADIR}/${PN}"
+	doins -r ../scourge_data/* || die "doins failed"
+	doicon assets/scourge.png
+	make_desktop_entry scourge Scourge
+	dodoc AUTHORS README
+	prepgamesdirs
+}