Bump

Package-Manager: portage-2.2_rc33/cvs/Linux x86_64

8 files changed, 218 insertions, 4 deletions

diff --git a/dev-libs/poppler-glib/ChangeLog b/dev-libs/poppler-glib/ChangeLog
index b5df38daeaa0..560f5828ba61 100644
--- a/dev-libs/poppler-glib/ChangeLog
+++ b/dev-libs/poppler-glib/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/poppler-glib
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/poppler-glib/ChangeLog,v 1.10 2009/06/16 20:24:44 klausman Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/poppler-glib/ChangeLog,v 1.11 2009/06/19 22:15:41 loki_val Exp $
+
+*poppler-glib-0.11.1 (19 Jun 2009)
+
+  19 Jun 2009; Peter Alfredsen <loki_val@gentoo.org>
+  +poppler-glib-0.11.1.ebuild:
+  Bump
 
   16 Jun 2009; Tobias Klausmann <klausman@gentoo.org>
   poppler-glib-0.10.7.ebuild:
diff --git a/dev-libs/poppler-glib/poppler-glib-0.11.1.ebuild b/dev-libs/poppler-glib/poppler-glib-0.11.1.ebuild
new file mode 100644
index 000000000000..e8ae0d141ae0
--- /dev/null
+++ b/dev-libs/poppler-glib/poppler-glib-0.11.1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/poppler-glib/poppler-glib-0.11.1.ebuild,v 1.1 2009/06/19 22:15:41 loki_val Exp $
+
+EAPI=2
+
+POPPLER_MODULE=glib
+
+inherit poppler flag-o-matic
+
+DESCRIPTION="Glib bindings for poppler"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="+cairo"
+
+# The Cairo renderer represents a superset of the splash renderer.
+# We could also have a gtk use-flag for the interface to gdk-pixbuf, but that wouldn't
+# make sense for us, because:
+# 1. Every app that is ok with only [cairo] is already depending on gtk+:2 :
+#	media-gfx/inkscape
+#	app-text/evince
+# 2. Cairo is a dependency of gtk+:2
+# 3. gdk and gdk-pixbuf is the old way of doing things. Everybody is hot for cairo.
+# 4. In fact, the only app that's ok with [-cairo,-gtk] is app-misc/tracker.
+
+RDEPEND="
+	~dev-libs/poppler-${PV}
+	>=dev-libs/glib-2.16
+	cairo? (
+		>=x11-libs/cairo-1.8.4
+		>=x11-libs/gtk+-2.14.0:2
+	)
+	"
+DEPEND="
+	${RDEPEND}
+	dev-util/pkgconfig
+	"
+
+pkg_setup() {
+	POPPLER_CONF="$(use_enable cairo cairo-output) $(use_enable cairo gdk) $(use_enable cairo splash-output)"
+	POPPLER_PKGCONFIG=( poppler-glib.pc cairo=poppler-cairo.pc )
+	if ! use cairo
+	then
+		export CPPFLAGS="${CPPFLAGS} -DHAVE_SPLASH" poppler_src_compile
+	fi
+}
+
+src_prepare() {
+	poppler_src_prepare
+	sed -i	\
+		-e 's:reference::'	\
+		-e 's:demo::'		\
+		-e '/DISABLE_DEPRECATED/d' \
+		glib/Makefile.in || die "Fixing glib Makefile.in failed"
+	use cairo || { sed -i -e 's:gdk-2.0 gdk-pixbuf-2.0 ::' poppler-glib.pc.in || die "Sedding poppler-glib.pc.in failed" ; }
+}
+
+src_compile() {
+	use cairo && POPPLER_MODULE_S="${S}/poppler" poppler_src_compile libpoppler-cairo.la
+	poppler_src_compile
+}
diff --git a/dev-libs/poppler-qt3/ChangeLog b/dev-libs/poppler-qt3/ChangeLog
index 7d51e0640ead..4e9e9d81bc9a 100644
--- a/dev-libs/poppler-qt3/ChangeLog
+++ b/dev-libs/poppler-qt3/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/poppler-qt3
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/poppler-qt3/ChangeLog,v 1.11 2009/06/16 20:25:31 klausman Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/poppler-qt3/ChangeLog,v 1.12 2009/06/19 22:14:31 loki_val Exp $
+
+*poppler-qt3-0.11.1 (19 Jun 2009)
+
+  19 Jun 2009; Peter Alfredsen <loki_val@gentoo.org>
+  +poppler-qt3-0.11.1.ebuild:
+  Bump
 
   16 Jun 2009; Tobias Klausmann <klausman@gentoo.org>
   poppler-qt3-0.10.7.ebuild:
