blob: 7eb922b7a07bbe870f5f192422e2e2203d712a31 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit flag-o-matic
PATCH_TAR="${PN}-3.7.1-patches-01.tar.xz"
DESCRIPTION="A general-purpose (yacc-compatible) parser generator"
HOMEPAGE="https://www.gnu.org/software/bison/"
SRC_URI="mirror://gnu/${PN}/${P}.tar.xz
mirror://gentoo/${PATCH_TAR}
https://dev.gentoo.org/~whissi/dist/bison/${PATCH_TAR}
https://dev.gentoo.org/~polynomial-c/dist/bison/${PATCH_TAR}"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ppc ~ppc64 ~riscv s390 ~sparc x86 ~ppc-aix ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="examples nls static test"
RESTRICT="!test? ( test )"
RDEPEND=">=sys-devel/m4-1.4.16"
DEPEND="${RDEPEND}"
BDEPEND="
sys-devel/flex
>=sys-devel/gettext-0.21
examples? ( dev-lang/perl )
test? ( dev-lang/perl )
"
DOCS=( AUTHORS ChangeLog NEWS README THANKS TODO ) # ChangeLog-2012 ChangeLog-1998 PACKAGING README-alpha README-release
PATCHES=(
"${WORKDIR}"/patches/${PN}-3.5-optional-perl.patch #538300
"${WORKDIR}"/patches/${PN}-3.7.1-avoid_autoreconf.patch
)
src_prepare() {
# Record date to avoid 'config.status --recheck' & regen of 'tests/package.m4'
touch -r configure.ac old.configure.ac || die
touch -r configure old.configure || die
default
# Restore date after patching
touch -r old.configure.ac configure.ac || die
touch -r old.configure configure || die
# The makefiles make the man page depend on the configure script
# which we patched above. Touch it to prevent regeneration.
touch doc/bison.1 || die #548778 #538300#9
# Avoid regenerating the info page when the timezone is diff. #574492
sed -i '2iexport TZ=UTC' build-aux/mdate-sh || die
}
src_configure() {
use static && append-ldflags -static
local myeconfargs=(
$(use_enable examples)
$(use_enable nls)
)
econf "${myeconfargs[@]}"
}
src_install() {
default
# This one is installed by dev-util/yacc
mv "${ED}"/usr/bin/yacc{,.bison} || die
mv "${ED}"/usr/share/man/man1/yacc{,.bison}.1 || die
# We do not need liby.a
rm -r "${ED}"/usr/lib* || die
}
pkg_postinst() {
local f="${EROOT}/usr/bin/yacc"
if [[ ! -e ${f} ]] ; then
ln -s yacc.bison "${f}"
fi
}
pkg_postrm() {
# clean up the dead symlink when we get unmerged #377469
local f="${EROOT}/usr/bin/yacc"
if [[ -L ${f} && ! -e ${f} ]] ; then
rm -f "${f}"
fi
}
|
GitWeb