sys-kernel/gentoo-kernel-bin: Bump to 5.10.202-r1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 129 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 8812945d5145..7576ff8c3b04 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -4,6 +4,8 @@ DIST genpatches-5.10-210.base.tar.xz 6166764 BLAKE2B d2afcbc4c25f01401b9971ee354
 DIST genpatches-5.10-210.extras.tar.xz 3876 BLAKE2B 51ff2998ba7713fd4c7f4cd025b5abd014ef7c8e944841a1b6a6517141aa4b74efb2b017179197b03c82972e1b24bfc3deb9ee4687e551af8b55162e3f73c520 SHA512 24cf5ed8915d9db4ed79e05d07bf95ae499daafb79b15113a917743dd5421467265b47effb356d813165f5d7675213e5d2d4ff9be37b11573e77172ef72c05c5
 DIST genpatches-5.10-212.base.tar.xz 6247964 BLAKE2B 946041f888556cfdce0b20394321eef7a28434b0a99abee389c51f72b6903276376d19e88f0ee8615269b73376667a223cfdc0c2c16f5a43d9fecd4f26d48edd SHA512 b3a67d0adada6c8922a9797a094192def65404ba75db193fd7b92a4389437a0163e259acd271e8a12bcb68867447318411bf85e4280e8bd84d5c105635f8b97d
 DIST genpatches-5.10-212.extras.tar.xz 3876 BLAKE2B 0899603bd8419915c49ff71ed423ec39ea5030b648ad9e3a2c25f02265b902e6797171bd58c2ad0be37a62caf0de65bc565dbeba37b0c2336c68edbf7374c932 SHA512 39ac14f636ec9a38968f525fb3aa6aba7c43082fb85cb6995210da93ac932a34e74645c5fefff9c7dbe7c2c27195bb4992caac858252e0ec2b0e2ac2684c3075
+DIST genpatches-5.10-213.base.tar.xz 6247856 BLAKE2B 8decc2789f586d6c91cee876713e76dfb15d2df1191deab54d8c656859561e29b7516693d46b9922c69cc20572c0c79cac02088b9e85d5c2fa0cf72ad78f1210 SHA512 9c2e5f12baeed7d57c6730f458ce32ff01ff3120d4f11e524e14062b449ea43a0e467950171cbe912de0c64e6b16ce1193d7e8e56e190d6abc1a8adc9a7b9f1d
+DIST genpatches-5.10-213.extras.tar.xz 3876 BLAKE2B b852d4e7759f8f3f6adb9789df694f083f3a8b26cc0f44dcfc30b45f0b0b1099a1af6495df7a5ca8da8b3c4d1e83dd9f493cefe8787d80e45843a64dbf72d045 SHA512 3d6ddd8c9bc36cea25dd778924b2f2577f6b62d773ff1e3b847a604b9558e7614bdd805860b3efa0a2fd22fee3363a8f64cf8e9be24da65a8e132a447d09d9eb
 DIST genpatches-5.15-143.base.tar.xz 5634608 BLAKE2B a00b2898db47b874fdfe2e2bf0c40edcb4f358765f14aba79c686b8d6f99c6a77792d45dfcce141837ad6d956c6ce417453e53b6ede9db2f4e88b501aeabda21 SHA512 1342f8090f18bd15c44ca11409fc09ee5c406801fc077277682595fd58e8f37a57e022f433a0e8fb132cf6bee64f48dccacdbdbabab776d45634477e195eed67
 DIST genpatches-5.15-143.extras.tar.xz 3936 BLAKE2B c942135c9120024effcc516070b81aef19de95969e19c95b7c222ccf9ba515db329735596f3c5dfe81f12ef29165b898de75988f0c632cd228b6d3579e3c5648 SHA512 eb9d0661d81c1acbf5884f3ccc864e0b110a517556bd62020f41f3fad77c32e57da5a7c1f6411a4dc7d9b85ad8fe9af4658613b0a3e9484fb609a7f9ac1a3f39
 DIST genpatches-5.15-144.base.tar.xz 5663416 BLAKE2B a4347f6e6f5916a3811ddb7ce19a506f6f4bb691e57ed5229adb55d90aa2fce14656d1a77d63539ef5fba8c0a5ed8c3cd0933c9f286694a83c65898b77015e66 SHA512 8f4a7429a9673cc2aeffe870ac1f742b6d111b0fb72bff74b3407d13eaaa6200ae7b931449b7c5923c215428b2c55352f728d60a09f1ac7907625f37a454a3cf
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.202-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.202-r1.ebuild
new file mode 100644
index 000000000000..ea061d08855e
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.202-r1.ebuild
@@ -0,0 +1,127 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit kernel-install toolchain-funcs unpacker
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 11 ))
+BINPKG=${P/-bin}-1
+
+DESCRIPTION="Pre-built Linux kernel with Gentoo patches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	amd64? (
+		https://dev.gentoo.org/~mgorny/binpkg/amd64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.gpkg.tar
+			-> ${BINPKG}.amd64.gpkg.tar
+	)
+	arm64? (
+		https://dev.gentoo.org/~mgorny/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.gpkg.tar
+			-> ${BINPKG}.arm64.gpkg.tar
+	)
+	ppc64? (
+		https://dev.gentoo.org/~mgorny/binpkg/ppc64le/kernel/sys-kernel/gentoo-kernel/${BINPKG}.gpkg.tar
+			-> ${BINPKG}.ppc64le.gpkg.tar
+	)
+	x86? (
+		https://dev.gentoo.org/~mgorny/binpkg/x86/kernel/sys-kernel/gentoo-kernel/${BINPKG}.gpkg.tar
+			-> ${BINPKG}.x86.gpkg.tar
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}
+"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}
+"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	app-alternatives/yacc
+"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH="$(tc-arch-kernel)"
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "${BINPKG}/image/usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/${BINPKG}/image/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"${BINPKG}/image/lib/modules/${KPV}"
+}
+
+src_install() {
+	mv "${BINPKG}"/image/{lib,usr} "${ED}"/ || die
+
+	# FIXME: requires proper mount-boot
+	if [[ -d ${BINPKG}/image/boot/dtbs ]]; then
+		mv "${BINPKG}"/image/boot "${ED}"/ || die
+	fi
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}