Version bump wrt security #411493 (Graphics Renderer and XBM Decoder Vulnerabilities). Missing %u in Exec= line to pass links to links -g, see http://standards.freedesktop.org/desktop-entry-spec/desktop-entry-spec-latest.html#exec-variables. USE="deprecated" as first step to get rid of the deprecated links2 compability symlink which is enabled by default for now.

Package-Manager: portage-2.2.0_alpha99/cvs/Linux x86_64

4 files changed, 144 insertions, 10 deletions

diff --git a/www-client/links/ChangeLog b/www-client/links/ChangeLog
index 7447a2f8476f..f1e5df298784 100644
--- a/www-client/links/ChangeLog
+++ b/www-client/links/ChangeLog
@@ -1,6 +1,16 @@
 # ChangeLog for www-client/links
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/links/ChangeLog,v 1.165 2012/04/06 20:34:22 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/links/ChangeLog,v 1.166 2012/04/10 19:44:04 ssuominen Exp $
+
+*links-2.6 (10 Apr 2012)
+
+  10 Apr 2012; Samuli Suominen <ssuominen@gentoo.org> +links-2.6.ebuild,
+  metadata.xml:
+  Version bump wrt security #411493 (Graphics Renderer and XBM Decoder
+  Vulnerabilities). Missing %u in Exec= line to pass links to links -g, see
+  http://standards.freedesktop.org/desktop-entry-spec/desktop-entry-spec-latest
+  .html#exec-variables. USE="deprecated" as first step to get rid of the
+  deprecated links2 compability symlink which is enabled by default for now.
 
   06 Apr 2012; Samuli Suominen <ssuominen@gentoo.org> links-2.5.ebuild:
   Only apply x-scheme-handler/https; to MimeType -line of the desktop file when
diff --git a/www-client/links/Manifest b/www-client/links/Manifest
index e954c9d34b69..5580aeb52444 100644
--- a/www-client/links/Manifest
+++ b/www-client/links/Manifest
@@ -2,18 +2,20 @@
 Hash: SHA1
 
 DIST links-2.5.tar.bz2 3849259 RMD160 ec0c2fbf239289d757fd12526495bdcb3c08a588 SHA1 fe4bc37be8aebd9196c35ffef724435cea94349c SHA256 f5c7f23f31d71d073b7b6ad2f123f3f93b07b787912b7b01b4fff565349295f2
+DIST links-2.6.tar.bz2 3866614 RMD160 ea13e446903fbeaa8b05b3aa81dcfe5f69224962 SHA1 228bd726c176ea44d35fa12cafd97aa83214d9dc SHA256 df9149f5f50d0b7742f6b3972b0fc0e9ff091ad4ef27153a3362a9ac1033835b
 DIST links2_2.5-1.debian.tar.gz 20869 RMD160 997338fd263a9519f105d24ced17caba65181caf SHA1 82a2f23c12dca937c29e8f4cd83b7527a7e374e8 SHA256 28fb3fe213b3ba2a2274353a810bcd23d4fd39d949d8cb608c3a366f09651b7e
 EBUILD links-2.5.ebuild 3352 RMD160 e5a88418045af2f898b0e0bc8edc8fe16d133d90 SHA1 4dde689c120577388b94be32a171756bfe1a33de SHA256 211ff99c3ca734e46362ad747ddcdc5cc646dfe65438e150aafdad1b1b9a3fcc
