sys-kernel/dracut: Rev-bump to 010-r2. Missing net-misc/ifenslave rdep fix.

Package-Manager: portage-2.1.10/cvs/Linux x86_64

3 files changed, 228 insertions, 9 deletions

diff --git a/sys-kernel/dracut/ChangeLog b/sys-kernel/dracut/ChangeLog
index 4e8796527e92..ba2b566128b9 100644
--- a/sys-kernel/dracut/ChangeLog
+++ b/sys-kernel/dracut/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-kernel/dracut
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/ChangeLog,v 1.22 2011/04/01 22:54:36 aidecoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/ChangeLog,v 1.23 2011/06/07 20:16:01 aidecoe Exp $
+
+*dracut-010-r2 (07 Jun 2011)
+
+  07 Jun 2011; Amadeusz Żołnowski <aidecoe@gentoo.org> +dracut-010-r2.ebuild:
+  Added missing net-misc/ifenslave runtime dependency.
 
 *dracut-010-r1 (01 Apr 2011)
 
diff --git a/sys-kernel/dracut/Manifest b/sys-kernel/dracut/Manifest
index 0d0e2aea91a9..5eac56e665aa 100644
--- a/sys-kernel/dracut/Manifest
+++ b/sys-kernel/dracut/Manifest
@@ -19,17 +19,18 @@ EBUILD dracut-008-r1.ebuild 5832 RMD160 5a5f978f28be2cdef5f6df5782d623b25a417123
 EBUILD dracut-008.ebuild 5745 RMD160 194d7b14c84d8411d49235a4359d6d2c6193cce6 SHA1 5346f7e5be40e78d57ec0dc2e0dcb326172a11ab SHA256 bd308a8caddf8737455439383931dd7275384e8814599a63c9eb76a0a165aa5f
 EBUILD dracut-009-r1.ebuild 5912 RMD160 6d0ca0bb0989d42700ecec4b2fea91be914861ff SHA1 121a9ea5bc03967b149b734db9de945c6213ca1c SHA256 620196708d1c6df83de5a433354c3c34062e031f9d06dba56887441b40b800a4
 EBUILD dracut-010-r1.ebuild 5897 RMD160 321f42b0fede142fe0743ce45df85e59a9470ae0 SHA1 9b4e023c2f5b59867250ae0f722f41e78248e68c SHA256 7227408b0dda7cccf552183c1ce92c194ac59d32cfbc9df97edc615fc895e4d6
+EBUILD dracut-010-r2.ebuild 5915 RMD160 712f773fbb37a04d2930aa09fdb2d977e58d8da0 SHA1 f64ca6dcf86655d6a288170b6503cb3fbd943313 SHA256 c9b61dca985fc8feccee2d2c729cb8a93854ea7f570215c5fcd8c6a3015fc4aa
 EBUILD dracut-010.ebuild 5838 RMD160 c96e3ef348086252d566d65228296df54745439a SHA1 c4c19cc7e0ac4e273b0446e8d6829cfde518d2f0 SHA256 4e54f06a6afabc593d225dec8c54271c195f9353bca40fe5913bec1f82cb8517
-MISC ChangeLog 6948 RMD160 aeb96c7db16a9e4f9c0dc3f155eee85d23897d3d SHA1 735fba03de3c075eabbdcab1fd7f79167e14645d SHA256 df0cb7d95304b40b038d29cec5ebc43c59eb966302db15b7f1c07e7e5fb238e3
+MISC ChangeLog 7114 RMD160 6708267c741f24656dfd986d294ac61a1f916b2a SHA1 377f262b25055da5914fb19405f720e42e62af46 SHA256 c062e0b3dd047c01e9e96f56314d906d30c70d8b10af658f2286fc281b8a3a48
 MISC metadata.xml 1725 RMD160 b297eb03e09381e2b03d98b37755c56f5ebe546d SHA1 145aef995db3cc66ead45189d722c7939c6d0ed7 SHA256 4a4acf6ddbe7fe41200c9bab075f677d46848b09f680a2eab05921a29455316f
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.17 (GNU/Linux)
 
