Fix a few IDE issues related to the -drive option. fixes #332993

Package-Manager: portage-2.1.8.3/cvs/Linux x86_64

3 files changed, 253 insertions, 2 deletions

diff --git a/app-emulation/qemu-kvm/ChangeLog b/app-emulation/qemu-kvm/ChangeLog
index 80e07aea2c16..7dff451496e7 100644
--- a/app-emulation/qemu-kvm/ChangeLog
+++ b/app-emulation/qemu-kvm/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-emulation/qemu-kvm
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu-kvm/ChangeLog,v 1.36 2010/08/12 08:49:51 dev-zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu-kvm/ChangeLog,v 1.37 2010/08/26 21:02:46 cardoe Exp $
+
+*qemu-kvm-0.12.5-r1 (26 Aug 2010)
+
+  26 Aug 2010; Doug Goldstein <cardoe@gentoo.org>
+  +qemu-kvm-0.12.5-r1.ebuild:
+  Fix a few IDE issues related to the -drive option. fixes #332993
 
   12 Aug 2010; Tiziano Müller <dev-zero@gentoo.org>
   qemu-kvm-0.11.1-r1.ebuild, qemu-kvm-0.12.3-r1.ebuild,
diff --git a/app-emulation/qemu-kvm/Manifest b/app-emulation/qemu-kvm/Manifest
index 4fb2ff9aa1a8..b8ce95094092 100644
--- a/app-emulation/qemu-kvm/Manifest
+++ b/app-emulation/qemu-kvm/Manifest
@@ -8,11 +8,13 @@ AUX qemu-kvm-0.12.4-large-virtio-corruption.patch 1291 RMD160 66ae04ddfbb6d2e6ce
 DIST qemu-kvm-0.11.1.tar.gz 4384334 RMD160 0f945f1812b3a42a5642698d2f15bd8f456612f8 SHA1 291d0b771feb4c67bce71d393868a6d1a1db345b SHA256 7df5b589fabb1f0f35a06abce7e34c81574e09ade538ba883ef5b43ccbd8458b
 DIST qemu-kvm-0.12.3.tar.gz 4718791 RMD160 fe88117e6e32188e097a86f95bffc4b74422a5e6 SHA1 235a790056a1b751791e64dd499129b2dbf55be8 SHA256 77cccdc8938b33f3ed74763d01deaad58918c85f04a06afd10f00857b504c2b2
 DIST qemu-kvm-0.12.4.tar.gz 4720232 RMD160 63a18ff3b95de2b4d0dfac130cf850c1cd7caec0 SHA1 955c8dad1f65df0eb5403f40a6c92d93a0a252be SHA256 1489fe5a0def7b857256817a998768bb21662167d10e7c372312c5939e64181e
+DIST qemu-kvm-0.12.5-backports-1.tar.bz2 3668 RMD160 59e1d7e3d64377e2b77faf26c45206fbde4ee847 SHA1 5a4eb644243d11a96c2430546f7335c780ec9243 SHA256 c822969f0a86106d5cba97fae33c76eeea0bcc3ea13d617647474557ed0e4dbf
 DIST qemu-kvm-0.12.5.tar.gz 4722351 RMD160 dc2686e70384a40601589cac2f2665254240710a SHA1 c316ac8a1b040e28275bf34911fbce14209c1563 SHA256 24c085aecbc784ea8b4837ca02bfe5086c7f91c8a88a0f607826692234af583f
 EBUILD qemu-kvm-0.11.1-r1.ebuild 5834 RMD160 14a6c25f17ca1585e6ae214faabbee03836c46be SHA1 fdd7b21a81beb3ab0e90631f995778bfe02c2b66 SHA256 5b13106de57e452c3b5b13e86b9eb472ed299442ab501c74e1a193b743bc0e2b
 EBUILD qemu-kvm-0.12.3-r1.ebuild 7490 RMD160 6e1372313a61822b6aa8aecd2adbb96aceced6e7 SHA1 97de1efe8be68f47f367988c463244d9201e409d SHA256 52f6e7351467fece7504b5a2a9641d737656213f68bdb82c6ac2c128873425af
 EBUILD qemu-kvm-0.12.4-r1.ebuild 7502 RMD160 c16a2e641bd879b8eabf27c2e317d250f3554d5f SHA1 e2bc0954389e96d01ef8ecc5f0e32797477f37eb SHA256 33c99cb7f99a73c9845ddfc0565c0d1a1c0b6ba3a2d25d3239c21912a2fbcb25
