sys-auth/yubico-piv-tool: bump to 2.2.0

Signed-off-by: Marek Szuba <marecki@gentoo.org>

2 files changed, 53 insertions, 0 deletions

diff --git a/sys-auth/yubico-piv-tool/Manifest b/sys-auth/yubico-piv-tool/Manifest
index 5f22756f38b7..fc99860636e1 100644
--- a/sys-auth/yubico-piv-tool/Manifest
+++ b/sys-auth/yubico-piv-tool/Manifest
@@ -1 +1,2 @@
 DIST yubico-piv-tool-2.1.1.tar.gz 1302573 BLAKE2B da4419b7074930f7d264f21a12973511d350e687d0487b93d25a528f4a79d5df44dbbdde34ef7cd0d14507ba1a00f776fcd7eaf503f2253d8ee8da3e9a68010f SHA512 14d880088f7624f600c6badb6504c4c71ef29ff82e9c29bd837013e62273c6b198ca581705cc7fb9f3c0c13334767ea7b340fb033ce99fb60fb0478281affc9f
+DIST yubico-piv-tool-2.2.0.tar.gz 1309359 BLAKE2B a5be7a48549f864b9322b5bf53726007b593ce7d08cd06f2251aef98cb065d90586e0189e6f3da94d6d274d6998459afa4a55a0d4c1145395f55830f53d334e4 SHA512 b2f8cd73800e0e0778ce36148b962026479f5d3ada3e313acb5a780993c28c41b03e9aa9335ac5b79fed7a418a2d3d3697231adf2da0dd06cd8d22ea5a01aca5
diff --git a/sys-auth/yubico-piv-tool/yubico-piv-tool-2.2.0.ebuild b/sys-auth/yubico-piv-tool/yubico-piv-tool-2.2.0.ebuild
new file mode 100644
index 000000000000..986733af196b
--- /dev/null
+++ b/sys-auth/yubico-piv-tool/yubico-piv-tool-2.2.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="Command-line tool and p11-kit module for the YubiKey PIV application"
+HOMEPAGE="https://developers.yubico.com/yubico-piv-tool/ https://github.com/Yubico/yubico-piv-tool"
+SRC_URI="https://github.com/Yubico/${PN}/archive/${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0/2"
+KEYWORDS="~amd64"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="sys-apps/pcsc-lite
+	dev-libs/openssl:0=[-bindist]"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/check )"
+BDEPEND="dev-util/gengetopt
+	sys-apps/help2man
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.1.1-no-Werror.patch
+	"${FILESDIR}"/${PN}-2.1.1-tests-optional.patch
+	"${FILESDIR}"/${PN}-2.1.1-ykcs11-threads.patch
+)
+
+S="${WORKDIR}/${PN}-${P}"
+
+src_configure() {
+	# As of 2.2.0, man pages end up in /usr/usr/... without the MANDIR override
+	local mycmakeargs=(
+		-DBUILD_STATIC_LIB=OFF
+		-DBUILD_TESTING=$(usex test)
+		-DCMAKE_INSTALL_MANDIR="share/man"
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	echo "module: ${EPREFIX}/usr/$(get_libdir)/libykcs11.so" > ${PN}.module \
+		|| die "Failed to generate p11-kit module configuration"
+	insinto /usr/share/p11-kit/modules
+	doins ${PN}.module
+}