sys-apps/pv: add 9999

Needed to test upstream changes for tests.

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 72 insertions, 5 deletions

diff --git a/sys-apps/pv/pv-1.8.0.ebuild b/sys-apps/pv/pv-1.8.0.ebuild
index c5442aa977e9..ca01ea55e00a 100644
--- a/sys-apps/pv/pv-1.8.0.ebuild
+++ b/sys-apps/pv/pv-1.8.0.ebuild
@@ -8,14 +8,21 @@ inherit linux-info toolchain-funcs verify-sig
 
 DESCRIPTION="Pipe Viewer: a tool for monitoring the progress of data through a pipe"
 HOMEPAGE="https://www.ivarch.com/programs/pv.shtml https://codeberg.org/a-j-wood/pv"
-SRC_URI="
-	https://www.ivarch.com/programs/sources/${P}.tar.gz
-	verify-sig? ( https://www.ivarch.com/programs/sources/${P}.tar.gz.txt -> ${P}.tar.gz.asc )
-"
+
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://codeberg.org/a-j-wood/pv"
+	inherit autotools git-r3
+else
+	SRC_URI="
+		https://www.ivarch.com/programs/sources/${P}.tar.gz
+		verify-sig? ( https://www.ivarch.com/programs/sources/${P}.tar.gz.txt -> ${P}.tar.gz.asc )
+	"
+
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+fi
 
 LICENSE="GPL-3+"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
 IUSE="debug nls"
 
 BDEPEND="verify-sig? ( sec-keys/openpgp-keys-pv )"
@@ -28,6 +35,12 @@ pkg_setup() {
 	fi
 }
 
+src_prepare() {
+	default
+
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
+
 src_configure() {
 	tc-export AR
 
diff --git a/sys-apps/pv/pv-9999.ebuild b/sys-apps/pv/pv-9999.ebuild
new file mode 100644
index 000000000000..7d003e10536d
--- /dev/null
+++ b/sys-apps/pv/pv-9999.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/pv.asc
+inherit linux-info toolchain-funcs verify-sig
+
+DESCRIPTION="Pipe Viewer: a tool for monitoring the progress of data through a pipe"
+HOMEPAGE="https://www.ivarch.com/programs/pv.shtml https://codeberg.org/a-j-wood/pv"
+
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://codeberg.org/a-j-wood/pv"
+	inherit autotools git-r3
+else
+	SRC_URI="
+		https://www.ivarch.com/programs/sources/${P}.tar.gz
+		verify-sig? ( https://www.ivarch.com/programs/sources/${P}.tar.gz.txt -> ${P}.tar.gz.asc )
+	"
+
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="debug nls"
+
+BDEPEND="verify-sig? ( sec-keys/openpgp-keys-pv )"
+
+pkg_setup() {
+	if use kernel_linux; then
+		CONFIG_CHECK="~SYSVIPC"
+		ERROR_SYSVIPC="You will need to enable CONFIG_SYSVIPC in your kernel to use the --remote option."
+		linux-info_pkg_setup
+	fi
+}
+
+src_prepare() {
+	default
+
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+	tc-export AR
+
+	econf \
+		$(use_enable debug debugging) \
+		$(use_enable nls)
+}
+
+src_test() {
+	emake -Onone check
+}