-MISC ChangeLog 32324 RMD160 f4519feda338e6fdcb17ae3da36a2f5280ff3d1f SHA1 9a75a713ad25d1508717bd35b8cfa4fb9f95b472 SHA256 4f5cf6817f5d884f1bcc4567b1fe725079500c0e26ee31704cd86955eac0a975
-MISC metadata.xml 342 RMD160 f48da44e2ff7ef33505a66744713dde872654bf5 SHA1 09f4631fef863d70a152eec29c2455243413c9ee SHA256 264e605d3878a9b815b642d43c413afd628f1945e9a875fc31eaf7e2cef0a085
+EBUILD links-2.6.ebuild 3146 RMD160 dcefcc74fb31272d11abcb9c931eb57bf3308642 SHA1 32ae747cdbb230b57a70c21a33fd49ee89d9e33c SHA256 2ba08c90ea33114a49c81c07d8709c3646321ba8ec8782578b841522b854ff10
+MISC ChangeLog 32817 RMD160 76cfc43e82660e02afc14a7668456677b558de6e SHA1 6015be90213a317702c5f84b8a7a9147d8e60080 SHA256 aa77d94839a736412f669da116311a8d1f79e089502a9ddc07b7b0c2ec20aace
+MISC metadata.xml 475 RMD160 8089a45a24128919ea9045afeab78b7f2142224f SHA1 1f7e54ea9eaf0ba842701c75e96ae0d045e42f5e SHA256 47cdac116651eba8a04d0e7a0560d5013bc967ce3aa2d86f61ee8688649a3916
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.19 (GNU/Linux)
 
-iQEcBAEBAgAGBQJPf1MwAAoJEEdUh39IaPFNL/8IAIJPfx+t8HF2yX0rGv0seJ1k
-gHOhgiSrdqfGDR/ao8wAcu6Kouj9G4z0GeRCMmA+kCJ6n4qqW+gndlhtNKbMh9x4
-eCS13/5fG4QLPXr58ktGbXpRpFQ2yz4igPkvBw6cGGKnBzzCfHACEVsBjI6vO7RV
-ENMlIosPRZGi110FhWiEo/CnSEAcBsdyqYWB2KRjpqeO3+QvBxsF6JUrOCCfOiEZ
-fe+uci9k6u1ZUfNFhSMK7k+KMz3tl3e7emgE8xrn5ojdFFXd9b5gwIKavpCyA53J
-5UWNDiJmNS/EaLQY6TPEe9Jxackou18S5ZPQaqvvT9VSDX2VX9+m7iFqoFmftJQ=
-=ToMD
+iQEcBAEBAgAGBQJPhI1XAAoJEEdUh39IaPFNrEgIAJkfyf6k9zV2pumJujZiddOQ
+ADkk0SMkGsSxih4ja3weq96dNB7MYkK537ySbAFBHuKujvbej2PW6uxHjBDEsMrH
+g0T5o0LZwKOM5kUZmI/v9wTVTSoxg9LgbiYayPkqaT4Bz70vf0f48e1WtpQQUPIO
+got+AzqDTdMil5wewE9lcFyP38Bn2ocBeyy71if0bOu4CMUf45aGbCZgkXew0QZZ
+22bD8ZBQPzwY0+YtFDwlqSuSTI3I2qHjtVAdWNAoZTmkRvA/EJGHAVEgLWamSVT5
+U+7OyV37JWSxWYO01aEashYtMijq4iJQ/jz80XKZzlouQuPweCJYY1RUl7Y9h8E=
+=oaeM
 -----END PGP SIGNATURE-----
