blob: c7213b0a9dc2b1ea8f4f4b477dad3bcbed837e73 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
MY_P=${PN}-10.2+${PV/_p/+}
inherit autotools multilib-minimal flag-o-matic
DESCRIPTION="an advanced CDDA reader with error correction"
HOMEPAGE="https://www.gnu.org/software/libcdio/"
SRC_URI="mirror://gnu/${PN%-*}/${MY_P}.tar.gz"
# COPYING-GPL from cdparanoia says "2 or later"
# COPYING-LGPL from cdparanoia says "2.1 or later" but 2 files are without the
# clause "or later" so we use LGPL-2.1 without +
LICENSE="GPL-3+ GPL-2+ LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha amd64 arm ~arm64 hppa ~ia64 ~mips ppc ppc64 ~sh sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
IUSE="+cxx static-libs test"
RDEPEND="app-eselect/eselect-cdparanoia
>=dev-libs/libcdio-0.94:0=[${MULTILIB_USEDEP}]
>=virtual/libiconv-0-r1[${MULTILIB_USEDEP}]
"
DEPEND="${RDEPEND}
sys-devel/gettext
virtual/pkgconfig
test? ( dev-lang/perl )"
RESTRICT="!test? ( test )"
S="${WORKDIR}/${MY_P}"
DOCS=( AUTHORS ChangeLog NEWS README.md THANKS )
PATCHES=(
"${FILESDIR}"/${PN}-0.90-oos-tests.patch
)
src_prepare() {
default
sed -i -e 's:AM_CONFIG_HEADER:AC_CONFIG_HEADERS:' configure.ac || die #466410
eautoreconf
[[ ${CC} == *clang* ]] && append-flags -std=gnu89
}
multilib_src_configure() {
local myeconfargs=(
--disable-maintainer-mode
--disable-example-progs
$(use_enable cxx)
--disable-cpp-progs
--with-cd-paranoia-name=libcdio-paranoia
# upstream accidentally default-disabled it
# reenable it to preserve ABI compat with previous versions
# https://bugs.gentoo.org/616054
# https://savannah.gnu.org/bugs/index.php?50978
--enable-ld-version-script
$(use_enable static-libs static)
)
# Darwin linker doesn't get this
[[ ${CHOST} == *-darwin* ]] && myeconfargs+=( --disable-ld-version-script )
ECONF_SOURCE="${S}" \
econf "${myeconfargs[@]}"
}
multilib_src_install_all() {
einstalldocs
find "${D}" -type f -name '*.la' -delete || die
}
pkg_postinst() {
eselect cdparanoia update ifunset
}
pkg_postrm() {
eselect cdparanoia update ifunset
}
|
GitWeb