Version bump, with GCC 4.4 support and ebuild cleanups: EAPI2, drop vpopmail setup (courier-imap does not support it anymore), only run eautoreconf in needed directories, remove CFLAGS workaround for bug #21330 (works fine now), add USE flag to enable trashquota (bug #173394)

Package-Manager: portage-2.2_rc44/cvs/Linux x86_64

4 files changed, 249 insertions, 3 deletions

diff --git a/net-mail/courier-imap/ChangeLog b/net-mail/courier-imap/ChangeLog
index 9eddd41e8c9a..42a88d82e070 100644
--- a/net-mail/courier-imap/ChangeLog
+++ b/net-mail/courier-imap/ChangeLog
@@ -1,6 +1,15 @@
 # ChangeLog for net-mail/courier-imap
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-mail/courier-imap/ChangeLog,v 1.173 2009/10/06 17:47:08 voyageur Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-mail/courier-imap/ChangeLog,v 1.174 2009/10/06 21:38:40 voyageur Exp $
+
+*courier-imap-4.6.0 (06 Oct 2009)
+
+  06 Oct 2009; Bernard Cafarelli <voyageur@gentoo.org>
+  +courier-imap-4.6.0.ebuild, metadata.xml:
+  Version bump, with GCC 4.4 support and ebuild cleanups: EAPI2, drop
+  vpopmail setup (courier-imap does not support it anymore), only run
+  eautoreconf in needed directories, remove CFLAGS workaround for bug #21330
+  (works fine now), add USE flag to enable trashquota (bug #173394)
 
   06 Oct 2009; Bernard Cafarelli <voyageur@gentoo.org> metadata.xml:
   Add myself to maintainers, so I get bugreports on everything I break
diff --git a/net-mail/courier-imap/Manifest b/net-mail/courier-imap/Manifest
index 8c300fbc4eb2..bc4916754c79 100644
--- a/net-mail/courier-imap/Manifest
+++ b/net-mail/courier-imap/Manifest
@@ -55,6 +55,7 @@ DIST courier-imap-4.0.6.tar.bz2 3157577 RMD160 4006c5ec4db6b2adac393e2ebdf9ee99a
 DIST courier-imap-4.1.2.tar.bz2 3257311 RMD160 56546e90fc16f92daab6d7540154bc5f7ad06e27 SHA1 73ed09528f440ef07ba98f59a83172f4f6f4106b SHA256 37c3530b31e0b9b5a5bcd639ac3db4862f12e77ec39d8d67f19e630d76853d71
 DIST courier-imap-4.4.1.tar.bz2 3383036 RMD160 ae1feff71b6dbd893ba1866bf4bf974e84210236 SHA1 c5d7a2790f6ce0ed7eda90a36268a1e772627bd7 SHA256 d7cff71f0aaf34ea8dc6823550dadf62def4f616b750548bf0512f12d1b4725f
 DIST courier-imap-4.5.0.tar.bz2 3565751 RMD160 eb53e59521d6c8799e6c28546258b77ded67be2c SHA1 e9828ae7f6880b546d4d4316952a26a5da640c12 SHA256 3d7de2ba6d5f7fa2e7ac4bfeb053055e127234c3442a09f36aa5dd71b9f44ffa
+DIST courier-imap-4.6.0.tar.bz2 3397972 RMD160 664fb26c1351965af6b1bb21e22230ef6632f110 SHA1 bec24c374007c3da265e0544891992ce5994d57f SHA256 d84e4bd4f643ec03ef1bdea9743c4b917fce7a36cf8967edeeefb7c15b825b37
 EBUILD courier-imap-3.0.8.ebuild 9370 RMD160 78c166ca40a0cd5e10ec1cd691dc1ee907d6eb94 SHA1 e14cbbdaa6411b4aa62ebac1082399fbdd19cb74 SHA256 fc32497d86a9d193d3398a93b8d9d2fdb1bfacdee282be199c899d1264954994
 EBUILD courier-imap-4.0.6-r2.ebuild 8494 RMD160 5a59a777cb8542e402e1dace7d46d31891214de2 SHA1 90feedba0217dc537a6a19f4bb7a79a7831afe40 SHA256 f9d117c1b0be12a96ae6b540ff424a356351ad8362759639d7ee2b21c367967f
 EBUILD courier-imap-4.0.6-r3.ebuild 8493 RMD160 8d52d5401496d2b8c9566fa52459969977d13c65 SHA1 661f252ca6e06d8d8709684f20b828a1d570aacb SHA256 f43d8dfe6f2d6a267ae6cfa8cad62e34d89a3fcee8bb4de8261f95cea1177b79
@@ -63,5 +64,6 @@ EBUILD courier-imap-4.1.2-r2.ebuild 8617 RMD160 d0a3829669277dc7dd93700c08e3ab77
 EBUILD courier-imap-4.4.1-r1.ebuild 8183 RMD160 8232777fbadc52e771c03709d4ec1d1f9245e1c2 SHA1 62be90bad4b44081e04e8697e5c1b99b7e77318a SHA256 781d1522ca333faf6a50ca23840fce77b9ffaf60ddf0a9b67f8c1f1c99209c54
 EBUILD courier-imap-4.4.1.ebuild 8180 RMD160 9256a66bc700aa74618ae98311c8bb7016186e0f SHA1 a04b23346efdf73f76048aca8cafa380e532f2c0 SHA256 c14e7187214c789546d38c339c2b586a296a1e3eb1400267b1ecf70b1ea30b8f
 EBUILD courier-imap-4.5.0.ebuild 8228 RMD160 c0094febcda5761f2d5557591d93b9ea142be8cd SHA1 95b1367261ad489579a1938e236c423e400f1bd6 SHA256 e7400867b68fabf30f575b8acdaf2004e50ac48962e19ced93f92d8c615d2228
-MISC ChangeLog 33896 RMD160 e66fa715693c6644ec2d2ae19e6d4d3299903474 SHA1 d46b60f1a54083486af1d69d49a9312b37f1ed9c SHA256 8a38a29baa1c0f04c08daeb04d5ae28f7727e79290f260bb125bedbfb4f73714
-MISC metadata.xml 357 RMD160 dee207a3d6ad2debe9e4faeeb25e0d07d9f9d360 SHA1 c2175483e2eeda5e7a64581d77061587be260791 SHA256 ac01a3773e891018c70edef4bdd22c17bae09623f2a7da3f0eef49b422201f76
+EBUILD courier-imap-4.6.0.ebuild 7842 RMD160 29b14bba306aec060571953529a17eac041b3593 SHA1 07fdb70a3dadd4507f83a82cc7e69c45424d6b3b SHA256 868e989d2a2e79d0442b5d68bd3e0f768b57ecb92cdf4598717e2432231abab3
+MISC ChangeLog 34316 RMD160 b4ec7642d7dd75fe9de7217a36696245bf46f492 SHA1 edca847c39bbb4182fa3c44e5cddc2eb21efca81 SHA256 b5c2258e5be25bac1274f5137e39d4cf5c42652d53470bde4b47f58a334d3731
+MISC metadata.xml 495 RMD160 a08ec4892b1931702f94b78f75841d4a6d0989ab SHA1 6fee69c5c0cc8fe6092d12e0028ca43739d94040 SHA256 009ce86710a6c7acebacfd6338e68e3eb73e17f9be05042aadad0a469a8a3da5
diff --git a/net-mail/courier-imap/courier-imap-4.6.0.ebuild b/net-mail/courier-imap/courier-imap-4.6.0.ebuild
new file mode 100644
index 000000000000..7ce71542c873
--- /dev/null
+++ b/net-mail/courier-imap/courier-imap-4.6.0.ebuild
@@ -0,0 +1,232 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-mail/courier-imap/courier-imap-4.6.0.ebuild,v 1.1 2009/10/06 21:38:40 voyageur Exp $
+
+EAPI=2
+inherit autotools eutils multilib libtool
+
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~x86-fbsd"
+
+DESCRIPTION="An IMAP daemon designed specifically for maildirs."
+HOMEPAGE="http://www.courier-mta.org/"
+SRC_URI="mirror://sourceforge/courier/${P}.tar.bz2"
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="berkdb debug fam gdbm ipv6 nls selinux gnutls trashquota"
+
+RDEPEND="gnutls? ( net-libs/gnutls )
+		!gnutls? ( >=dev-libs/openssl-0.9.6 )
+		>=net-libs/courier-authlib-0.61
+		>=net-mail/mailbase-0.00-r8
+		berkdb? ( sys-libs/db )
+		fam? ( virtual/fam )
+		gdbm? ( >=sys-libs/gdbm-1.8.0 )
+		selinux? ( sec-policy/selinux-courier-imap )"
+DEPEND="${RDEPEND}
+		dev-lang/perl
+		!mail-mta/courier
+		userland_GNU? ( sys-process/procps )"
+RDEPEND="${RDEPEND}
+		!virtual/imapd"
+
+PROVIDE="virtual/imapd"
+
+RC_VER="4.0.6-r1"
+INITD_VER="4.0.6-r1"
+
+pkg_setup() {
+	if ! use berkdb && ! use gdbm ; then
+		echo
+		eerror "Either the 'berkdb' or the 'gdbm' USE flag is required."
+		eerror "Please add it to '/etc/make.conf' or '/etc/portage/package.use'."
+		eerror "Use 'man 5 portage' for more info on '/etc/portage/package.use'."
+		echo
+		die "Required USE flag missing."
+	fi
+}
+
+src_prepare() {
+	# Bug #48838. Patch to enable/disable FAM support.
+	# 20 Aug 2004 langthang@gentoo.org
+	# This patch should fix bug #51540. fam USE flag is not needed for shared folder support.
+	epatch "${FILESDIR}"/${PN}-4.0.1-disable-fam-configure.in.patch
+
+	# Kill unneeded call to AC_PROG_SYSCONFTOOL (bug #168206).
+	epatch "${FILESDIR}"/${PN}-4.0.6-aclocal-fix.patch
+
+	# These patches should fix problems detecting BerkeleyDB.
+	# We now can compile with db4 support.
+	if use berkdb ; then
+		epatch "${FILESDIR}"/${PN}-4.0.6-db4-bdbobj_configure.in.patch
+		epatch "${FILESDIR}"/${PN}-4.0.6-db4-configure.in.patch
+	fi
+
+	AT_NO_RECURSIVE="true" eautoreconf || die "root eautoreconf failed"
+	cd "${S}"/maildir
+	eautoreconf || die "maildir eautoreconf failed"
+	cd "${S}"/bdbobj
+	eautoreconf || die "bdobj eautoreconf failed"
+}
+
+src_configure() {
+	local myconf=""
+
+	# 19 Aug 2004 langthang@gentoo.org
+	# Default to gdbm if both berkdb and gdbm are present.
+	if use gdbm ; then
+		einfo "Building with GDBM support"
+		myconf="${myconf} --with-db=gdbm"
+	elif use berkdb ; then
+		einfo "Building with BerkeleyDB support"
+		myconf="${myconf} --with-db=db"
+	fi
+
+	# The default character set is ISO-8859-1/US-ASCII.
+	# USE 'nls' will enable all available character sets.
+	# Set ENABLE_UNICODE=iso-8859-1,utf-8,iso-8859-10
+	# to include only specified translation tables.
+	if use nls && [[ -z "${ENABLE_UNICODE}" ]] ; then
+		einfo "ENABLE_UNICODE is not set, building with all available character sets"
+		myconf="${myconf} --enable-unicode"
+	elif use nls ; then
+		einfo "ENABLE_UNICODE is set, building with unicode=${ENABLE_UNICODE}"
+		myconf="${myconf} --enable-unicode=${ENABLE_UNICODE}"
+	else
+		einfo "Disabling unicode support"
+		myconf="${myconf} --disable-unicode"
+	fi
+
+	if use trashquota ; then
+		einfo "Building with Trash Quota Support"
+		myconf="${myconf} --with-trashquota"
+	fi
+
+	use debug && myconf="${myconf} debug=true"
+
+	# Do the actual build now
+	econf \
+		--disable-root-check \
+		--bindir=/usr/sbin \
+		--sysconfdir=/etc/${PN} \
+		--libexecdir=/usr/$(get_libdir)/${PN} \
+		--localstatedir=/var/lib/${PN} \
+		--with-authdaemonvar=/var/lib/${PN}/authdaemon \
+		--enable-workarounds-for-imap-client-bugs \
+		--with-mailuser=mail \
+		--with-mailgroup=mail \
+		$(use_with fam) \
+		$(use_with ipv6) \
+		$(use_with gnutls) \
+		${myconf} || die "econf failed"
+
+	# Change the pem file location.
+	sed -i -e "s:^\(TLS_CERTFILE=\).*:\1/etc/courier-imap/imapd.pem:" \
+		imap/imapd-ssl.dist || \
+		die "sed failed"
+
+	sed -i -e "s:^\(TLS_CERTFILE=\).*:\1/etc/courier-imap/pop3d.pem:" \
+		imap/pop3d-ssl.dist || \
+		die "sed failed"
+}
+
+src_compile() {
+	# spurious failures with parallel compiles
+	emake -j1 || die "emake failed"
+}
+
+src_install() {
+	dodir /var/lib/${PN} /etc/pam.d
+	emake DESTDIR="${D}" install || die "emake install failed"
+	rm -Rf "${D}/etc/pam.d"
+
+	# Avoid name collisions in /usr/sbin wrt imapd and pop3d
+	cd "${D}/usr/sbin"
+	for name in imapd pop3d ; do
+		mv -f "${name}" "courier-${name}" || die "Failed to mv ${name} to courier-${name}"
+	done
+
+	# Hack /usr/lib/courier-imap/foo.rc to use ${MAILDIR} instead of
+	# 'Maildir', and to use /usr/sbin/courier-foo names.
+	cd "${D}/usr/$(get_libdir)/${PN}"
+	for service in {imapd,pop3d}{,-ssl} ; do
+		sed -i -e 's/Maildir/${MAILDIR}/' "${service}.rc" || die "sed failed"
+		sed -i -e "s/\/usr\/sbin\/${service}/\/usr\/sbin\/courier-${service}/" "${service}.rc" || die "sed failed"
+	done
+
+	# Rename the config files correctly and add a value for ${MAILDIR} to them.
+	cd "${D}/etc/${PN}"
+	for service in {imapd,pop3d}{,-ssl} ; do
+		mv -f "${service}.dist" "${service}" || die "Failed to mv ${service}.dist to ${service}"
+		echo -e '\n# Hardwire a value for ${MAILDIR}' >> "${service}"
+		echo 'MAILDIR=.maildir' >> "${service}"
+		echo 'MAILDIRPATH=.maildir' >> "${service}"
+	done
+	for service in imapd pop3d ; do
+		echo -e '# Put any program for ${PRERUN} here' >> "${service}"
+		echo 'PRERUN=' >> "${service}"
+		echo -e '# Put any program for ${LOGINRUN} here' >> "${service}"
+		echo -e '# this is for relay-ctrl-allow in 4*' >> "${service}"
+		echo 'LOGINRUN=' >> "${service}"
+	done
+
+	cd "${D}/usr/sbin"
+	for x in * ; do
+		if [[ -L "${x}" ]] ; then
+			rm -f "${x}" || die "Failed to rm ${x}"
+		fi
+	done
+
+	cd ../share
+	mv -f * ../sbin
+	mv -f ../sbin/man .
+	cd ..
+
+	for x in mkimapdcert mkpop3dcert ; do
+		mv -f "${D}/usr/sbin/${x}" "${D}/usr/sbin/${x}.orig" || die "Failed to mv /usr/sbin/${x} to /usr/sbin/${x}.orig"
+	done
+
+	exeinto /usr/sbin
+	doexe "${FILESDIR}/mkimapdcert" "${FILESDIR}/mkpop3dcert" || die "doexe failed"
+
+	dosym /usr/sbin/courierlogger /usr/$(get_libdir)/${PN}/courierlogger || die "dosym failed"
+
+	mkdir "${WORKDIR}/tmp" ; cd "${WORKDIR}/tmp"
+	for initd in courier-{imapd,pop3d}{,-ssl} ; do
+		sed -e "s:GENTOO_LIBDIR:$(get_libdir):g" "${FILESDIR}/${PN}-${INITD_VER}-${initd}.rc6" > "${initd}" || die "initd libdir-sed failed"
+		doinitd "${initd}" || die "doinitd ${initd} failed"
+	done
+	exeinto /usr/$(get_libdir)/${PN}
+	for exe in gentoo-{imapd,pop3d}{,-ssl}.rc courier-{imapd,pop3d}.indirect ; do
+		sed -e "s:GENTOO_LIBDIR:$(get_libdir):g" "${FILESDIR}/${PN}-${RC_VER}-${exe}" > "${exe}" || die "exe libdir-sed failed"
+		doexe "${exe}" || die "doexe ${exe} failed"
+	done
+
+	dodir /usr/bin
+	mv -f "${D}/usr/sbin/maildirmake" "${D}/usr/bin/maildirmake" || die "Failed to mv /usr/sbin/maildirmake to /usr/bin/maildirmake"
+
+	# Bug #45953, more docs.
+	cd "${S}"
+	dohtml -r "${S}"/*
+	dodoc "${S}"/{00README.NOW.OR.SUFFER,AUTHORS,INSTALL,NEWS,README,ChangeLog} "${FILESDIR}"/${PN}-gentoo.readme
+	docinto imap
+	dodoc "${S}"/imap/{ChangeLog,BUGS,BUGS.html,README}
+	docinto maildir
+	dodoc "${S}"/maildir/{AUTHORS,INSTALL,README.maildirquota.txt,README.sharedfolders.txt}
+	docinto tcpd
+	dodoc "${S}"/tcpd/README.couriertls
+}
+
+pkg_postinst() {
+	elog "Authdaemond is no longer provided by this package."
+	elog "Authentication libraries are now in courier-authlib."
+	elog "For a quick-start howto please refer to"
+	elog "${PN}-gentoo.readme in /usr/share/doc/${PF}"
+	# Some users have been reporting that permissions on this directory were
+	# getting scrambled, so let's ensure that they are sane.
+	chmod 0755 "${ROOT}/usr/$(get_libdir)/${PN}" || die "Failed to ensure sane permissions on ${ROOT}/usr/$(get_libdir)/${PN}"
+}
+
+src_test() {
+	ewarn "make check is not supported by this package due to the"
+	ewarn "--enable-workarounds-for-imap-client-bugs option."
+}
diff --git a/net-mail/courier-imap/metadata.xml b/net-mail/courier-imap/metadata.xml
index 81291dfdad95..852c1f711df9 100644
--- a/net-mail/courier-imap/metadata.xml
+++ b/net-mail/courier-imap/metadata.xml
@@ -10,4 +10,7 @@
 		<email>voyageur@gentoo.org</email>
 		<name>Bernard Cafarelli</name>
 	</maintainer>
+	<use>
+		<flag name="trashquota">include deleted messages, and the Trash folder, in the estimated quota usage for maildirs</flag>
+	</use>
 </pkgmetadata>