Version bump, as requested by jkroon on #gentoo-voip and Travis Hansen <travisghansen@yahoo.com> in bug #282751.

Package-Manager: portage-2.1.6.13/cvs/Linux x86_64

3 files changed, 472 insertions, 5 deletions

diff --git a/net-misc/asterisk/ChangeLog b/net-misc/asterisk/ChangeLog
index 23cedbef151b..93da97e2f3de 100644
--- a/net-misc/asterisk/ChangeLog
+++ b/net-misc/asterisk/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/asterisk
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/asterisk/ChangeLog,v 1.205 2009/08/04 17:29:04 chainsaw Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/asterisk/ChangeLog,v 1.206 2009/08/27 14:02:17 chainsaw Exp $
+
+*asterisk-1.6.1.4 (27 Aug 2009)
+
+  27 Aug 2009; <chainsaw@gentoo.org> +asterisk-1.6.1.4.ebuild:
+  Version bump, as requested by jkroon on #gentoo-voip and Travis Hansen
+  <travisghansen@yahoo.com> in bug #282751.
 
 *asterisk-1.2.33-r1 (04 Aug 2009)
 
diff --git a/net-misc/asterisk/Manifest b/net-misc/asterisk/Manifest
index d365f7bc5f48..4a849c14cf1a 100644
--- a/net-misc/asterisk/Manifest
+++ b/net-misc/asterisk/Manifest
@@ -34,18 +34,20 @@ DIST asterisk-1.2.32.tar.gz 10636564 RMD160 2d83e006e5f4e8f03862d188525df665396d
 DIST asterisk-1.2.33.tar.gz 10638312 RMD160 529fc724fc9e3f4ba6951a39b9e1164ba03a5475 SHA1 e660940ddc330d484fe3c450eded637624b31cec SHA256 0d8b6b9eecbdf78edcce433085be274844128f895a2db73727ed32151f956e16
 DIST asterisk-1.6.1.0.tar.gz 13627016 RMD160 2fd9fc82a3f9cf23bbe2ed974b008a7a5bfdd570 SHA1 cd976cf05ba4c4b53b50e7af69fd6d684f070f86 SHA256 37b97603d19a9b403f59e3a8a5246cea10871b74d5f3ba8614345610e4d2cab8
 DIST asterisk-1.6.1.1.tar.gz 13630484 RMD160 2eddf1f8b234480a84ce840323c66b204fea09e1 SHA1 db9462d1a829625da0149c4952abfa7eee99d0c2 SHA256 551775588a8d25544b7bcc4017185cb15fd33988f832c30c87e014df78401b9a
+DIST asterisk-1.6.1.4.tar.gz 22966500 RMD160 571720c6b574df81de2322979864e17f298898e3 SHA1 66cba9e555bc38cfb0995f7ecd538234b525532c SHA256 3ed67429e6459a20ce1ca090d2803f427aa4a615a095d273ad5c3576e6d42bcc
 EBUILD asterisk-1.2.32.ebuild 10943 RMD160 72ba0b3e164603f1def0609e17ecdbaca0ab785c SHA1 6d17e406b88790da4c4e6f2311f366d6e719ea05 SHA256 39de089b06b8027d11be5e512daed22ffb680f4833c01b33badb10d66c07ae2a
 EBUILD asterisk-1.2.33-r1.ebuild 11038 RMD160 fbd7167840fb0e095f0366b4454907fffba21ea8 SHA1 60e4ed0e15dc363f3e75fd06cf440e4bfb19e6c3 SHA256 ca013f0940a3a66725ae8759bcfecc494debbf01a9483643b5fb2b9bdff79f16
 EBUILD asterisk-1.2.33.ebuild 10836 RMD160 7d75d0e7dde5dd9d000460f34bf6ae15e7e40526 SHA1 81fceed8c13539161fda9a6d68901bbf90dbc093 SHA256 e2c6b157f257d8a4da7ec14a55d68ba68a3f603aa38989c269d7a6d18c9be0d3
 EBUILD asterisk-1.6.1.0.ebuild 12058 RMD160 3b4a9ac79f571983519d760f55beeed93ebe6cba SHA1 f1aa0e09f5c290059e194f3647d4bdf484cb8e40 SHA256 16a33feb73b0fbdb79c07273031c97f6d148bde797bbbd977f4cede311c10985
 EBUILD asterisk-1.6.1.1-r1.ebuild 12325 RMD160 952f5dd9045b164072ffe62177340ea6f3492f3a SHA1 c89301eeea6e391ba10553b244ecedd0161daaa2 SHA256 add01201617434161c584717d3ab270220be528bc297f59778cab29d65629217
 EBUILD asterisk-1.6.1.1.ebuild 12058 RMD160 06dcb9e125aa728a7218d0ed8741db2e1fbb000d SHA1 a94c19c5d345dfc5dad7b22bea33636d87f9ac05 SHA256 4ab193b98b6e66e8c48eb0ddb952b5c60201ffe173d95104139aeef8b6d1528b
