Version bump, now with support for audacious. Had to drop ~alpha, ~ppc64 & ~sparc keywords because of this.

Package-Manager: portage-2.0.53_rc7

1 files changed, 51 insertions, 0 deletions

diff --git a/net-irc/xchat-xsys/xchat-xsys-2.0.9.ebuild b/net-irc/xchat-xsys/xchat-xsys-2.0.9.ebuild
new file mode 100644
index 000000000000..895dfada27bf
--- /dev/null
+++ b/net-irc/xchat-xsys/xchat-xsys-2.0.9.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2005 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-irc/xchat-xsys/xchat-xsys-2.0.9.ebuild,v 1.1 2005/11/13 22:09:53 chainsaw Exp $
+
+inherit toolchain-funcs eutils
+
+MY_P="${P/xchat-/}"
+S=${WORKDIR}/${MY_P}
+DESCRIPTION="Sysinfo plugin for X-Chat."
+SRC_URI="mirror://gentoo/${MY_P}.tar.bz2"
+HOMEPAGE="http://dev.gentoo.org/~chainsaw/xsys/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="audacious bmp buttons xmms"
+
+DEPEND="|| (
+		>=net-irc/xchat-2.4.0
+		>=net-irc/xchat-gnome-0.4
+	)
+	sys-apps/pciutils
+	audacious? ( media-sound/audacious )
+	bmp? ( media-sound/beep-media-player )
+	xmms? ( media-sound/xmms )"
+
+src_unpack() {
+	unpack ${A}
+	sed -i -e "s:-O2 -Wall:${CFLAGS} -Wall:" ${S}/Makefile
+	if use buttons; then
+		sed -i -e "s:#BUTTON:BUTTON:" ${S}/Makefile
+	fi
+	if use audacious; then
+		sed -i -e "s:# FOR AUDACIOUS # ::g" ${S}/Makefile
+	elif use bmp; then
+		sed -i -e "s:# FOR BMP # ::g" ${S}/Makefile
+	elif use xmms; then
+		sed -i -e "s:# FOR XMMS # ::g" ${S}/Makefile
+	fi
+}
+
+src_compile() {
+	emake -j1 CC="$(tc-getCC)" || die "Compile failed"
+}
+
+src_install() {
+	exeinto /usr/$(get_libdir)/xchat/plugins
+	doexe xsys-${PV}.so || die "doexe failed"
+
+	dodoc ChangeLog README || die "dodoc failed"
+}