Fix libdvdread linking, bug 234268

Package-Manager: portage-2.2_rc6/cvs/Linux 2.6.25-tuxonice-r6 x86_64

3 files changed, 157 insertions, 12 deletions

diff --git a/app-cdr/k3b/ChangeLog b/app-cdr/k3b/ChangeLog
index 6019a6f152a9..12c1427e518e 100644
--- a/app-cdr/k3b/ChangeLog
+++ b/app-cdr/k3b/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-cdr/k3b
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/ChangeLog,v 1.209 2008/07/24 20:57:21 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/ChangeLog,v 1.210 2008/08/08 20:36:43 beandog Exp $
+
+*k3b-1.0.5-r3 (08 Aug 2008)
+
+  08 Aug 2008; Steve Dibb <beandog@gentoo.org> +k3b-1.0.5-r3.ebuild:
+  Fix libdvdread linking, bug 234268
 
   24 Jul 2008; Doug Goldstein <cardoe@gentoo.org> metadata.xml:
   add GLEP 56 USE flag desc from use.local.desc
diff --git a/app-cdr/k3b/Manifest b/app-cdr/k3b/Manifest
index d382ab841c6c..f1c6d98496c6 100644
--- a/app-cdr/k3b/Manifest
+++ b/app-cdr/k3b/Manifest
@@ -1,6 +1,3 @@
------BEGIN PGP SIGNED MESSAGE-----
-Hash: SHA1
-
 AUX k3b-0.12.17+flac-1.1.3.patch 5567 RMD160 a20b5ae7a752b9f91c479218e75ba173af48be44 SHA1 41eae878580d21341ef6b1549a7d43df39c470d6 SHA256 4df6f523d8a05485bf1ccd3cda367460d234dc1b47564e6e8a52bfa58413149c
 AUX k3b-0.12.17-flac-beta.patch 1282 RMD160 c91a54ca3f54e34cd6805b39e5bbbdc058eaa394 SHA1 53a79cb65025ea4a2f31096a891f750b0b7711c9 SHA256 6f74700e5920ac2ec751ee16a8933cb3de5a6b3d6ea90d3a4e1d3d3815b7b8bc
 AUX k3b-1.0-alsa-fix.patch 669 RMD160 0e4ac67c18db77d655f482d2607cffef2ba9d0ab SHA1 b036e9932eb31ecc037ddfa0a58320248319f97f SHA256 31ac29a43f931786a4c71d3824a15abbb36a4439977eace2c668bcd53912536f
@@ -23,13 +20,7 @@ EBUILD k3b-1.0.4-r1.ebuild 4514 RMD160 749783ccd4372193dbf23f29c992d68a79f1de5b
 EBUILD k3b-1.0.4.ebuild 4255 RMD160 ccdc0eb639e96ac360907d6bc67841633f949cb6 SHA1 804b49671d2f687b4cb83b5a5309500879b9588f SHA256 5fb468f6cb7676cbee6e814f73eb00767a13ec6232f6bdca2fd19b4f442b9a37
 EBUILD k3b-1.0.5-r1.ebuild 4318 RMD160 235579de927264771e00721a57ae44c849553f3a SHA1 113e3811175947fade6b69537b0fa06199888822 SHA256 bebf54e81d25dcf1d2fe34ac3aaf7bc99543fb5a0c5f55e830fa6055f7479f07
 EBUILD k3b-1.0.5-r2.ebuild 4378 RMD160 5ae44145bd661c2b7d70236a9b6507e54ecb139d SHA1 b76b61b15f8694d9ff7ebda2cfbb01ceced18f64 SHA256 eb9162b5099734215762a2258f70b33bb7e82f8257da9f3d20b1e05d363fae82
+EBUILD k3b-1.0.5-r3.ebuild 4413 RMD160 7cce14aa9573bd17a21cef515d58ca1613944c91 SHA1 dda328fffdce6e5d7cf49e50bc725e29e61429f2 SHA256 c4252136f76a9d26921dd061a659ebeba40203ef89d4467bed67a6b6badd8e7b
 EBUILD k3b-1.0.5.ebuild 4511 RMD160 ef33c75a421e870d2e8d7a0bb32bee3f9e8a4ba5 SHA1 d65fb1262d97626904b3e91cee5ff9b3c8c913f6 SHA256 5b976a1d7598c33a250481ce473f8b429f4ca9faefb93abe82f31b785f630a00