-MISC ChangeLog 43556 RMD160 d87ddc9d015e7391906c2f3bb80f1b8faf55aa2f SHA1 03f1848b6c474243fe848cc7644820e4a81e9bf1 SHA256 4c8df09299229cc9ab639e8580c697b0bf415e2bb89c12c7a2dd87574397b47e
+EBUILD asterisk-1.6.1.4.ebuild 12058 RMD160 a676de6cb12618d411d676a9bfa3ee36862e1c0b SHA1 c2f257679d7614d25e1975efb5344782f6f79255 SHA256 cd10243e9e374acd85b4e330e712259515f06d9bc7af283b37138c9f6bd70bb5
+MISC ChangeLog 43770 RMD160 5a98359a46cd5699930dbf6dd76467cdff331d38 SHA1 37fcedd0b1465957f7beaaa15e1d3f0923f4f0a2 SHA256 773234832399463def12b54518c325c0490cca5e1d9e3967aee93b2da8fdd47c
 MISC metadata.xml 1185 RMD160 eb12d6782abb8afd1c4eced97537a3528f960839 SHA1 80f58a977e41229cf37ee2cb5820e1cc29e517bc SHA256 4f1f9a977fac87bc22bc782cb30e4e7952e9772685d3424c69a514de3be5d0d3
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.11 (GNU/Linux)
 
-iEYEARECAAYFAkp4b8sACgkQp5vW4rUFj5o3VwCeJ0fxTkcbqj5MFBG6t1E99J7a
-x/MAn0FATzsu+h2cFKFnhI83AiI6bzCa
-=OPBe
+iEYEARECAAYFAkqWkcMACgkQp5vW4rUFj5qpIACfVijvo1bxypbY3NAJuzfPe9Mo
+K6wAoKPhWEilHwiX4LGaS7a05kwKStSB
+=rAVK
 -----END PGP SIGNATURE-----
