push a new snapshot, fixes 329921, 339036 and should help with 179872

Package-Manager: portage-2.2_rc91/cvs/Linux x86_64

3 files changed, 285 insertions, 2 deletions

diff --git a/media-video/ffmpeg/ChangeLog b/media-video/ffmpeg/ChangeLog
index 600604166f99..323feb590e09 100644
--- a/media-video/ffmpeg/ChangeLog
+++ b/media-video/ffmpeg/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/ffmpeg
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ChangeLog,v 1.375 2010/10/08 14:50:47 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ChangeLog,v 1.376 2010/10/09 13:44:10 aballier Exp $
+
+*ffmpeg-0.6_p25423 (09 Oct 2010)
+
+  09 Oct 2010; Alexis Ballier <aballier@gentoo.org>
+  +ffmpeg-0.6_p25423.ebuild:
+  push a new snapshot, fixes 329921, 339036 and should help with 179872
 
   08 Oct 2010; Brent Baude <ranger@gentoo.org> ffmpeg-0.6.ebuild:
   Marking ffmpeg-0.6 ppc for bug 332361
diff --git a/media-video/ffmpeg/Manifest b/media-video/ffmpeg/Manifest
index 27ca27d6f3c3..d98af281db06 100644
--- a/media-video/ffmpeg/Manifest
+++ b/media-video/ffmpeg/Manifest
@@ -1,9 +1,21 @@
+-----BEGIN PGP SIGNED MESSAGE-----
+Hash: SHA1
+
 DIST ffmpeg-0.5_p20373.tar.bz2 3087600 RMD160 6a960e0837f419c882c7bd18c91f582df0e19c58 SHA1 ddf5d0389586d8ceb2979e0804a7b80a9640aad4 SHA256 2a217144c82f11c80f325c653157bd9fc5424dc43a2b2ccbc8eb03a01d33418d
 DIST ffmpeg-0.5_p22846.tar.bz2 3675057 RMD160 3ebd997321d59fa0baf87329518e925ccbed3cf8 SHA1 d207570ed009b63c94485ccc64439107cf700f39 SHA256 a52d82476afa7c8ed62c1a52760e49907947c1ef1ecfc3e9022fa713e9783f2f
 DIST ffmpeg-0.6.tar.bz2 3720372 RMD160 1ff6a8f419239a03d84f67cc954f60f73632432a SHA1 c130e3bc368251b9130ce6eafb44fe8c3993ff5c SHA256 6730baa6750f0cbffaf5f4c04f8ddcf1ebe6c651a6eeb12ae947a228de4c8120
+DIST ffmpeg-0.6_p25423.tar.bz2 3965683 RMD160 79e9ebd2adc2d3f6ef7188c096b90387ae7091c4 SHA1 cc60a2cc5a422e2d94122a0d2b85ba2758467a87 SHA256 6768814cd0fd6d6f118053a421e35347d3021575c75cbd7488be1342f339a9e8
 EBUILD ffmpeg-0.5_p20373.ebuild 7761 RMD160 872bb18a1eabab4c81cea1d4cf4f1283b14f4c34 SHA1 270130d83e1a5230102e2add113b9f3bbfe7a564 SHA256 81f73aa9857663d18734f0881bd5d8b648f9228dcec10a2dfb08bef262a1c1e9
 EBUILD ffmpeg-0.5_p22846.ebuild 7608 RMD160 d4a4c505829c6fd6c93e1e6ec465028a0997989e SHA1 46e7764045594b636d0eb6179f464e3f378b4895 SHA256 227cbee58e559eab07d0d97dbccbd2212b56be6c60cc7a57436894ac3b10e63d
 EBUILD ffmpeg-0.6.ebuild 7784 RMD160 a00616a9b94c33923aff22c8ae5ab6e3e57f3fcf SHA1 452a4f35f2015ea9b886658c9493f285b6777e49 SHA256 dda62f682aa8eac89ad96e7bd687fa42b9a1241529698658a57bf3c740b4520a
+EBUILD ffmpeg-0.6_p25423.ebuild 7888 RMD160 54e383f791e47363435ac124a2f0eed226424012 SHA1 7f7a48c07bc7ace97c5f5cb473ac48ed60ab9f5b SHA256 53a70dd2ec43c8bf771de5358ac014902099be7f125aaf552f5b2814340021ef
 EBUILD ffmpeg-9999.ebuild 7914 RMD160 2b04b839d28c3df22cbabcc2e1b5392d1c4e34a6 SHA1 121ecafc84e4ee8cff3b28d4ec374f68452a60af SHA256 df255584ab0485a87736c1b0e18ab48e7ac06cd0365249f6f725e9d37fe397b7
