sys-apps/pv: add 1.8.9

Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 71 insertions, 1 deletions

diff --git a/sys-apps/pv/Manifest b/sys-apps/pv/Manifest
index 8a8378104f3c..2d299974d165 100644
--- a/sys-apps/pv/Manifest
+++ b/sys-apps/pv/Manifest
@@ -1,2 +1,4 @@
 DIST pv-1.8.5.tar.gz 327072 BLAKE2B ef7fcf64430a72e04ca3a922115e7012c999109bb7e1a52f480c27eeb6c49952f4be52e6041a063c710d934c68555cfb65796103920fd240e4ebde2fa6a323c7 SHA512 6d7a0f785ace5e25c5677af4cf38a003386774e60563865de7f1dae60f1785685541da93e1f88236b8b2e14431584bc2cb2adb3a575fb90dc774bc6bacf22e21
 DIST pv-1.8.5.tar.gz.asc 691 BLAKE2B ac5bd2b05e145d4ea5aedbb148b39a317d68329787f06f39f808be75951da0e0f460254b4a5049a8eafabad07edfbe936be00154f5dfa660628c8a3dfa3b7ffd SHA512 8414b2485347579a54233a2f241c080ab6461799c149567ab1063ce812b08ab2293f55bf8a24bcadabf94d12ce3dce36fe57277d822d115db9e53c957fe99c20
+DIST pv-1.8.9.tar.gz 330129 BLAKE2B a8e8b567a0e9eed9fa9b938b5ef52623adda8907b26d6dc3664fb0e3c8bee193e615ad0f357f688a53fa0014d978bf98a157a072d0159e9aaded447d3e4b16e0 SHA512 d6e483d2cb5ef3def1df9c72774ab70a5210e7a45f165d3d1527f11366e7bbab57320f1987d460783eda94605a17c5ef2a027fa4a7e9d58b529f4b1b05ec07a8
+DIST pv-1.8.9.tar.gz.asc 691 BLAKE2B 24640b3ba4d3306175f6e63d5efe86bc4a29da3b822417098f66892c0c59ddab713b202ebcc6e8fbe97de104b0583221ee12b4ef72adb2402912e3f799403e92 SHA512 ad4791b094caacc05485ee817c3162c65110c46bd7feaf06617fcf7d42c0d407e5696cf35ff881aa19340a13d02e04183c5e4db51cc68bb443fa524d9573ce57
diff --git a/sys-apps/pv/pv-1.8.9.ebuild b/sys-apps/pv/pv-1.8.9.ebuild
new file mode 100644
index 000000000000..5e5b703403bd
--- /dev/null
+++ b/sys-apps/pv/pv-1.8.9.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/pv.asc
+inherit linux-info toolchain-funcs verify-sig
+
+DESCRIPTION="Pipe Viewer: a tool for monitoring the progress of data through a pipe"
+HOMEPAGE="https://www.ivarch.com/programs/pv.shtml https://codeberg.org/a-j-wood/pv"
+
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://codeberg.org/a-j-wood/pv"
+	inherit autotools git-r3
+else
+	SRC_URI="
+		https://www.ivarch.com/programs/sources/${P}.tar.gz
+		verify-sig? ( https://www.ivarch.com/programs/sources/${P}.tar.gz.txt -> ${P}.tar.gz.asc )
+	"
+
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="debug nls"
+
+BDEPEND="verify-sig? ( sec-keys/openpgp-keys-pv )"
+
+pkg_setup() {
+	if use kernel_linux; then
+		CONFIG_CHECK="~SYSVIPC"
+		ERROR_SYSVIPC="You will need to enable CONFIG_SYSVIPC in your kernel to use the --remote option."
+		linux-info_pkg_setup
+	fi
+}
+
+src_prepare() {
+	default
+
+	# Valgrind isn't reliable within sandbox.
+	cat <<-EOF > tests/run-valgrind.sh || die
+	#!/bin/sh
+	exit 77
+	EOF
+	chmod +x tests/run-valgrind.sh || Die
+
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+	tc-export AR
+
+	econf \
+		$(use_enable debug debugging) \
+		$(use_enable nls)
+}
+
+src_test() {
+	emake -Onone check
+}
diff --git a/sys-apps/pv/pv-9999.ebuild b/sys-apps/pv/pv-9999.ebuild
index 7d003e10536d..5e5b703403bd 100644
--- a/sys-apps/pv/pv-9999.ebuild
+++ b/sys-apps/pv/pv-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -38,6 +38,13 @@ pkg_setup() {
 src_prepare() {
 	default
 
+	# Valgrind isn't reliable within sandbox.
+	cat <<-EOF > tests/run-valgrind.sh || die
+	#!/bin/sh
+	exit 77
+	EOF
+	chmod +x tests/run-valgrind.sh || Die
+
 	[[ ${PV} == 9999 ]] && eautoreconf
 }