diff --git a/www-client/links/links-2.6.ebuild b/www-client/links/links-2.6.ebuild
new file mode 100644
index 000000000000..dcdd4086ffbd
--- /dev/null
+++ b/www-client/links/links-2.6.ebuild
@@ -0,0 +1,119 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/links/links-2.6.ebuild,v 1.1 2012/04/10 19:44:04 ssuominen Exp $
+
+EAPI=4
+inherit autotools eutils fdo-mime
+
+DESCRIPTION="A fast and lightweight web browser running in both graphics and text mode"
+HOMEPAGE="http://links.twibright.com/"
+SRC_URI="http://${PN}.twibright.com/download/${P}.tar.bz2
+	mirror://debian/pool/main/${PN:0:1}/${PN}2/${PN}2_2.5-1.debian.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~x86-fbsd ~ia64-hpux ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="bzip2 +deprecated directfb fbcon gpm jpeg livecd lzma ssl suid svga tiff unicode X zlib"
+
+GRAPHICS_DEPEND=">=media-libs/libpng-1.2:0" #75685
+
+RDEPEND=">=sys-libs/ncurses-5.7-r7
+	bzip2? ( app-arch/bzip2 )
+	directfb? ( dev-libs/DirectFB )
+	fbcon? ( ${GRAPHICS_DEPEND} )
+	gpm? ( sys-libs/gpm )
+	jpeg? ( virtual/jpeg )
+	livecd? ( ${GRAPHICS_DEPEND} )
+	lzma? ( app-arch/xz-utils )
+	ssl? ( dev-libs/openssl:0 )
+	svga? (
+		${GRAPHICS_DEPEND}
+		>=media-libs/svgalib-1.4.3
+		)
+	tiff? ( media-libs/tiff:0 )
+	X? (
+		${GRAPHICS_DEPEND}
+		x11-libs/libXext
+		)
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+GRAPHICS_USE="jpeg gpm"
+
+REQUIRED_USE="fbcon? ( ${GRAPHICS_USE} )
+	livecd? ( ${GRAPHICS_USE} )
+	svga? ( suid )"
+
+DOCS=( AUTHORS BRAILLE_HOWTO ChangeLog KEYS NEWS README SITES )
+
+src_prepare() {
+	epatch "${WORKDIR}"/debian/patches/verify-ssl-certs-510417.diff
+
+	if use unicode; then
+		pushd intl >/dev/null
+		./gen-intl || die
+		./synclang || die
+		popd >/dev/null
+	fi
+
+	# error: conditional "am__fastdepCXX" was never defined (for eautoreconf)
+	sed -i -e '/AC_PROG_CXX/s:#::' configure.in || die
+
+	# Upstream configure produced by broken autoconf-2.13. This also fixes 
+	# toolchain detection.
+	eautoreconf #131440 and #103483#c23
+}
+
+src_configure() {
+	export ac_cv_lib_gpm_Gpm_Open=$(usex gpm)
+
+	local myconf
+
+	if use X || use fbcon || use directfb || use svga || use livecd; then
+		myconf+=' --enable-graphics'
+	fi
+
+	if use fbcon || use livecd; then
+		myconf+=' --with-fb'
+	else
+		myconf+=' --without-fb'
+	fi
+
+	econf \
+		$(use_with ssl) \
+		$(use_with zlib) \
+		$(use_with bzip2) \
+		$(use_with lzma) \
+		$(use_with svga svgalib) \
+		$(use_with X x) \
+		$(use_with directfb) \
+		$(use_with jpeg libjpeg) \
+		$(use_with tiff libtiff) \
+		${myconf}
+}
+
+src_install() {
+	default
+
+	if use X; then
+		newicon Links_logo.png links.png
+		make_desktop_entry 'links -g %u' Links links 'Network;WebBrowser'
+		local d="${ED}"/usr/share/applications
+		echo 'MimeType=x-scheme-handler/http;' >> "${d}"/*.desktop
+		use ssl && sed -i -e 's:x-scheme-handler/http;:&x-scheme-handler/https;:' \
+			"${d}"/*.desktop
+	fi
+
+	nonfatal dohtml doc/links_cal/*
+	use deprecated && dosym links /usr/bin/links2
+	use suid && fperms 4755 /usr/bin/links
+}
+
+pkg_postinst() {
+	use X && fdo-mime_desktop_database_update
+}
+
+pkg_postrm() {
+	use X && fdo-mime_desktop_database_update
+}
diff --git a/www-client/links/metadata.xml b/www-client/links/metadata.xml
index 29e773eb58b1..c7d4d84cd646 100644
--- a/www-client/links/metadata.xml
+++ b/www-client/links/metadata.xml
@@ -9,4 +9,7 @@
     <email>ssuominen@gentoo.org</email>
     <name>Samuli Suominen</name>
   </maintainer>
+  <use>
+    <flag name='deprecated'>Install deprecated 'links2 -> links' symlink for compability reasons temporarily</flag>
+  </use>
 </pkgmetadata>