blob: 1975543f7f9daeec8c6c9699e515389ad9dbcae6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools
DESCRIPTION="Check C programs for vulnerabilities and programming mistakes"
HOMEPAGE="http://lclint.cs.virginia.edu/"
SRC_URI="http://www.splint.org/downloads/${P}.src.tgz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~ia64 ~mips ppc ppc64 sparc x86 ~ppc-macos ~x64-macos"
DEPEND="sys-devel/flex"
PATCHES=(
"${FILESDIR}"/${PN}-3.1.2-musl.patch
)
src_prepare() {
default
# verbose compiler calls
sed -i -e '/Compiling/d' src/Makefile.am || die
# automake complains about trailing \
sed -i -e '1600d' test/Makefile.am || die
# do not install these header files twice
sed -i -e '/\$(UnixHeaders)/s|stdio.h stdlib.h||g' lib/Makefile.am || die
eautoreconf
}
src_configure() {
# We do not need bison/yacc at all here
# We definitely need libfl
BISON=no LEXLIB=-lfl econf
}
src_compile() {
local subdir
# skip test/ subdir
for subdir in src lib imports doc; do
emake -j1 -C ${subdir}
done
}
src_test() {
emake -C test
}
|
GitWeb