-iQEcBAEBAgAGBQJN21KMAAoJEPATRTHh2/q1OXQH/2iu76Vq+FfBXTIq8TwR89Yt
-spoa+Bqk5/gVjoig+AnW2jjqcJNEDNtFiz5kFSLBTSLeBkTkvL2pl0YYzTBld/rD
-WIzdzvxcB/Xvv+Zvu3M4rDwmzm3QQRVZ0vnJ5QwEvB44pKARogoTBHcOM3E+iFu/
-aOxw4pFfgryOhrbEYOfXdKq0pE0GCyvdiRXBMaKv4pQ279RrnyuJj9NrzFnMtHwD
-NjJYOmUKwfSRMCjmWjCRuw3cmccc4vwqOEiCXsGJZI+7uQ6TyOMWA/M3Jecx5O89
-km7BgWSGxkoBxTDXnZCbNqFUD+iU0s6fw0Pwb//q4ZIjPSMyn2GVF4uo79G5R68=
-=GagN
+iQEcBAEBAgAGBQJN7ocGAAoJEPATRTHh2/q16TMH/3JnPzyLTZjjecLgbJM0VY92
+s22pPdhJVxpFHth7yqc6JMoZJkfYI70r76ETHgfomSQjZ0JjceG3C5Q37nFWUPBp
+YZ97h/zjwk9OgO4iZMox8eINfRvqPHDmwxbgu6nduJK9HvroVbYkTWm9Kx7Dc/+R
+WT9HWo9lFb3gbcFSlYgCGhoxO+UFLypY7sbnLwj3h0RktmnJwUzEqlwE68xe8HpC
+nhpCbTjgeuR1+9WTX9IourYzXUJQIkd610PuZZ8ZjGdb7iWoVjlgZDfKaRJ4t1dg
+yjuBHXil7Kxx358azVsQfjDDiqWEQjKaRN143vDNsvCLP5uaQkWrvb6VUpAtcbA=
+=c1S9
 -----END PGP SIGNATURE-----
