1 files changed, 0 insertions, 99 deletions
diff --git a/app-admin/keepassxc/keepassxc-2.4.2.ebuild b/app-admin/keepassxc/keepassxc-2.4.2.ebuild
deleted file mode 100644
index fa1b4e6b2168..000000000000
--- a/app-admin/keepassxc/keepassxc-2.4.2.ebuild
+++ /dev/null
@@ -1,99 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit cmake-utils xdg
-
-DESCRIPTION="KeePassXC - KeePass Cross-platform Community Edition"
-HOMEPAGE="https://keepassxc.org"
-
-if [[ "${PV}" != 9999 ]] ; then
-	if [[ "${PV}" == *_beta* ]] ; then
-		SRC_URI="https://github.com/keepassxreboot/keepassxc/archive/${PV/_/-}.tar.gz -> ${P}.tar.gz"
-		S="${WORKDIR}/${P/_/-}"
-	else
-		#SRC_URI="https://github.com/keepassxreboot/keepassxc/archive/${PV}.tar.gz -> ${P}.tar.gz"
-		SRC_URI="https://github.com/keepassxreboot/keepassxc/releases/download/${PV}/${P}-src.tar.xz"
-		KEYWORDS="~amd64 ~x86"
-	fi
-else
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/keepassxreboot/${PN}"
-fi
-
-LICENSE="LGPL-2.1 GPL-2 GPL-3"
-SLOT="0"
-IUSE="autotype browser debug keeshare +network test yubikey"
-
-RDEPEND="
-	app-crypt/argon2:=
-	dev-libs/libgcrypt:=
-	>=dev-libs/libsodium-1.0.12:=
-	dev-qt/qtconcurrent:5
-	dev-qt/qtcore:5
-	dev-qt/qtdbus:5
-	dev-qt/qtgui:5
-	dev-qt/qtnetwork:5
-	dev-qt/qtsvg:5
-	dev-qt/qtwidgets:5
-	media-gfx/qrencode:=
-	sys-libs/zlib:=
-	autotype? (
-		dev-qt/qtx11extras:5
-		x11-libs/libX11
-		x11-libs/libXi
-		x11-libs/libXtst
-	)
-	browser? ( >=dev-libs/libsodium-1.0.12 )
-	keeshare? ( dev-libs/quazip )
-	yubikey? ( sys-auth/ykpers )
-"
-
-DEPEND="
-	${RDEPEND}
-	dev-qt/linguist-tools:5
-	dev-qt/qttest:5
-"
-
-# Not a runtime dependency but still needed (see bug #667092)
-PDEPEND="
-	x11-misc/xsel
-"
-
-src_prepare() {
-	 use test || \
-		sed -e "/^find_package(Qt5Test/d" -i CMakeLists.txt || die
-
-	 cmake-utils_src_prepare
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DWITH_GUI_TESTS=OFF
-		-DWITH_TESTS="$(usex test)"
-		-DWITH_XC_AUTOTYPE="$(usex autotype)"
-		-DWITH_XC_BROWSER="$(usex browser)"
-		-DWITH_XC_KEESHARE_SECURE="$(usex keeshare)"
-		-DWITH_XC_NETWORKING="$(usex network)"
-		-DWITH_XC_SSHAGENT=ON
-		-DWITH_XC_UPDATECHECK=OFF
-		-DWITH_XC_YUBIKEY="$(usex yubikey)"
-	)
-	if [[ "${PV}" == *_beta* ]] ; then
-		mycmakeargs+=( -DOVERRIDE_VERSION="${PV/_/-}" )
-	fi
-	cmake-utils_src_configure
-}
-
-pkg_preinst() {
-	xdg_pkg_preinst
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-}
-
-pkg_postrm() {
-	xdg_pkg_postrm
-}