-MISC ChangeLog 30823 RMD160 0d95531db3cd2096954f9d34d742ea97ed977da8 SHA1 9c1c56497e6495ac833b00f7f5ba05f4f6ca6b16 SHA256 cb736b47e15b3f26bde9edf423afb14eddea816510ab652d6e90966d7d32c7f3
+MISC ChangeLog 30960 RMD160 164b7fd212c26ac94e717737882d0eafa50b3355 SHA1 6a964c55e57eb08a36c38350602a2b0e2815b028 SHA256 08b5b91569d6c39d17ec9a2bfa5e69a1348dc9544ef91aa53c37ac237a4bb531
 MISC metadata.xml 265 RMD160 59c880c9c5efb9521978dbd903168505b105564a SHA1 c7ff34e4da0ae454589f8ae79f0c074915754879 SHA256 017dbf66cb3b0c2b77f42714c7544570e19f9605bb260245094b3678a6a34324
------BEGIN PGP SIGNATURE-----
-Version: GnuPG v2.0.9 (GNU/Linux)
-
-iEYEARECAAYFAkiI7LgACgkQoeSe8B0zEfwnJACfU/L9ZyeT72ZRr1irfu4QU/2J
-ussAnjD8JaENf/WAFPyx+0HMuz3MB6bR
-=wZl2
------END PGP SIGNATURE-----
diff --git a/app-cdr/k3b/k3b-1.0.5-r3.ebuild b/app-cdr/k3b/k3b-1.0.5-r3.ebuild
new file mode 100644
index 000000000000..2e33de3c8d3a
--- /dev/null
+++ b/app-cdr/k3b/k3b-1.0.5-r3.ebuild
@@ -0,0 +1,149 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/k3b-1.0.5-r3.ebuild,v 1.1 2008/08/08 20:36:43 beandog Exp $
+
+inherit kde eutils
+
+MY_P=${P/_/}
+S="${WORKDIR}/${MY_P}"
+
+DESCRIPTION="K3b, KDE CD Writing Software"
+HOMEPAGE="http://www.k3b.org/"
+SRC_URI="mirror://sourceforge/k3b/${MY_P}.tar.bz2"
+LICENSE="GPL-2"
+
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="alsa css dvdr dvdread encode ffmpeg flac hal mp3 musepack musicbrainz
+	sndfile vcd vorbis emovix"
+
+DEPEND="hal? ( dev-libs/dbus-qt3-old sys-apps/hal )
+	media-libs/libsamplerate
+	media-libs/taglib
+	>=media-sound/cdparanoia-3.9.8
+	sndfile? ( media-libs/libsndfile )
+	ffmpeg? ( >=media-video/ffmpeg-0.4.9_p20080326 )
+	flac? ( media-libs/flac )
+	mp3? ( media-libs/libmad )
+	musepack? ( media-libs/libmpcdec )
+	vorbis? ( media-libs/libvorbis )
+	musicbrainz? ( =media-libs/musicbrainz-2* )
+	encode? ( media-sound/lame )
+	alsa? ( media-libs/alsa-lib )
+	dvdread? ( media-libs/libdvdread )"
+
+RDEPEND="${DEPEND}
+	virtual/cdrtools
+	>=app-cdr/cdrdao-1.1.7-r3
+	media-sound/normalize
+	dvdr? ( >=app-cdr/dvd+rw-tools-7.0 )
+	css? ( media-libs/libdvdcss )
+	encode? ( media-sound/sox
+				media-video/transcode )
+	vcd? ( media-video/vcdimager )
+	emovix? ( media-video/emovix )"
+
+DEPEND="${DEPEND}
+	dev-util/pkgconfig"
+
+need-kde 3.5
+
+PATCHES=(	"${FILESDIR}/k3b-1.0.5-desktop-entry.diff"
+		"${FILESDIR}/k3b-1.0.5-ffmpeg-0.4.9_p20080326-API.patch"	)
+
+I18N="${PN}-i18n-${PV}"
+
+# Supported languages and translated documentation
+LANGS="af ar bg br bs ca cs cy da de el en_GB es et eu fa fi fr ga gl he hi hu is it ja ka lt mk ms nb nds nl nn pa pl pt pt_BR ru rw se sk sr sr@Latn sv ta tr uk uz zh_CN zh_TW"
+for X in ${LANGS}; do
+	SRC_URI="${SRC_URI} linguas_${X}? ( mirror://sourceforge/k3b/${I18N}.tar.bz2 )"
+	IUSE="${IUSE} linguas_${X}"
+done
+
+pkg_setup() {
+	if use hal && has_version '<sys-apps/dbus-0.91' && ! built_with_use sys-apps/dbus qt3; then
+		eerror "You are trying to compile ${CATEGORY}/${PF} with the \"hal\" USE flag enabled,"
+		eerror "but sys-apps/dbus is not built with Qt3 support."
+		die "Please, rebuild sys-apps/dbus with the \"qt3\" USE flag."
+	fi
+	if use encode && ! built_with_use media-video/transcode dvdread; then
+		eerror "You are trying to compile ${CATEGORY}/${PF} with the \"encode\""
+		eerror "USE flag enabled, however media-video/transcode was not built"
+		eerror "with libdvdread support. Also keep in mind that enabling"
+		eerror "the dvdread USE flag will cause k3b to use libdvdread as well."
+		die "Please, rebuild media-video/transcode with the \"dvdread\" USE flag."
+	fi
+
+	if use flac && ! built_with_use --missing true media-libs/flac cxx; then
+		eerror "To build ${PN} with flac support you need the C++ bindings for flac."
+		eerror "Please enable the cxx USE flag for media-libs/flac"
+		die "Missing FLAC C++ bindings."
+	fi
+
+	kde_pkg_setup
+}
+
+src_unpack() {
+	kde_src_unpack
+
+	if [ -d "${WORKDIR}/${I18N}" ]; then
+		cd "${WORKDIR}/${I18N}"
+		for X in ${LANGS}; do
+			use linguas_${X} || rm -rf "${X}"
+		done
+		rm -f configure
+	fi
+	rm -f "${S}/configure"
+}
+
+src_compile() {
+	local myconf="--enable-libsuffix=		\
+			--with-external-libsamplerate	\
+			--without-resmgr				\
+			--without-cdrecord-suid-root	\
+			--without-k3bsetup				\
+			$(use_with hal)					\
+			$(use_with encode lame)			\
+			$(use_with ffmpeg)				\
+			$(use_with flac)				\
+			$(use_with vorbis oggvorbis)	\
+			$(use_with sndfile)				\
+			$(use_with mp3 libmad)			\
+			$(use_with musepack)			\
+			$(use_with musicbrainz)			\
+			$(use_with dvdread libdvdread)	\
+			$(use_with alsa)"
+
+	# Build process of K3b
+	kde_src_compile
+
+	# Build process of K3b-i18n
+	if [ -d "${WORKDIR}/${I18N}" ]; then
+		KDE_S="${WORKDIR}/${I18N}" \
+		kde_src_compile
+	fi
+}
+
+src_install() {
+	kde_src_install
+	dodoc FAQ KNOWNBUGS PERMISSIONS
+
+	if [ -d "${WORKDIR}/${I18N}" ]; then
+		KDE_S="${WORKDIR}/${I18N}" \
+		kde_src_install
+	fi
+}
+
+pkg_postinst() {
+	echo
+	elog "We don't install k3bsetup anymore because Gentoo doesn't need it."
+	elog "If you get warnings on start-up, uncheck the \"Check system"
+	elog "configuration\" option in the \"Misc\" settings window."
+	echo
+
+	local group=cdrom
+	use kernel_linux || group=operator
+	elog "Make sure you have proper read/write permissions on the cdrom device(s)."
+	elog "Usually, it is sufficient to be in the ${group} group."
+	echo
+}