diff --git a/sys-kernel/dracut/dracut-010-r2.ebuild b/sys-kernel/dracut/dracut-010-r2.ebuild
new file mode 100644
index 000000000000..9619d6f6b330
--- /dev/null
+++ b/sys-kernel/dracut/dracut-010-r2.ebuild
@@ -0,0 +1,213 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/dracut-010-r2.ebuild,v 1.1 2011/06/07 20:16:01 aidecoe Exp $
+
+EAPI=2
+
+inherit eutils
+
+DESCRIPTION="Generic initramfs generation tool"
+HOMEPAGE="http://dracut.wiki.kernel.org"
+SRC_URI="mirror://kernel/linux/utils/boot/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~x86 ~amd64"
+
+COMMON_MODULES="
+	dracut_modules_biosdevname
+	dracut_modules_btrfs
+	dracut_modules_caps
+	dracut_modules_gensplash
+	dracut_modules_mdraid
+	dracut_modules_multipath
+	dracut_modules_plymouth
+	dracut_modules_syslog
+	dracut_modules_xen
+	"
+NETWORK_MODULES="
+	dracut_modules_iscsi
+	dracut_modules_nbd
+	dracut_modules_nfs
+	"
+DM_MODULES="
+	dracut_modules_crypt
+	dracut_modules_dmraid
+	dracut_modules_dmsquash-live
+	dracut_modules_lvm
+	"
+IUSE_DRACUT_MODULES="${COMMON_MODULES} ${DM_MODULES} ${NETWORK_MODULES}"
+IUSE="debug selinux ${IUSE_DRACUT_MODULES}"
+
+NETWORK_DEPS="net-misc/bridge-utils >=net-misc/dhcp-4.2.1-r1 sys-apps/iproute2
+	net-misc/ifenslave"
+DM_DEPS="|| ( sys-fs/device-mapper >=sys-fs/lvm2-2.02.33 )"
+
+RDEPEND="
+	>=app-shells/bash-4.0
+	>=app-shells/dash-0.5.4.11
+	>=sys-apps/baselayout-1.12.14-r1
+	>=sys-apps/module-init-tools-3.5
+	>=sys-apps/sysvinit-2.87-r3
+	>=sys-apps/util-linux-2.16
+	>=sys-fs/udev-149
+
+	debug? ( dev-util/strace )
+	selinux? ( sys-libs/libselinux sys-libs/libsepol )
+	dracut_modules_biosdevname? ( sys-apps/biosdevname )
+	dracut_modules_btrfs? ( sys-fs/btrfs-progs )
+	dracut_modules_caps? ( sys-libs/libcap )
+	dracut_modules_crypt? ( sys-fs/cryptsetup ${DM_DEPS} )
+	dracut_modules_dmraid? ( sys-fs/dmraid sys-fs/multipath-tools ${DM_DEPS} )
+	dracut_modules_dmsquash-live? ( virtual/eject ${DM_DEPS} )
+	dracut_modules_gensplash? ( media-gfx/splashutils )
+	dracut_modules_iscsi? ( >=sys-block/open-iscsi-2.0.871.3 ${NETWORK_DEPS} )
+	dracut_modules_lvm? ( >=sys-fs/lvm2-2.02.33 )
+	dracut_modules_mdraid? ( sys-fs/mdadm )
+	dracut_modules_multipath? ( sys-fs/multipath-tools )
+	dracut_modules_nbd? ( sys-block/nbd ${NETWORK_DEPS} )
+	dracut_modules_nfs? ( net-fs/nfs-utils net-nds/rpcbind ${NETWORK_DEPS} )
+	dracut_modules_plymouth? ( >=sys-boot/plymouth-0.8.3-r1 )
+	dracut_modules_syslog? ( || ( app-admin/syslog-ng app-admin/rsyslog ) )
+	dracut_modules_xen? ( app-emulation/xen )
+	"
+DEPEND="
+	>=dev-libs/libxslt-1.1.26
+	app-text/docbook-xml-dtd:4.5
+	>=app-text/docbook-xsl-stylesheets-1.75.2
+	"
+
+#
+# Helper functions
+#
+
+# Returns true if any of specified modules is enabled by USE flag and false
+# otherwise.
+# $1 = list of modules (which have corresponding USE flags of the same name)
+any_module() {
+	local m modules=" $@ "
+
+	for m in ${modules}; do
+		! use $m && modules=${modules/ $m / }
+	done
+
+	shopt -s extglob
+	modules=${modules%%+( )}
+	shopt -u extglob
+
+	[[ ${modules} ]]
+}
+
+# Removes module from modules.d.
+# $1 = module name
+# Module name can be specified without number prefix.
+rm_module() {
+	local m
+
+	for m in $@; do
+		if [[ $m =~ ^[0-9][0-9][^\ ]*$ ]]; then
+			rm -rf "${modules_dir}"/$m
+		else
+			rm -rf "${modules_dir}"/[0-9][0-9]$m
+		fi
+	done
+}
+
+# Displays Gentoo Base System major release number
+base_sys_maj_ver() {
+	local line
+
+	read line < /etc/gentoo-release
+	line=${line##* }
+	echo "${line%%.*}"
+}
+
+#
+# ebuild functions
+#
+
+src_prepare() {
+	epatch "${FILESDIR}/${P}-multipath-udev-rules.patch"
+	epatch "${FILESDIR}/${P}-empty-etc-ld.so.conf.d.patch"
+}
+
+src_compile() {
+	emake WITH_SWITCH_ROOT=0 || die "emake failed"
+}
+
+src_install() {
+	emake WITH_SWITCH_ROOT=0 \
+		prefix=/usr sysconfdir=/etc DESTDIR="${D}" \
+		install || die "emake install failed"
+
+	local gen2conf
+
+	dodir /var/lib/dracut/overlay
+	dodoc HACKING TODO AUTHORS NEWS README* || die 'dodoc failed'
+
+	case "$(base_sys_maj_ver)" in
+		1) gen2conf=gentoo.conf ;;
+		2) gen2conf=gentoo-openrc.conf ;;
+		*) die "Expected ver. 1 or 2 of Gentoo Base System (/etc/gentoo-release)."
+	esac
+
+	insinto /etc/dracut.conf.d
+	newins dracut.conf.d/${gen2conf}.example ${gen2conf} \
+		|| die 'gen2conf ins failed'
+
+	insinto /etc/logrotate.d
+	newins dracut.logrotate dracut || die 'dracut.logrotate ins failed'
+
+	#
+	# Modules
+	#
+	local module
+	modules_dir="${D}/usr/share/dracut/modules.d"
+
+	echo "${PF}" > "${modules_dir}"/10rpmversion/dracut-version \
+		|| die 'dracut-version failed'
+
+	# Remove modules not enabled by USE flags
+	for module in ${IUSE_DRACUT_MODULES} ; do
+		! use ${module} && rm_module ${module#dracut_modules_}
+	done
+
+	# Those flags are specific, and even are corresponding to modules, they need
+	# to be declared as regular USE flags.
+	use debug || rm_module 95debug
+	use selinux || rm_module 98selinux
+
+	! any_module ${DM_MODULES} && rm_module 90dm
+	! any_module ${NETWORK_MODULES} && rm_module 45ifcfg 40network
+
+	# Remove S/390 modules which are not tested at all
+	rm_module 95dasd 95dasd_mod 95zfcp 95znet
+
+	# Remove modules which won't work for sure
+	rm_module 00bootchart 05busybox # broken
+	rm_module 95fcoe # no tools
+
+	# fips module depends on masked app-crypt/hmaccalc
+	rm_module 01fips
+}
+
+pkg_postinst() {
+	elog 'To generate the initramfs:'
+	elog '    # mount /boot (if necessary)'
+	elog '    # dracut "" <kernel-version>'
+	elog ''
+	elog 'For command line documentation see dracut.kernel(7).'
+	elog ''
+	elog 'Simple example to select root and resume partition:'
+	elog '    root=/dev/sda1 resume=/dev/sda2'
+	elog ''
+	elog 'The default config (in /etc/dracut.conf) is very minimal and is highly'
+	elog 'recommended you adjust based on your needs. To include only dracut'
+	elog 'modules and kernel drivers for this system, use the "-H" option.'
+	elog 'Some modules need to be explicitly added with "-a" option even if'
+	elog 'required tools are installed.'
+	echo
+	elog 'Options (documented in dracut.kernel(7)) have new format since'
+	elog 'version 008. Old format is preserved, but will be removed in future.'
+	elog 'Please migrate to the new one.'
+}