blob: 195bd1ac5af6e39165104363642bce7ae603ecd2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools toolchain-funcs xdg
DESCRIPTION="Convert HTML pages into a PDF document"
HOMEPAGE="https://www.msweet.org/htmldoc/"
SRC_URI="https://github.com/michaelrsweet/${PN}/releases/download/v${PV}/${P}-source.tar.gz"
SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~alpha amd64 ~arm ~hppa ~ia64 ~ppc ppc64 sparc x86"
IUSE="fltk ssl"
BDEPEND="virtual/pkgconfig"
DEPEND="
>=media-libs/libpng-1.4:0=
sys-libs/zlib
virtual/jpeg:0
ssl? ( net-libs/gnutls )
fltk? ( x11-libs/fltk:1 )
"
RDEPEND="${DEPEND}"
src_prepare() {
default
eautoreconf
# Make sure not to use the libs htmldoc ships with
rm -r jpeg png zlib || die "failed to unbundle jpeg, png, and zlib"
# Fix the documentation path in a few places. Some Makefiles aren't
# autotoolized =(
for file in configure doc/Makefile doc/htmldoc.man; do
sed -i "${file}" \
-e "s:/doc/htmldoc:/doc/${PF}/html:g" \
|| die "failed to fix documentation path in ${file}"
done
}
src_configure() {
local myeconfargs=(
$(use_with fltk gui)
$(use_enable ssl)
$(use_enable ssl gnutls)
--disable-localjpeg
--disable-localpng
--disable-localzlib
)
CC="$(tc-getCC)" CXX="$(tc-getCXX)" DSTROOT="${ED}" econf "${myeconfargs[@]}"
}
src_install() {
emake STRIPPROG="true" DSTROOT="${ED}" install
}
|
GitWeb
