Added patch to fix compilation problems for projects depending on log4cxx (bug #162523, thanks to Pedro). Dropped old versions.

Package-Manager: portage-2.1.2.2

1 files changed, 85 insertions, 0 deletions

diff --git a/dev-libs/log4cxx/log4cxx-0.9.7-r4.ebuild b/dev-libs/log4cxx/log4cxx-0.9.7-r4.ebuild
new file mode 100644
index 000000000000..97010ced943d
--- /dev/null
+++ b/dev-libs/log4cxx/log4cxx-0.9.7-r4.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/log4cxx/log4cxx-0.9.7-r4.ebuild,v 1.1 2007/03/15 22:48:29 dev-zero Exp $
+
+WANT_AUTOCONF="2.5"
+WANT_AUTOMAKE="latest"
+
+inherit autotools eutils flag-o-matic
+
+KEYWORDS="~amd64 ~x86"
+
+DESCRIPTION="Library of C++ classes for flexible logging to files, syslog and other destinations"
+HOMEPAGE="http://logging.apache.org/log4cxx/"
+SRC_URI="http://www.apache.org/dist/logging/${PN}/${P}.tar.gz"
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="doc iodbc unicode odbc smtp threads"
+
+RDEPEND="dev-libs/boost
+		dev-libs/libxml2
+		odbc? (
+			iodbc? ( >=dev-db/libiodbc-3.52.4 )
+			!iodbc? ( dev-db/unixODBC ) )
+		smtp? ( dev-libs/libsmtp )"
+DEPEND="${RDEPEND}
+		doc? ( app-doc/doxygen media-gfx/graphviz )"
+
+pkg_setup() {
+	if use iodbc && ! use odbc ; then
+		elog "Please enable the odbc USE-flag as well if you want odbc-support through iodbc."
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	sed -i \
+		-e "s:\(htmldir = \).*\(/html\):\1\$(datadir)/doc/${PF}\2:" \
+		docs/Makefile.am || die "sed failed"
+
+	epatch "${FILESDIR}/${P}-gentoo.diff"
+
+	if use unicode && use odbc ; then
+		epatch "${FILESDIR}/${P}-use-SQLWCHAR.diff"
+	fi
+
+	epatch "${FILESDIR}/${P}-gcc41.patch"
+	epatch "${FILESDIR}/${P}-tchar.patch"
+	eautoreconf
+}
+
+src_compile() {
+	# has cppunit support, but make check builds nothing...
+	local myconf="--disable-cppunit"
+	use doc && myconf="${myconf} --enable-doxygen --enable-dot
+		--enable-html-docs" || \
+		myconf="${myconf} --disable-doxygen --disable-dot --disable-html-docs"
+	use smtp && myconf="${myconf} --with-SMTP=libsmtp"
+	if use odbc ; then
+		if use iodbc ; then
+			myconf="${myconf} --with-ODBC=iODBC"
+		else
+			myconf="${myconf} --with-ODBC=unixODBC"
+		fi
+	fi
+	# it's broken, so we must do this rather than use_enable
+	use unicode && myconf="${myconf} --enable-unicode"
+	use threads && myconf="${myconf} --with-thread=pthread"
+
+	if use unicode && use odbc ; then
+		# fix some warnings as w/o it TCHAR gets typedef'd to signed short
+		# instead of wchar_t
+		append-flags -DSQL_WCHART_CONVERT
+	fi
+
+	econf \
+		--with-XML=libxml2 \
+		${myconf} || die "econf failed"
+	emake -j1 || die "emake failed"
+}
+
+src_install () {
+	emake DESTDIR="${D}" install || die "make install failed"
+	dodoc AUTHORS ChangeLog README
+}