+EBUILD qemu-kvm-0.12.5-r1.ebuild 7639 RMD160 17d66051f497346ba3c1d5581abbfbab3a931099 SHA1 15955b33d8849c1e9a9d5c2cc0c43e23f662092e SHA256 1215552f067b11312c57f2424116a34d2ea22df71c7621665095cfc14b6b2a84
 EBUILD qemu-kvm-0.12.5.ebuild 7639 RMD160 f9ddc850b4f35539834de213f6063875ea1a7233 SHA1 702e1638d36b27c2571e08551268da087ca168ca SHA256 fa61415340a418deee2f100e245b674922e1e7816749ac8c26912bb2497b5ea8
 EBUILD qemu-kvm-9999.ebuild 7610 RMD160 031ed377373a4a683e534bf15d97a7f696979cbb SHA1 7c123820b986ecde8692bc8c7b2bcfa5aed39f01 SHA256 6f4506ab7d2867d447701a41f17cc78d15647221a51d2ec7ff138b0fcf9b1ead
-MISC ChangeLog 7983 RMD160 8819a863892022b01ea40422e387a815feaed82c SHA1 82454f936b9f80a176fb5731c7db576d6cb54d42 SHA256 62a82478ab31fce430279b99d46f3ef5d5c4bd8f67d9ce599dbf927009241c3a
+MISC ChangeLog 8164 RMD160 578a608e16fea6e61b091c72809d33f3bc1b3577 SHA1 985ec625a6a765b0638e92b96fb4e050e0dd1060 SHA256 6e2ca809ffdc130f9d19576c9389b3b5ee18f65d3362d25883cd24fe1bbb9723
 MISC metadata.xml 978 RMD160 2e120b8332c7fc1d6b4baa4149b0f13a73c74fb2 SHA1 5fe37c22d64ca52ef6d26debc46b23b415e04a7a SHA256 76676f1a327e743dd3579109250ace6012ac93ffea5d1daab0a24b194b55164f