diff --git a/net-misc/asterisk/asterisk-1.6.1.4.ebuild b/net-misc/asterisk/asterisk-1.6.1.4.ebuild
new file mode 100644
index 000000000000..7799957f4d33
--- /dev/null
+++ b/net-misc/asterisk/asterisk-1.6.1.4.ebuild
@@ -0,0 +1,459 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/asterisk/asterisk-1.6.1.4.ebuild,v 1.1 2009/08/27 14:02:17 chainsaw Exp $
+
+EAPI=1
+inherit eutils autotools
+
+MY_P="${PN}-${PV/_/-}"
+
+DESCRIPTION="Asterisk: A Modular Open Source PBX System"
+HOMEPAGE="http://www.asterisk.org/"
+SRC_URI="http://downloads.digium.com/pub/asterisk/releases/${MY_P}.tar.gz"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="alsa +caps curl dahdi debug freetds h323 iconv imap jabber ldap keepsrc misdn newt nosamples odbc oss postgres radius snmp span speex ssl sqlite static vorbis"
+
+RDEPEND="virtual/libc
+	sys-libs/ncurses
+	dev-libs/popt
+	sys-libs/zlib
+	alsa? ( media-libs/alsa-lib )
+	caps? ( sys-libs/libcap )
+	curl? ( net-misc/curl )
+	dahdi? ( >=net-libs/libpri-1.4.7
+		net-misc/dahdi-tools )
+	freetds? ( dev-db/freetds )
+	h323? ( dev-libs/pwlib
+		net-libs/openh323 )
+	iconv? ( virtual/libiconv )
+	imap? ( virtual/imap-c-client )
+	jabber? ( dev-libs/iksemel )
+	ldap?	( net-nds/openldap )
+	misdn? ( net-dialup/misdnuser )
+	newt? ( dev-libs/newt )
+	odbc? ( dev-db/unixODBC )
+	postgres? ( virtual/postgresql-base )
+	radius? ( net-dialup/radiusclient-ng )
+	snmp? ( net-analyzer/net-snmp )
+	span? ( media-libs/spandsp )
+	speex? ( media-libs/speex )
+	sqlite? ( dev-db/sqlite )
+	ssl? ( dev-libs/openssl )
+	vorbis? ( media-libs/libvorbis )"
+
+DEPEND="${RDEPEND}
+	!<net-misc/asterisk-addons-1.6"
+
+S="${WORKDIR}/${MY_P}"
+
+#
+# shortcuts
+#
+
+# update from asterisk-1.0.x
+is_ast10update() {
+	return $(has_version "=net-misc/asterisk-1.0*")
+}
+
+# update from asterisk-1.2.x
+is_ast12update() {
+	return $(has_version "=net-misc/asterisk-1.2*")
+}
+
+# update from asterisk 1.4.x
+is_ast14update() {
+	return $(has_version "=net-misc/asterisk-1.4*")
+}
+
+# update in the asterisk-1.6.x line
+is_astupdate() {
+	if ! is_ast10update && ! is_ast12update && !is_ast14update; then
+		return $(has_version "<net-misc/asterisk-${PV}")
+	fi
+	return 0
+}
+
+get_available_modules() {
+	local modules mod x
+
+	# build list of available modules...
+	for x in app cdr codec format func pbx res; do
+
+		for mod in $(find "${S}" -type f -name "${x}_*.c*" -print)
+		do
+			modules="${modules} $(basename ${mod/%.c*})"
+		done
+	done
+
+	echo "${modules}"
+}
+
+pkg_setup() {
+	local checkfailed=0 waitaftermsg=0
+
+	if is_ast10update || is_ast12update || is_ast14update ; then
+		ewarn "      Asterisk UPGRADE Warning"
+		ewarn ""
+		ewarn "- Please read "${ROOT}"usr/share/doc/${PF}/UPGRADE.txt.bz2 after the installation!"
+		ewarn ""
+		ewarn "      Asterisk UPGRADE Warning"
+		echo
+		waitaftermsg=1
+	fi
+
+	if [[ $waitaftermsg -eq 1 ]]; then
+		einfo "Press Ctrl+C to abort"
+		echo
+		ebeep 10
+	fi
+
+	#
+	# Regular checks
+	#
+	einfo "Running some pre-flight checks..."
+	echo
+
+	# imap requires ssl if imap-c-client was built with ssl,
+	# conversely if ssl and imap are both on then imap-c-client needs ssl
+	if use imap; then
+		if use ssl && ! built_with_use virtual/imap-c-client ssl; then
+			eerror
+			eerror "IMAP with SSL requested, but your IMAP C-Client libraries"
+			eerror "are built without SSL!"
+			eerror
+			die "Please recompile the IMAP C-Client libraries with SSL support enabled"
+		elif ! use ssl && built_with_use virtual/imap-c-client ssl; then
+			eerror
+			eerror "IMAP without SSL requested, but your IMAP C-Client"
+			eerror "libraries are built with SSL!"
+			eerror
+			die "Please recompile the IMAP C-Client libraries without SSL support enabled"
+		fi
+	fi
+
+	if [[ -n "${ASTERISK_MODULES}" ]] ; then
+		ewarn "You are overriding ASTERISK_MODULES. We will assume you know what you are doing. There is no support for this option, try without if you see breakage."
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	#
+	# comment about h323 issues
+	#
+	if use h323 ; then
+		ewarn "h323 useflag: It is known that the h323 module doesn't compile
+		the \"normal\" way: For a workaround, asterisk will be built two times
+		without cleaning the build dir."
+	fi
+
+	#
+	# put pid file(s) into /var/run/asterisk
+	#
+	epatch "${FILESDIR}"/1.6.1/${PN}-1.6.1-var_rundir.patch || die "patch failed"
+
+	#
+	# fix gsm codec cflags (e.g. i586 core epias) and disable
+	# assembler optimizations
+	#
+	epatch "${FILESDIR}"/1.6.1/${PN}-1.6.1-gsm-pic.patch || die "patch failed"
+
+	#
+	# add missing LIBS for uclibc
+	#
+	epatch "${FILESDIR}"/1.6.1/${PN}-1.6.1-uclibc.patch  || die "patch failed"
+
+	#
+	# try to tame the custom build system a little so make likes it better
+	# patch credit: Diego E. 'Flameeyes' Pettenò <flameeyes@entoo.org>
+	#
+	epatch "${FILESDIR}"/1.6.1/asterisk-1.6.1-parallelmake.patch || die "patch failed"
+
+	#
+	# do not try to pass libraries in ldflags but use libs properly
+	# keeps NET-SNMP configure test from failing horribly on --as-needed
+	# http://bugs.digium.com/view.php?id=14671
+	#
+	epatch "${FILESDIR}"/1.6.1/asterisk-1.6.1-toolcheck-libs-not-ldflags.patch || die "patch failed"
+
+	#
+	# link UW-IMAP with Kerberos5 if necessary
+	#
+	epatch "${FILESDIR}"/1.6.1/asterisk-1.6.1-imap-kerberos.patch || die "patch failed"
+
+	AT_M4DIR=autoconf eautoreconf
+
+	# parse modules list
+	if [[ -n "${ASTERISK_MODULES}" ]]; then
+		local x modules="$(get_available_modules)"
+
+		einfo "Custom list of modules specified, checking..."
+
+		use debug && {
+			einfo "Available modules: ${modules}"
+			einfo " Selected modules: ${ASTERISK_MODULES}"
+		}
+
+		for x in ${ASTERISK_MODULES}; do
+			if [[ "${x}" = "-*" ]]; then
+				MODULES_LIST=""
+			else
+				if has ${x} ${modules}
+				then
+					MODULES_LIST="${MODULES_LIST} ${x}"
+				else
+					eerror "Unknown module: ${x}"
+				fi
+			fi
+		done
+
+		export MODULES_LIST
+	fi
+}
+
+src_compile() {
+	#
+	# start with configure
+	#
+	econf \
+		--libdir="/usr/$(get_libdir)" \
+		--localstatedir="/var" \
+		--with-gsm=internal \
+		--with-popt \
+		--with-z \
+		$(use_with alsa asound) \
+		$(use_with caps cap) \
+		$(use_with curl) \
+		$(use_with dahdi pri) \
+		$(use_with dahdi tonezone) \
+		$(use_with dahdi) \
+		$(use_with freetds tds) \
+		$(use_with h323 h323 "/usr/share/openh323") \
+		$(use_with h323 pwlib "/usr/share/pwlib") \
+		$(use_with iconv) \
+		$(use_with imap) \
+		$(use_with jabber iksemel) \
+		$(use_with misdn isdnnet) \
+		$(use_with misdn suppserv) \
+		$(use_with misdn) \
+		$(use_with newt) \
+		$(use_with odbc) \
+		$(use_with oss) \
+		$(use_with postgres) \
+		$(use_with radius) \
+		$(use_with snmp netsnmp) \
+		$(use_with span spandsp) \
+		$(use_with speex) \
+		$(use_with speex speexdsp) \
+		$(use_with sqlite sqlite3) \
+		$(use_with ssl crypto) \
+		$(use_with ssl) \
+		$(use_with vorbis ogg) \
+		$(use_with vorbis) || die "econf failed"
+
+	#
+	# custom module filter
+	# run menuselect to evaluate the list of modules
+	# and rewrite the list afterwards
+	#
+	if [[ -n "${MODULES_LIST}" ]]
+	then
+		local mod category tmp_list failed_list
+
+		###
+		# run menuselect
+
+		emake menuselect.makeopts || die "emake menuselect.makeopts failed"
+
+		###
+		# get list of modules with failed dependencies
+
+		failed_list="$(awk -F= '/^MENUSELECT_DEPSFAILED=/{ print $3 }' menuselect.makeopts)"
+
+		###
+		# traverse our list of modules
+
+		for category in app cdr codec format func pbx res; do
+			tmp_list=""
+
+			# search list of modules for matching ones first...
+			for mod in ${MODULES_LIST}; do
+				# module is from current category?
+				if [[ "${mod/%_*}" = "${category}" ]]
+				then
+					# check menuselect thinks the dependencies are met
+					if has ${mod} ${failed_list}
+					then
+						eerror "${mod}: dependencies required to build this module are not met, NOT BUILDING!"
+					else
+						tmp_list="${tmp_list} ${mod}"
+					fi
+				fi
+			done
+
+			use debug && echo "${category} tmp: ${tmp_list}"
+
+			# replace the module list for $category with our custom one
+			if [[ -n "${tmp_list}" ]]
+			then
+				category="$(echo ${category} | tr '[:lower:]' '[:upper:]')"
+				sed -i -e "s:^\(MENUSELECT_${category}S?\):\1=${tmp_list}:" \
+					menuselect.makeopts || die "failed to set list of ${category} applications"
+			fi
+		done
+	fi
+
+	#
+	# fasten your seatbelts (and start praying)
+	#
+	if use h323 ; then
+		# emake one time to get h323 to make.... yea not "clean" but works
+		emake
+	fi
+
+	emake || die "emake failed"
+}
+
+src_install() {
+	# setup directory structure
+	#
+	mkdir -p "${D}"usr/lib/pkgconfig
+
+	emake DESTDIR="${D}" install || die "emake install failed"
+	emake DESTDIR="${D}" samples || die "emake samples failed"
+
+	# remove installed sample files if nosamples flag is set
+	if use nosamples; then
+		einfo "Skipping installation of sample files..."
+		rm -f  "${D}"var/lib/asterisk/mohmp3/*
+		rm -f  "${D}"var/lib/asterisk/sounds/demo-*
+		rm -f  "${D}"var/lib/asterisk/agi-bin/*
+	else
+		einfo "Sample files have been installed"
+	fi
+	rm -rf "${D}"var/spool/asterisk/voicemail/default
+
+	# move sample configuration files to doc directory
+	if is_ast10update || is_ast12update || is_ast14update; then
+		einfo "Updating from old (pre-1.6) asterisk version, new configuration files have been installed"
+		einfo "into "${ROOT}"etc/asterisk, use etc-update or dispatch-conf to update them"
+	fi
+
+	einfo "Configuration samples have been moved to: "${ROOT}"/usr/share/doc/${PF}/conf"
+	insinto /usr/share/doc/${PF}/conf
+	doins "${D}"etc/asterisk/*.conf*
+
+	# keep directories
+	keepdir /var/spool/asterisk/{system,tmp,meetme,monitor,dictate,voicemail}
+	keepdir /var/log/asterisk/{cdr-csv,cdr-custom}
+
+	newinitd "${FILESDIR}"/1.6.1/asterisk.rc6 asterisk
+	newconfd "${FILESDIR}"/1.6.0/asterisk.confd asterisk
+
+	# some people like to keep the sources around for custom patching
+	# copy the whole source tree to /usr/src/asterisk-${PVF} and run make clean there
+	if use keepsrc
+	then
+		einfo "keepsrc useflag enabled, copying source..."
+		dodir /usr/src
+
+		cp -dPR "${S}" "${D}"/usr/src/${PF} || die "copying source tree failed"
+
+		ebegin "running make clean..."
+		emake -C "${D}"/usr/src/${PF} clean >/dev/null || die "make clean failed"
+		eend $?
+
+		einfo "Source files have been saved to "${ROOT}"usr/src/${PF}"
+	fi
+
+	# install the upgrade documentation
+	#
+	dodoc README UPGRADE* BUGS CREDITS
+
+	# install snmp mib files
+	#
+	if use snmp
+	then
+		insinto /usr/share/snmp/mibs/
+		doins doc/digium-mib.txt doc/asterisk-mib.txt
+	fi
+}
+
+pkg_preinst() {
+	enewgroup asterisk
+	enewuser asterisk -1 -1 /var/lib/asterisk "asterisk,dialout"
+}
+
+pkg_postinst() {
+	ebegin "Fixing up permissions"
+		chown -R asterisk:asterisk "${ROOT}"var/log/asterisk
+		chmod -R u=rwX,g=rX,o=     "${ROOT}"var/log/asterisk
+
+		for x in lib run spool; do
+			chown -R asterisk:asterisk "${ROOT}"var/${x}/asterisk
+			chmod -R u=rwX,g=rwX,o=    "${ROOT}"var/${x}/asterisk
+		done
+
+		chown asterisk:asterisk "${ROOT}"etc/asterisk/
+		chown asterisk:asterisk "${ROOT}"etc/asterisk/*.adsi
+		chown asterisk:asterisk "${ROOT}"etc/asterisk/extensions.ael
+		chmod u=rwX,g=rwX,o= "${ROOT}"etc/asterisk/
+		chmod u=rwX,g=rwX,o= "${ROOT}"etc/asterisk/*.adsi
+		chmod u=rwX,g=rwX,o= "${ROOT}"etc/asterisk/extensions.ael
+	eend $?
+
+	#
+	# Announcements, warnings, reminders...
+	#
+	einfo "Asterisk has been installed"
+	echo
+	elog "If you want to know more about asterisk, visit these sites:"
+	elog "http://www.asteriskdocs.org/"
+	elog "http://www.voip-info.org/wiki-Asterisk"
+	echo
+	elog "http://www.automated.it/guidetoasterisk.htm"
+	echo
+	elog "Gentoo VoIP IRC Channel:"
+	elog "#gentoo-voip @ irc.freenode.net"
+	echo
+	echo
+
+	#
+	# Warning about 1.x -> 1.6 changes...
+	#
+	if is_ast10update || is_ast12update || is_ast14update; then
+		ewarn ""
+		ewarn "- Please read "${ROOT}"usr/share/doc/${PF}/UPGRADE.txt.bz2 before continuing"
+		ewarn ""
+	fi
+}
+
+pkg_config() {
+	einfo "Do you want to reset file permissions and ownerships (y/N)?"
+
+	read tmp
+	tmp="$(echo $tmp | tr '[:upper:]' '[:lower:]')"
+
+	if [[ "$tmp" = "y" ]] ||\
+		[[ "$tmp" = "yes" ]]
+	then
+		einfo "Resetting permissions to defaults..."
+
+		for x in spool run lib log; do
+			chown -R asterisk:asterisk "${ROOT}"var/${x}/asterisk
+			chmod -R u=rwX,g=rwX,o=    "${ROOT}"var/${x}/asterisk
+		done
+
+		chown -R root:asterisk  "${ROOT}"etc/asterisk
+		chmod -R u=rwX,g=rwX,o= "${ROOT}"etc/asterisk
+
+		einfo "done"
+	else
+		einfo "skipping"
+	fi
+}