[kde-base] Add long waiting KDE SC 4.7.4

Package-Manager: portage-2.2.0_alpha79/cvs/Linux x86_64

2 files changed, 72 insertions, 1 deletions

diff --git a/kde-base/kdeplasma-addons/ChangeLog b/kde-base/kdeplasma-addons/ChangeLog
index 7405562706a3..99151c2899e3 100644
--- a/kde-base/kdeplasma-addons/ChangeLog
+++ b/kde-base/kdeplasma-addons/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for kde-base/kdeplasma-addons
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kdeplasma-addons/ChangeLog,v 1.111 2011/12/07 23:07:41 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdeplasma-addons/ChangeLog,v 1.112 2011/12/11 18:52:16 alexxy Exp $
+
+*kdeplasma-addons-4.7.4 (11 Dec 2011)
+
+  11 Dec 2011; Alexey Shvetsov <alexxy@gentoo.org>
+  +kdeplasma-addons-4.7.4.ebuild:
+  Version bump KDE SC 4.7.4
 
   07 Dec 2011; Andreas K. Huettel <dilfridge@gentoo.org>
   -kdeplasma-addons-4.7.2.ebuild:
diff --git a/kde-base/kdeplasma-addons/kdeplasma-addons-4.7.4.ebuild b/kde-base/kdeplasma-addons/kdeplasma-addons-4.7.4.ebuild
new file mode 100644
index 000000000000..2001f31caebd
--- /dev/null
+++ b/kde-base/kdeplasma-addons/kdeplasma-addons-4.7.4.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdeplasma-addons/kdeplasma-addons-4.7.4.ebuild,v 1.1 2011/12/11 18:52:16 alexxy Exp $
+
+EAPI=4
+
+KDE_SCM="git"
+inherit kde4-base
+
+DESCRIPTION="Extra Plasma applets and engines."
+HOMEPAGE="http://www.kde.org/"
+LICENSE="GPL-2 LGPL-2"
+
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="attica debug desktopglobe exif qalculate qwt scim semantic-desktop"
+
+# krunner is only needed to generate dbus interface for lancelot
+COMMON_DEPEND="
+	app-crypt/qca:2
+	app-crypt/qca-ossl:2
+	$(add_kdebase_dep kdelibs 'semantic-desktop=')
+	$(add_kdebase_dep krunner)
+	$(add_kdebase_dep plasma-workspace 'semantic-desktop=')
+	x11-misc/shared-mime-info
+	attica? ( dev-libs/libattica )
+	desktopglobe? ( $(add_kdebase_dep marble) )
+	exif? ( $(add_kdebase_dep libkexiv2) )
+	qalculate? ( sci-libs/libqalculate )
+	qwt? ( x11-libs/qwt:5 )
+	scim? ( app-i18n/scim )
+	semantic-desktop? (
+		$(add_kdebase_dep kdepimlibs 'semantic-desktop')
+		$(add_kdebase_dep plasma-workspace 'rss')
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	dev-cpp/eigen:2
+"
+RDEPEND="${COMMON_DEPEND}
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-4.7.3-knowledge.patch"
+)
+
+src_prepare() {
+	use semantic-desktop || epatch "${FILESDIR}/${PN}-4.6.2-optional-akonadi.patch"
+	kde4-base_src_prepare
+}
+
+src_configure() {
+	mycmakeargs=(
+		-DDBUS_INTERFACES_INSTALL_DIR="${EPREFIX}/usr/share/dbus-1/interfaces/"
+		$(cmake-utils_use_with attica LibAttica)
+		$(cmake-utils_use_with desktopglobe Marble)
+		$(cmake-utils_use_with exif Kexiv2)
+		$(cmake-utils_use_with qalculate)
+		$(cmake-utils_use_with qwt)
+		$(cmake-utils_use_with semantic-desktop KdepimLibs)
+		$(cmake-utils_use_with semantic-desktop Nepomuk)
+		$(cmake-utils_use_with scim)
+	)
+
+	kde4-base_src_configure
+}