diff --git a/app-emulation/qemu-kvm/qemu-kvm-0.12.5-r1.ebuild b/app-emulation/qemu-kvm/qemu-kvm-0.12.5-r1.ebuild
new file mode 100644
index 000000000000..bd21b3723196
--- /dev/null
+++ b/app-emulation/qemu-kvm/qemu-kvm-0.12.5-r1.ebuild
@@ -0,0 +1,243 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu-kvm/qemu-kvm-0.12.5-r1.ebuild,v 1.1 2010/08/26 21:02:46 cardoe Exp $
+
+BACKPORTS=1
+
+EAPI="2"
+
+if [[ ${PV} = *9999* ]]; then
+	EGIT_REPO_URI="git://git.kernel.org/pub/scm/virt/kvm/qemu-kvm.git"
+	GIT_ECLASS="git"
+fi
+
+inherit eutils flag-o-matic ${GIT_ECLASS} linux-info toolchain-funcs
+
+if [[ ${PV} = *9999* ]]; then
+	SRC_URI=""
+	KEYWORDS=""
+else
+	SRC_URI="mirror://sourceforge/kvm/${PN}/${P}.tar.gz
+		${BACKPORTS:+mirror://gentoo/${P}-backports-${BACKPORTS}.tar.bz2}"
+	KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+fi
+
+DESCRIPTION="QEMU + Kernel-based Virtual Machine userland tools"
+HOMEPAGE="http://www.linux-kvm.org"
+
+LICENSE="GPL-2"
+SLOT="0"
+# xen is disabled until the deps are fixed
+IUSE="+aio alsa bluetooth curl esd gnutls fdt hardened kvm-trace ncurses \
+pulseaudio qemu-ifup sasl sdl static vde"
+
+COMMON_TARGETS="i386 x86_64 arm cris m68k microblaze mips mipsel ppc ppc64 sh4 sh4eb sparc sparc64"
+IUSE_SOFTMMU_TARGETS="${COMMON_TARGETS} mips64 mips64el ppcemb"
+IUSE_USER_TARGETS="${COMMON_TARGETS} alpha armeb ppc64abi32 sparc32plus"
+
+for target in ${IUSE_SOFTMMU_TARGETS}; do
+	IUSE="${IUSE} +qemu_softmmu_targets_${target}"
+done
+
+for target in ${IUSE_USER_TARGETS}; do
+	IUSE="${IUSE} +qemu_user_targets_${target}"
+done
+
+RESTRICT="test"
+
+RDEPEND="
+	!app-emulation/kqemu
+	!app-emulation/qemu
+	!app-emulation/qemu-softmmu
+	!app-emulation/qemu-user
+	!app-emulation/qemu-kvm-spice
+	sys-apps/pciutils
+	>=sys-apps/util-linux-2.16.0
+	sys-libs/zlib
+	aio? ( dev-libs/libaio )
+	alsa? ( >=media-libs/alsa-lib-1.0.13 )
+	bluetooth? ( net-wireless/bluez )
+	curl? ( net-misc/curl )
+	esd? ( media-sound/esound )
+	fdt? ( sys-apps/dtc )
+	gnutls? ( net-libs/gnutls )
+	ncurses? ( sys-libs/ncurses )
+	pulseaudio? ( media-sound/pulseaudio )
+	qemu-ifup? ( sys-apps/iproute2 net-misc/bridge-utils )
+	sasl? ( dev-libs/cyrus-sasl )
+	sdl? ( >=media-libs/libsdl-1.2.11[X] )
+	vde? ( net-misc/vde )
+"
+
+DEPEND="${RDEPEND}
+	app-text/texi2html
+	>=sys-kernel/linux-headers-2.6.29
+	gnutls? ( dev-util/pkgconfig )"
+
+kvm_kern_warn() {
+	eerror "Please enable KVM support in your kernel, found at:"
+	eerror
+	eerror "  Virtualization"
+	eerror "    Kernel-based Virtual Machine (KVM) support"
+	eerror
+}
+
+pkg_setup() {
+
+	local counter="0" check
+	use qemu_softmmu_targets_x86_64 || ewarn "You disabled default target QEMU_SOFTMMU_TARGETS=x86_64"
+	for check in ${IUSE_SOFTMMU_TARGETS} ; do
+		use "qemu_softmmu_targets_${check}" && counter="1"
+	done
+	[[ ${counter} == 0 ]] && die "You need to set at least 1 target in QEMU_SOFTMMU_TARGETS"
+
+	if kernel_is lt 2 6 25; then
+		eerror "This version of KVM requres a host kernel of 2.6.25 or higher."
+		eerror "Either upgrade your kernel"
+	else
+		if ! linux_config_exists; then
+			eerror "Unable to check your kernel for KVM support"
+			kvm_kern_warn
+		elif ! linux_chkconfig_present KVM; then
+			kvm_kern_warn
+		fi
+	fi
+
+	enewgroup kvm
+}
+
+src_prepare() {
+	# prevent docs to get automatically installed
+	sed -i '/$(DESTDIR)$(docdir)/d' Makefile || die
+	# Alter target makefiles to accept CFLAGS set via flag-o
+	sed -i 's/^\(C\|OP_C\|HELPER_C\)FLAGS=/\1FLAGS+=/' \
+		Makefile Makefile.target || die
+	# append CFLAGS while linking
+	sed -i 's/$(LDFLAGS)/$(QEMU_CFLAGS) $(CFLAGS) $(LDFLAGS)/' rules.mak || die
+
+	# remove part to make udev happy
+	sed -e 's~NAME="%k", ~~' -i kvm/scripts/65-kvm.rules || die
+
+	epatch "${FILESDIR}"/qemu-0.11.0-mips64-user-fix.patch \
+		"${FILESDIR}"/${PN}-0.12.3-fix-crash-with-sdl.patch \
+		"${FILESDIR}"/${PN}-0.12.3-include-madvise-defines.patch
+
+	[[ -n ${BACKPORTS} ]] && \
+		EPATCH_FORCE=yes EPATCH_SUFFIX="patch" EPATCH_SOURCE="${S}/patches" \
+			epatch
+}
+
+src_configure() {
+	local conf_opts audio_opts softmmu_targets user_targets
+
+	for target in ${IUSE_SOFTMMU_TARGETS} ; do
+		use "qemu_softmmu_targets_${target}" && \
+		softmmu_targets="${softmmu_targets} ${target}-softmmu"
+	done
+
+	for target in ${IUSE_USER_TARGETS} ; do
+		use "qemu_user_targets_${target}" && \
+		user_targets="${user_targets} ${target}-linux-user"
+	done
+
+	if [ ! -z "${softmmu_targets}" ]; then
+		einfo "Building the following softmmu targets: ${softmmu_targets}"
+	fi
+
+	if [ ! -z "${user_targets}" ]; then
+		einfo "Building the following user targets: ${user_targets}"
+		conf_opts="${conf_opts} --enable-linux-user"
+	else
+		conf_opts="${conf_opts} --disable-linux-user"
+	fi
+
+	# Fix QA issues. QEMU needs executable heaps and we need to mark it as such
+	conf_opts="${conf_opts} --extra-ldflags=-Wl,-z,execheap"
+
+	# Add support for static builds
+	use static && conf_opts="${conf_opts} --static"
+
+	#config options
+	conf_opts="${conf_opts} $(use_enable aio linux-aio)"
+	use bluetooth || conf_opts="${conf_opts} --disable-bluez"
+	conf_opts="${conf_opts} $(use_enable curl)"
+	use gnutls || conf_opts="${conf_opts} --disable-vnc-tls"
+	conf_opts="${conf_opts} $(use_enable fdt)"
+	use hardened && conf_opts="${conf_opts} --enable-user-pie"
+	use kvm-trace && conf_opts="${conf_opts} --with-kvm-trace"
+	use ncurses || conf_opts="${conf_opts} --disable-curses"
+	use sasl || conf_opts="${conf_opts} --disable-vnc-sasl"
+	use sdl || conf_opts="${conf_opts} --disable-sdl"
+	use vde || conf_opts="${conf_opts} --disable-vde"
+#	conf_opts="${conf_opts} $(use_enable xen)"
+	conf_opts="${conf_opts} --disable-xen"
+	conf_opts="${conf_opts} --disable-darwin-user --disable-bsd-user"
+
+	# audio options
+	audio_opts="oss"
+	use alsa && audio_opts="alsa ${audio_opts}"
+	use esd && audio_opts="esd ${audio_opts}"
+	use pulseaudio && audio_opts="pa ${audio_opts}"
+	use sdl && audio_opts="sdl ${audio_opts}"
+	./configure --prefix=/usr \
+		--disable-strip \
+		--enable-kvm \
+		--enable-nptl \
+		--enable-uuid \
+		${conf_opts} \
+		--audio-drv-list="${audio_opts}" \
+		--target-list="${softmmu_targets} ${user_targets}" \
+		--cc="$(tc-getCC)" \
+		--host-cc="$(tc-getBUILD_CC)" \
+		|| die "configure failed"
+
+		# this is for qemu upstream's threaded support which is
+		# in development and broken
+		# the kvm project has its own support for threaded IO
+		# which is always on and works
+#		--enable-io-thread \
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "make install failed"
+
+	insinto /etc/udev/rules.d/
+	doins kvm/scripts/65-kvm.rules || die
+
+	if use qemu-ifup; then
+		insinto /etc/qemu/
+		insopts -m0755
+		doins kvm/scripts/qemu-ifup || die
+	fi
+
+	dodoc Changelog MAINTAINERS TODO pci-ids.txt || die
+	newdoc pc-bios/README README.pc-bios || die
+	dohtml qemu-doc.html qemu-tech.html || die
+
+	if use qemu_softmmu_targets_x86_64 ; then
+		dobin "${FILESDIR}"/qemu-kvm
+		dosym /usr/bin/qemu-kvm /usr/bin/kvm
+	else
+		elog "You disabled QEMU_SOFTMMU_TARGETS=x86_64, this disables install"
+		elog "of /usr/bin/qemu-kvm and /usr/bin/kvm"
+	fi
+}
+
+pkg_postinst() {
+	elog "If you don't have kvm compiled into the kernel, make sure you have"
+	elog "the kernel module loaded before running kvm. The easiest way to"
+	elog "ensure that the kernel module is loaded is to load it on boot."
+	elog "For AMD CPUs the module is called 'kvm-amd'"
+	elog "For Intel CPUs the module is called 'kvm-intel'"
+	elog "Please review /etc/conf.d/modules for how to load these"
+	elog
+	elog "Make sure your user is in the 'kvm' group"
+	elog "Just run 'gpasswd -a <USER> kvm', then have <USER> re-login."
+	elog
+	elog "You will need the Universal TUN/TAP driver compiled into your"
+	elog "kernel or loaded as a module to use the virtual network device"
+	elog "if using -net tap.  You will also need support for 802.1d"
+	elog "Ethernet Bridging and a configured bridge if using the provided"
+	elog "kvm-ifup script from /etc/kvm."
+	echo
+}