-MISC ChangeLog 55875 RMD160 7915b25750b075b3c4d509e6787ec2f0730438f6 SHA1 26a8574949067478531fcbaa3c11dc5ddd704c38 SHA256 237da9e07459bdacab147381f792024e3a31533b0ded0e4bec3fbb7aa927af20
+MISC ChangeLog 56065 RMD160 a64eb12e99c407ac3692bda3c4c388310e542f08 SHA1 44c0b8725e2bdcdb9b0617a3f8b0aaf56f7ef473 SHA256 475a393e4e569d39aa0e991905b2deb4877338332ef4ab90a567e71bf824c0d3
 MISC metadata.xml 2116 RMD160 881f00e64f73bbdd20d5017bba99d34fb96e7d6a SHA1 17780b8d193967be4835ff2fee71f3bcd6ff77f4 SHA256 f5ff02d46c6d928807a03062eeee3320eba15682f5b0a2f633e07d7c2340fe08
+-----BEGIN PGP SIGNATURE-----
+Version: GnuPG v2.0.16 (GNU/Linux)
+
+iEYEARECAAYFAkywcdMACgkQvFcC4BYPU0pDHQCfXZs8f8SSt7Fo46RJUhJtUGsA
+rQsAoMisK2AEfaujncgL9CeTMh49rYxH
+=lx3k
+-----END PGP SIGNATURE-----
diff --git a/media-video/ffmpeg/ffmpeg-0.6_p25423.ebuild b/media-video/ffmpeg/ffmpeg-0.6_p25423.ebuild
new file mode 100644
index 000000000000..9c3372c71360
--- /dev/null
+++ b/media-video/ffmpeg/ffmpeg-0.6_p25423.ebuild
@@ -0,0 +1,265 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ffmpeg-0.6_p25423.ebuild,v 1.1 2010/10/09 13:44:21 aballier Exp $
+
+EAPI="2"
+
+SCM=""
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SCM="subversion"
+	ESVN_REPO_URI="svn://svn.ffmpeg.org/ffmpeg/trunk"
+fi
+
+inherit eutils flag-o-matic multilib toolchain-funcs ${SCM}
+
+DESCRIPTION="Complete solution to record, convert and stream audio and video. Includes libavcodec."
+HOMEPAGE="http://ffmpeg.org/"
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SRC_URI=""
+elif [ "${PV%_p*}" != "${PV}" ] ; then # Snapshot
+	SRC_URI="mirror://gentoo/${P}.tar.bz2"
+else # Release
+	SRC_URI="http://ffmpeg.org/releases/${P}.tar.bz2"
+fi
+FFMPEG_REVISION="${PV#*_p}"
+
+LICENSE="GPL-3"
+SLOT="0"
+if [ "${PV#9999}" = "${PV}" ] ; then
+	KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+fi
+IUSE="+3dnow +3dnowext alsa altivec amr bindist +bzip2 cpudetection custom-cflags debug dirac doc +encode faac frei0r gsm +hardcoded-tables ieee1394 jack jpeg2k +mmx +mmxext mp3 network oss pic qt-faststart rtmp schroedinger sdl speex +ssse3 static-libs test theora threads v4l v4l2 vaapi vdpau vorbis vpx X x264 xvid +zlib"
+
+VIDEO_CARDS="nvidia"
+
+for x in ${VIDEO_CARDS}; do
+	IUSE="${IUSE} video_cards_${x}"
+done
+
+RDEPEND="
+	alsa? ( media-libs/alsa-lib )
+	amr? ( media-libs/opencore-amr )
+	bzip2? ( app-arch/bzip2 )
+	dirac? ( media-video/dirac )
+	encode? (
+		faac? ( media-libs/faac )
+		mp3? ( media-sound/lame )
+		theora? ( >=media-libs/libtheora-1.1.1[encode] media-libs/libogg )
+		vorbis? ( media-libs/libvorbis media-libs/libogg )
+		x264? ( >=media-libs/x264-0.0.20100605 )
+		xvid? ( >=media-libs/xvid-1.1.0 )
+	)
+	frei0r? ( media-plugins/frei0r-plugins )
+	gsm? ( >=media-sound/gsm-1.0.12-r1 )
+	ieee1394? ( media-libs/libdc1394 sys-libs/libraw1394 )
+	jack? ( media-sound/jack-audio-connection-kit )
+	jpeg2k? ( >=media-libs/openjpeg-1.3-r2 )
+	rtmp? ( media-video/rtmpdump )
+	sdl? ( >=media-libs/libsdl-1.2.13-r1[audio,video] )
+	schroedinger? ( media-libs/schroedinger )
+	speex? ( >=media-libs/speex-1.2_beta3 )
+	vaapi? ( x11-libs/libva )
+	video_cards_nvidia? ( vdpau? ( x11-libs/libvdpau ) )
+	vpx? ( media-libs/libvpx )
+	X? ( x11-libs/libX11 x11-libs/libXext )
+	zlib? ( sys-libs/zlib )
+	!media-video/qt-faststart
+"
+
+DEPEND="${RDEPEND}
+	>=sys-devel/make-3.81
+	dirac? ( dev-util/pkgconfig )
+	doc? ( app-text/texi2html )
+	mmx? ( dev-lang/yasm )
+	rtmp? ( dev-util/pkgconfig )
+	schroedinger? ( dev-util/pkgconfig )
+	test? ( net-misc/wget )
+	v4l? ( sys-kernel/linux-headers )
+	v4l2? ( sys-kernel/linux-headers )
+"
+
+src_prepare() {
+	if [ "${PV#9999}" != "${PV}" ] ; then
+		# Set SVN version manually
+		subversion_wc_info
+		sed -i -e "s/UNKNOWN/SVN-r${ESVN_WC_REVISION}/" "${S}/version.sh" || die
+	elif [ "${PV%_p*}" != "${PV}" ] ; then # Snapshot
+		sed -i -e "s/UNKNOWN/SVN-r${FFMPEG_REVISION}/" "${S}/version.sh" || die
+	fi
+}
+
+src_configure() {
+	local myconf="${EXTRA_FFMPEG_CONF}"
+
+	# enabled by default
+	for i in debug doc network vaapi zlib; do
+		use ${i} || myconf="${myconf} --disable-${i}"
+	done
+	use bzip2 || myconf="${myconf} --disable-bzlib"
+	use sdl || myconf="${myconf} --disable-ffplay"
+	use static-libs || myconf="${myconf} --disable-static"
+
+	use custom-cflags && myconf="${myconf} --disable-optimizations"
+	use cpudetection && myconf="${myconf} --enable-runtime-cpudetect"
+
+	#for i in h264_vdpau mpeg1_vdpau mpeg_vdpau vc1_vdpau wmv3_vdpau; do
+	#	use video_cards_nvidia || myconf="${myconf} --disable-decoder=${i}"
+	#	use vdpau || myconf="${myconf} --disable-decoder=${i}"
+	#done
+	use video_cards_nvidia && use vdpau || myconf="${myconf} --disable-vdpau"
+
+	# Encoders
+	if use encode
+	then
+		use mp3 && myconf="${myconf} --enable-libmp3lame"
+		for i in theora vorbis x264 xvid; do
+			use ${i} && myconf="${myconf} --enable-lib${i}"
+		done
+		if use bindist
+		then
+			use faac && ewarn "faac is nonfree and cannot be distributed;
+			disabling faac support."
+		else
+			use faac && myconf="${myconf} --enable-libfaac --enable-nonfree"
+		fi
+	else
+		myconf="${myconf} --disable-encoders"
+	fi
+
+	# libavdevice options
+	use ieee1394 && myconf="${myconf} --enable-libdc1394"
+	# Indevs
+	for i in v4l v4l2 alsa oss jack ; do
+		use ${i} || myconf="${myconf} --disable-indev=${i}"
+	done
+	use X && myconf="${myconf} --enable-x11grab"
+	# Outdevs
+	for i in alsa oss ; do
+		use ${i} || myconf="${myconf} --disable-outdev=${i}"
+	done
+	# libavfilter options
+	use frei0r && myconf="${myconf} --enable-frei0r"
+
+	# Threads; we only support pthread for now but ffmpeg supports more
+	use threads && myconf="${myconf} --enable-pthreads"
+
+	# Decoders
+	use amr && myconf="${myconf} --enable-libopencore-amrwb --enable-libopencore-amrnb"
+	for i in gsm dirac rtmp schroedinger speex vpx; do
+		use ${i} && myconf="${myconf} --enable-lib${i}"
+	done
+	use jpeg2k && myconf="${myconf} --enable-libopenjpeg"
+
+	# CPU features
+	for i in mmx ssse3 altivec ; do
+		use ${i} || myconf="${myconf} --disable-${i}"
+	done
+	use mmxext || myconf="${myconf} --disable-mmx2"
+	use 3dnow || myconf="${myconf} --disable-amd3dnow"
+	use 3dnowext || myconf="${myconf} --disable-amd3dnowext"
+	# disable mmx accelerated code if PIC is required
+	# as the provided asm decidedly is not PIC for x86.
+	if use pic && use x86 ; then
+		myconf="${myconf} --disable-mmx --disable-mmx2"
+	fi
+
+	# Option to force building pic
+	use pic && myconf="${myconf} --enable-pic"
+
+	# Try to get cpu type based on CFLAGS.
+	# Bug #172723
+	# We need to do this so that features of that CPU will be better used
+	# If they contain an unknown CPU it will not hurt since ffmpeg's configure
+	# will just ignore it.
+	for i in $(get-flag march) $(get-flag mcpu) $(get-flag mtune) ; do
+		[ "${i}" = "native" ] && i="host" # bug #273421
+		[[ ${i} = *-sse3 ]] && i="${i%-sse3}" # bug 283968
+		myconf="${myconf} --cpu=${i}"
+		break
+	done
+
+	# Mandatory configuration
+	myconf="
+		--enable-gpl
+		--enable-version3
+		--enable-postproc
+		--enable-avfilter
+		--disable-stripping
+		${myconf}"
+
+	# cross compile support
+	if tc-is-cross-compiler ; then
+		myconf="${myconf} --enable-cross-compile --arch=$(tc-arch-kernel) --cross-prefix=${CHOST}-"
+		case ${CHOST} in
+			*freebsd*)
+				myconf="${myconf} --target-os=freebsd"
+				;;
+			mingw32*)
+				myconf="${myconf} --target-os=mingw32"
+				;;
+			*linux*)
+				myconf="${myconf} --target-os=linux"
+				;;
+		esac
+	fi
+
+	# Misc stuff
+	use hardcoded-tables && myconf="${myconf} --enable-hardcoded-tables"
+
+	# Specific workarounds for too-few-registers arch...
+	if [[ $(tc-arch) == "x86" ]]; then
+		filter-flags -fforce-addr -momit-leaf-frame-pointer
+		append-flags -fomit-frame-pointer
+		is-flag -O? || append-flags -O2
+		if (use debug); then
+			# no need to warn about debug if not using debug flag
+			ewarn ""
+			ewarn "Debug information will be almost useless as the frame pointer is omitted."
+			ewarn "This makes debugging harder, so crashes that has no fixed behavior are"
+			ewarn "difficult to fix. Please have that in mind."
+			ewarn ""
+		fi
+	fi
+
+	cd "${S}"
+	./configure \
+		--prefix=/usr \
+		--libdir=/usr/$(get_libdir) \
+		--shlibdir=/usr/$(get_libdir) \
+		--mandir=/usr/share/man \
+		--enable-static --enable-shared \
+		--cc="$(tc-getCC)" \
+		${myconf} || die
+}
+
+src_compile() {
+	emake version.h || die #252269
+	emake || die
+
+	if use qt-faststart; then
+		tc-export CC
+		emake -C tools qt-faststart || die
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install install-man || die
+
+	dodoc Changelog README INSTALL
+	dodoc doc/*
+
+	if use qt-faststart; then
+		dobin tools/qt-faststart || die
+	fi
+}
+
+src_test() {
+	if use encode ; then
+		for t in codectest lavftest seektest ; do
+			LD_LIBRARY_PATH="${S}/libpostproc:${S}/libswscale:${S}/libavcodec:${S}/libavdevice:${S}/libavfilter:${S}/libavformat:${S}/libavutil" \
+				emake ${t} || die "Some tests in ${t} failed"
+		done
+	else
+		ewarn "Tests fail without USE=encode, skipping"
+	fi
+}