Version Bump

Package-Manager: portage-2.2.0_alpha89/cvs/Linux x86_64

5 files changed, 187 insertions, 4 deletions

diff --git a/sci-chemistry/burrow-owl/ChangeLog b/sci-chemistry/burrow-owl/ChangeLog
index 39655e33fbac..ef6ef0946133 100644
--- a/sci-chemistry/burrow-owl/ChangeLog
+++ b/sci-chemistry/burrow-owl/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sci-chemistry/burrow-owl
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/burrow-owl/ChangeLog,v 1.5 2012/02/14 19:58:49 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/burrow-owl/ChangeLog,v 1.6 2012/02/27 22:50:44 jlec Exp $
+
+*burrow-owl-1.5.1 (27 Feb 2012)
+
+  27 Feb 2012; Justin Lecher <jlec@gentoo.org> +burrow-owl-1.5.1.ebuild:
+  Version Bump
 
 *burrow-owl-1.5 (14 Feb 2012)
 
diff --git a/sci-chemistry/burrow-owl/burrow-owl-1.5.1.ebuild b/sci-chemistry/burrow-owl/burrow-owl-1.5.1.ebuild
new file mode 100644
index 000000000000..9021afe8e3f8
--- /dev/null
+++ b/sci-chemistry/burrow-owl/burrow-owl-1.5.1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/burrow-owl/burrow-owl-1.5.1.ebuild,v 1.1 2012/02/27 22:50:44 jlec Exp $
+
+EAPI=4
+
+inherit autotools-utils
+
+DESCRIPTION="Visualize multidimensional nuclear magnetic resonance (NMR) spectra"
+HOMEPAGE="http://burrow-owl.sourceforge.net/"
+SRC_URI="
+	mirror://sourceforge/${PN}/${P}.tar.gz
+	examples? ( mirror://sourceforge/${PN}/burrow-demos.tar )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples static-libs"
+
+RDEPEND="
+	dev-libs/g-wrap
+	dev-libs/glib:2
+	dev-scheme/guile[networking,regex]
+	dev-scheme/guile-cairo
+	dev-scheme/guile-gnome-platform
+	sci-libs/starparse
+	x11-libs/gtk+:2"
+DEPEND="${RDEPEND}
+	dev-util/indent
+	dev-util/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+
+src_configure() {
+	local myeconfargs=(
+		$(use_with doc doxygen doxygen)
+	)
+	autotools-utils_src_configure
+}
+
+src_test () {
+	autotools-utils_src_compile -C test-suite check
+}
+
+src_install() {
+	use doc && HTML_DOCS=("${AUTOTOOLS_BUILD_DIR}/doc/api/html/")
+	autotools-utils_src_install
+
+	use examples && \
+		insinto /usr/share/${PN} && \
+		doins -r "${WORKDIR}"/burrow-demos/*
+}
diff --git a/sci-chemistry/pymol/ChangeLog b/sci-chemistry/pymol/ChangeLog
index c46ca1931d60..10250bc2c153 100644
--- a/sci-chemistry/pymol/ChangeLog
+++ b/sci-chemistry/pymol/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sci-chemistry/pymol
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/ChangeLog,v 1.84 2012/02/26 06:10:49 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/ChangeLog,v 1.85 2012/02/27 22:53:03 jlec Exp $
+
+*pymol-1.5.0.2 (27 Feb 2012)
+
+  27 Feb 2012; Justin Lecher <jlec@gentoo.org> pymol-1.5.0.1.ebuild,
+  +pymol-1.5.0.2.ebuild:
+  Version Bump
 
   26 Feb 2012; Patrick Lauer <patrick@gentoo.org> pymol-1.3.1_pre3925-r1.ebuild,
   pymol-1.4.1.ebuild, pymol-1.5.0.1.ebuild:
diff --git a/sci-chemistry/pymol/pymol-1.5.0.1.ebuild b/sci-chemistry/pymol/pymol-1.5.0.1.ebuild
index 050bfca4b455..c0511e130639 100644
--- a/sci-chemistry/pymol/pymol-1.5.0.1.ebuild
+++ b/sci-chemistry/pymol/pymol-1.5.0.1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/pymol-1.5.0.1.ebuild,v 1.3 2012/02/26 06:10:49 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/pymol-1.5.0.1.ebuild,v 1.4 2012/02/27 22:53:03 jlec Exp $
 
 EAPI=4
 
@@ -104,7 +104,7 @@ src_install() {
 	dodoc DEVELOPERS README
 
 	doicon "${WORKDIR}"/${PN}.xpm
-	make_desktop_entry pymol PyMol ${PN}.xpm "Graphics;Science;Chemistry"
+	make_desktop_entry pymol PyMol ${PN} "Graphics;Science;Chemistry"
 }
 
 pkg_postinst() {
diff --git a/sci-chemistry/pymol/pymol-1.5.0.2.ebuild b/sci-chemistry/pymol/pymol-1.5.0.2.ebuild
new file mode 100644
index 000000000000..40ff66f76107
--- /dev/null
+++ b/sci-chemistry/pymol/pymol-1.5.0.2.ebuild
@@ -0,0 +1,120 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/pymol-1.5.0.2.ebuild,v 1.1 2012/02/27 22:53:03 jlec Exp $
+
+EAPI=4
+
+PYTHON_DEPEND="2:2.7"
+SUPPORT_PYTHON_ABIS="1"
+RESTRICT_PYTHON_ABIS="2.4 2.5 2.6 3.* *-jython 2.7-pypy-*"
+PYTHON_USE_WITH="tk"
+PYTHON_MODNAME="${PN} chempy pmg_tk pmg_wx"
+
+inherit distutils eutils fdo-mime prefix versionator
+
+DESCRIPTION="A Python-extensible molecular graphics system"
+HOMEPAGE="http://pymol.sourceforge.net/"
+SRC_URI="
+	http://dev.gentoo.org/~jlec/distfiles/${P}.tar.xz
+	http://dev.gentoo.org/~jlec/distfiles/${PN}.xpm.tar"
+
+LICENSE="PSF-2.2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
+IUSE="apbs numpy vmd web"
+
+DEPEND="
+	dev-python/numpy
+	dev-python/pmw
+	media-libs/freetype:2
+	media-libs/glew
+	media-libs/libpng
+	media-video/mpeg-tools
+	sys-libs/zlib
+	media-libs/freeglut
+	apbs? (
+		dev-libs/maloc
+		sci-chemistry/apbs
+		sci-chemistry/pdb2pqr
+		sci-chemistry/pymol-apbs-plugin
+	)
+	web? ( !dev-python/webpy )"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${PN}-1.5.0.1-setup.py.patch \
+		"${FILESDIR}"/${PN}-1.5.0.1-data-path.patch \
+		"${FILESDIR}"/${PN}-1.5.0.1-flags.patch
+
+	use web || epatch "${FILESDIR}"/${PN}-1.5.0.1-web.patch
+
+	epatch "${FILESDIR}"/${PN}-1.5.0.1-prefix.patch && \
+		eprefixify setup.py
+
+	use vmd && epatch "${FILESDIR}"/${PN}-1.5.0.1-vmd.patch
+
+	if use numpy; then
+		sed \
+			-e '/PYMOL_NUMPY/s:^#::g' \
+			-i setup.py || die
+	fi
+
+	rm ./modules/pmg_tk/startup/apbs_tools.py || die
+
+	echo "site_packages = \'$(python_get_sitedir -f)\'" > setup3.py || die
+
+	# python 3.* fix
+	# sed '452,465d' -i setup.py
+	distutils_src_prepare
+}
+
+src_configure() {
+	:
+}
+
+src_install() {
+	distutils_src_install
+
+	# These environment variables should not go in the wrapper script, or else
+	# it will be impossible to use the PyMOL libraries from Python.
+	cat >> "${T}"/20pymol <<- EOF
+		PYMOL_PATH="${EPREFIX}/$(python_get_sitedir -f)/${PN}"
+		PYMOL_DATA="${EPREFIX}/usr/share/pymol/data"
+		PYMOL_SCRIPTS="${EPREFIX}/usr/share/pymol/scripts"
+	EOF
+
+	doenvd "${T}"/20pymol
+
+	cat >> "${T}"/pymol <<- EOF
+	#!/bin/sh
+	$(PYTHON -f) -O \${PYMOL_PATH}/__init__.py -q \$*
+	EOF
+
+	dobin "${T}"/pymol
+
+	insinto /usr/share/pymol
+	doins -r test data scripts
+
+	insinto /usr/share/pymol/examples
+	doins -r examples
+
+	dodoc DEVELOPERS README
+
+	doicon "${WORKDIR}"/${PN}.xpm
+	make_desktop_entry pymol PyMol ${PN} "Graphics;Science;Chemistry"
+}
+
+pkg_postinst() {
+	elog "\t USE=shaders was removed,"
+	elog "please use pymol config settings"
+	elog "\t set use_shaders, 1"
+	distutils_pkg_postinst
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+}