sys-kernel/gentoo-kernel-bin: bump to 5.4.119 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 115 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 2da2a26fcaa1..94af0a2f4a89 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -49,6 +49,7 @@ DIST gentoo-kernel-5.4.118-1.amd64.xpak 61392444 BLAKE2B d99b66e6396fa0bf48c691a
 DIST gentoo-kernel-5.4.118-1.arm64.xpak 56379069 BLAKE2B a0c824628d237c015c5b446e1e5841d0f819abe985606d76b7a022c65468e8f373889a86f59015a3327b7fd2a378b730ef2ef4ff68c6a14853c10df38e4c665f SHA512 d8f8060719573b427a065c6c84fe7b5dfffcec4d8bb47c416628e1ed4988c68d4658f30693091b8e68fe8f629b5c87c2d52bdeb44b56deec126dbf9276dcf9da
 DIST gentoo-kernel-5.4.118-1.x86.xpak 53177998 BLAKE2B 4a7e8160ce0c9ca321be346ec1d909d2dd546dfffeb8c2ca88e52060a8791545ec4afb04571294eff834fdb3da3538b686c690195e40c70f508afbd50dd54dc7 SHA512 2f3220f6e4c1b1c5a94cd4a50d4ef5ad993ce2ab4f0988de45bf2a734583401fae7ad4da21d314ffa181f772f85675698a22d9a63c7f09c560e0829e006c2ddc
 DIST gentoo-kernel-5.4.119-1.amd64.xpak 61350639 BLAKE2B adc69bc18fb447cf5855abcb36b9806a68aa3c1e5076c32ca91e86a310347265f04c9192827dfba02e480d71c3554f6a645ac50cbce2e176b0f64f0ebee8892a SHA512 726cb65a7ceeda730ac0154552aace5695f89ee97be401d9db197c9e9a278fcf678ad5c28186cec7b01867dfaa0ccb75c216e8e1987659e040c2fd9302fbb54d
+DIST gentoo-kernel-5.4.119-1.arm64.xpak 56392771 BLAKE2B 96d87aa624459ff93c0492d9497bd59155cd6623a5c30cc2b4f0ad5790d5d9f8ac7768e70f6fe2d92c2aadca938ba02fd0b3945f7fc51e515c068413be3ff5c3 SHA512 df380b96f853402f80d918131bbc524db4a8a27e5a08a07ec2940c35d56f5904d2f9b673e9c3da7b29ac13d7d7d29a86db757c5d28f5894a6345623777ea2abb
 DIST gentoo-kernel-5.4.119-1.x86.xpak 53192878 BLAKE2B 9681a1d5d955b51b57de103dcbb4a101395b1e0c7c545c472dd5e93e3901d9abad9a692383fabce37c9fa043946c3fab9de3f880a5946cf6864259f4735e364d SHA512 44935242acc37a00ff3f5784ae79d5356032a1271c2e48bec5c321724e6630e165c979d5ccb4d8b6ec4a2b5cf0ca6326aa1afccd5dd3d7dedc0b0207d11a154d
 DIST linux-5.10.tar.xz 116606704 BLAKE2B b923d7b66309224f42f35f8a5fa219421b0a9362d2adacdadd8d96251f61f7230878ea297a269a7f3b3c56830f0b177e068691e1d7f88501a05653b0a13274d1 SHA512 95bc137d0cf9148da6a9d1f1a878698dc27b40f68e22c597544010a6c591ce1b256f083489d3ff45ff77753289b535135590194d88ef9f007d0ddab3d74de70e
 DIST linux-5.11.tar.xz 117619104 BLAKE2B 81300c27bd5476387a83123aaeb4163c73eb61e9245806c23660cb5e6a4fa88ffc9def027031335fa0270fc4080506cd415990014364e3a98b9d2e8c58a29524 SHA512 a567ec133018bb5ec00c60281479b466c26e02137a93a9c690e83997947df02b6fd94e76e8df748f6d70ceb58a19bacc3b1467de10b7a1fad2763db32b3f1330
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.119-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.119-r1.ebuild
new file mode 100644
index 000000000000..b63276300c50
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.119-r1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}