sys-kernel/gentoo-kernel-bin: add 5.10.80-r1 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 873fdd288d96..fcdb0ccbd02b 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -67,6 +67,7 @@ DIST gentoo-kernel-5.10.79-1.amd64.xpak 65535104 BLAKE2B 110338738477cce7cceedc9
 DIST gentoo-kernel-5.10.79-1.arm64.xpak 60978468 BLAKE2B 759f9f78e81b2bafe617b555a5164a8964e4a3abecff38e1de74b6e8103f30bf0110d698ba8979d628aebaa07cca9cc9b19993b02a02b489f2e5c138f02c408b SHA512 6a5763d65a5bca550abe52c7c846a41a1d2a3f3c914d08a7c7157b267efd614bc40377a19640891764bb4ce2f472327de00d1211bf856906dda1da4deb8700fd
 DIST gentoo-kernel-5.10.79-1.x86.xpak 57295318 BLAKE2B a3ce89be878ba48ebbe236532a0662897915ba9e84da4dd006e805def3039527ef39efe4d1d9c70d4e85f3c670dbe2a40dbae488b71c2e9b4ed3975ac802ffbc SHA512 b1abb1b5bdda8660ba461b7b21f9745705209c9aee994ff855ef609b982c23e01a6c055c7c3e14efa16b63f957b996a0b446fa9cdc098ebe34fa17465d66dd58
 DIST gentoo-kernel-5.10.80-1.amd64.xpak 65555264 BLAKE2B d1dc0d0c31ea77a806c0081ea7cf5c13b19079acd542eb9ce62457b8956755e70e75392b9315c93dec8ed5be990a76d3b832b01f7769977f3d8f48014dda9bfc SHA512 1f6538c49a78bb61c5dbd24a30c10156747b666fe90528b7dde58f25ac96032a7148cb65d4202e6f86e868870ca9fccfd469beeb00211ffff858de48f0014f03
+DIST gentoo-kernel-5.10.80-1.arm64.xpak 60925011 BLAKE2B 88684720fb6d4f9ca5927540de6dbe96b27aa0894756d8438947e5f5da909e1eace19a69e9f352a34cb4baa2a98a024125b005a611ee6cf9c8233df99323f17c SHA512 d74953b24dbe685e1933611cb1192fb96d45bef2429bf145f174448bfe0224521e2883e85616e610ba49fc9807572924f4e1c1e9b2d08437f9bac12ab474822a
 DIST gentoo-kernel-5.10.80-1.x86.xpak 57272943 BLAKE2B d2b6b55a4eb046efbb097508d5f8e96d340fcbc499452620a7150200978f7f80832a281db6dc147f1552419c19f3e1910b0f6cbeaf7baa45b1e3e34a0ac37bc7 SHA512 ec1e841644e9fbfee2fbf319048cb3c911a67191a8e0f81b57dc59f5b165f925b07588a2fe9669edd811f40231b59df242c064bbbdac63222aab94df7538c042
 DIST gentoo-kernel-5.13.19-1.amd64.xpak 67338326 BLAKE2B d9e718a94bf9a341f5b57063cbde2f3f1f0ea6d03f1805051c084b792388789494a49786d643f1570871ca2b6366a206497aed83f9ed00837c542ac970a71fc6 SHA512 aea74f6f39861752f7a5dae16d955d541f65d3e7b8a0e5fba593011d9ca8583f3dd0964e76aa21daa6583d5d26e3616885aeca8a04dbba222e0aae2a85062b40
 DIST gentoo-kernel-5.13.19-1.arm64.xpak 62747957 BLAKE2B 1981ddb4e35d2210e1c678856ac58e088cd100ecbd70d2b5c88ffe8eb25b56f3f0c90e45d12adb74c7a0fb881dfd36b1d46d6fdfb837dbdff1881ded066b906d SHA512 d8c1e524a3e58def5352b3faae07c42074a2d67015cc62b9601e20bb9b7f29d44d2843e7771e0399e9150be1de2be2b28776f96f7fe75ba7ec4e8f2c31e1f715
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.80-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.80-r1.ebuild
new file mode 100644
index 000000000000..a76ca745a641
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.80-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 7 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}