diff --git a/dev-libs/poppler-qt3/poppler-qt3-0.11.1.ebuild b/dev-libs/poppler-qt3/poppler-qt3-0.11.1.ebuild
new file mode 100644
index 000000000000..319486c336cf
--- /dev/null
+++ b/dev-libs/poppler-qt3/poppler-qt3-0.11.1.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/poppler-qt3/poppler-qt3-0.11.1.ebuild,v 1.1 2009/06/19 22:14:31 loki_val Exp $
+
+EAPI=2
+
+POPPLER_MODULE=qt
+POPPLER_PKGCONFIG=poppler-qt.pc
+POPPLER_CONF="--enable-poppler-qt"
+
+inherit qt3 poppler
+
+DESCRIPTION="Qt3 bindings for poppler"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE=""
+
+RDEPEND="
+	~dev-libs/poppler-${PV}
+	>=x11-libs/qt-3.3:3
+	"
+DEPEND="
+	${RDEPEND}
+	"
+
+src_compile() {
+	poppler_src_compile POPPLER_QT_LIBS="$(pkg-config --libs qt-mt)"
+}
diff --git a/dev-libs/poppler-qt4/ChangeLog b/dev-libs/poppler-qt4/ChangeLog
index 80a20fe2a815..825e17ff9673 100644
--- a/dev-libs/poppler-qt4/ChangeLog
+++ b/dev-libs/poppler-qt4/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/poppler-qt4
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/poppler-qt4/ChangeLog,v 1.10 2009/06/16 20:26:19 klausman Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/poppler-qt4/ChangeLog,v 1.11 2009/06/19 22:14:54 loki_val Exp $
+
+*poppler-qt4-0.11.1 (19 Jun 2009)
+
+  19 Jun 2009; Peter Alfredsen <loki_val@gentoo.org>
+  +poppler-qt4-0.11.1.ebuild:
+  Bump
 
   16 Jun 2009; Tobias Klausmann <klausman@gentoo.org>
   poppler-qt4-0.10.7.ebuild:
diff --git a/dev-libs/poppler-qt4/poppler-qt4-0.11.1.ebuild b/dev-libs/poppler-qt4/poppler-qt4-0.11.1.ebuild
new file mode 100644
index 000000000000..518b6382c4f7
--- /dev/null
+++ b/dev-libs/poppler-qt4/poppler-qt4-0.11.1.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/poppler-qt4/poppler-qt4-0.11.1.ebuild,v 1.1 2009/06/19 22:14:54 loki_val Exp $
+
+EAPI=2
+
+POPPLER_MODULE=qt4/src
+POPPLER_PKGCONFIG=poppler-qt4.pc
+
+inherit poppler
+
+DESCRIPTION="Qt4 bindings for poppler"
+SRC_URI="${SRC_URI}
+	test? ( mirror://gentoo/poppler-test-0.9.2.tar.bz2 )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="test"
+
+RDEPEND="
+	~dev-libs/poppler-${PV}
+	>=x11-libs/qt-core-4.4.2:4
+	>=x11-libs/qt-gui-4.4.2:4
+	>=x11-libs/qt-test-4.4.2:4
+	"
+DEPEND="
+	${RDEPEND}
+	"
+
+src_compile() {
+	POPPLER_MODULE_S="${S}/poppler" poppler_src_compile libpoppler-arthur.la
+	poppler_src_compile
+	use test && POPPLER_MODULE_S="${S}/qt4/tests" poppler_src_compile
+}
+
+src_test() {
+	cd "${S}/qt4/tests"
+	emake check
+}
diff --git a/dev-libs/poppler/ChangeLog b/dev-libs/poppler/ChangeLog
index d604b69ef26c..5c941c719e1f 100644
--- a/dev-libs/poppler/ChangeLog
+++ b/dev-libs/poppler/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/poppler
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/poppler/ChangeLog,v 1.9 2009/06/16 20:23:58 klausman Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/poppler/ChangeLog,v 1.10 2009/06/19 22:15:17 loki_val Exp $
+
+*poppler-0.11.1 (19 Jun 2009)
+
+  19 Jun 2009; Peter Alfredsen <loki_val@gentoo.org> +poppler-0.11.1.ebuild:
+  Bump
 
   16 Jun 2009; Tobias Klausmann <klausman@gentoo.org> poppler-0.10.7.ebuild:
   Stable on alpha, bug #272980
diff --git a/dev-libs/poppler/poppler-0.11.1.ebuild b/dev-libs/poppler/poppler-0.11.1.ebuild
new file mode 100644
index 000000000000..7d2f092cc492
--- /dev/null
+++ b/dev-libs/poppler/poppler-0.11.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/poppler/poppler-0.11.1.ebuild,v 1.1 2009/06/19 22:15:17 loki_val Exp $
+
+EAPI=2
+
+POPPLER_MODULE=poppler
+
+inherit poppler
+
+DESCRIPTION="PDF rendering library based on the xpdf-3.0 code base"
+HOMEPAGE="http://poppler.freedesktop.org/"
+SRC_URI="http://poppler.freedesktop.org/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="+abiword +lcms +poppler-data"
+
+DEPEND="
+	abiword? ( >=dev-libs/libxml2-2.7.2 )
+	lcms? ( >=media-libs/lcms-1.18 )
+	>=media-libs/freetype-2.3.7
+	>=media-libs/fontconfig-2
+	>=media-libs/jpeg-6b
+	>=media-libs/openjpeg-1.3-r2
+	sys-libs/zlib
+	"
+RDEPEND="
+	${DEPEND}
+	poppler-data? ( >=app-text/poppler-data-0.2.1 )
+	!<dev-libs/poppler-qt3-${PV}
+	!<dev-libs/poppler-qt4-${PV}
+	!<dev-libs/poppler-glib-${PV}
+	!<app-text/poppler-utils-${PV}
+	"
+
+pkg_setup() {
+	POPPLER_CONF="	$(use_enable abiword abiword-output)
+			$(use_enable lcms cms)
+			--disable-poppler-qt4
+			--disable-cairo-output"
+	POPPLER_PKGCONFIG=( "poppler-splash.pc" "poppler.pc" )
+}
+
+src_compile() {
+	for dir in goo fofi splash poppler
+	do
+		POPPLER_MODULE_S="${S}/${dir}" poppler_src_compile
+	done
+}
+
+src_install() {
+	for dir in goo fofi splash poppler
+	do
+		POPPLER_MODULE_S="${S}/${dir}" poppler_src_install
+	done
+}