sci-mathematics/fricas: remove old versions

Signed-off-by: Andrey Grozin <grozin@gentoo.org>

3 files changed, 0 insertions, 179 deletions

diff --git a/sci-mathematics/fricas/Manifest b/sci-mathematics/fricas/Manifest
index 6c0959685da2..7f5ab6e655a2 100644
--- a/sci-mathematics/fricas/Manifest
+++ b/sci-mathematics/fricas/Manifest
@@ -1,2 +1 @@
-DIST fricas-1.3.10-full.tar.bz2 10971513 BLAKE2B 0ea96cf1076dcd23f53ebdcd3ebf5c6e605915ce332093b83d62a5ed482d32f14833857e270865a4031d7bfc033d961c69007e936260e7d85e632b091d969e0d SHA512 de23c34a1e47b0a4ab2f85e1154e6fa5b0905427718e8c0ad4fe298bf6ebbb1abcc02426e528b7b34d15aebfc2ca1b06f73e39a24ec741d2d5c70f9b48b02665
 DIST fricas-1.3.11-full.tar.bz2 10937641 BLAKE2B 52bb467468de83dfbb8a61717356d74c605efe1174168c35af50d15232c8441457415ca2c88fd19356caec9f9ee29af556104f421dc0479f3ae635144432be7a SHA512 6166661866829764fdf02e84c08f3afd8f631a40c8c5340648640b4fa388641c703021f5006e135ac32e671786b1a75bc290039e929ef322c60a0ba0cb0212ac
diff --git a/sci-mathematics/fricas/fricas-1.3.10.ebuild b/sci-mathematics/fricas/fricas-1.3.10.ebuild
deleted file mode 100644
index e6de50964068..000000000000
--- a/sci-mathematics/fricas/fricas-1.3.10.ebuild
+++ /dev/null
@@ -1,78 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-inherit elisp-common
-
-DESCRIPTION="FriCAS is a fork of Axiom computer algebra system"
-HOMEPAGE="https://fricas.sourceforge.net/
-	https://github.com/fricas/fricas
-	https://fricas.github.io/"
-SRC_URI="https://downloads.sourceforge.net/${PN}/${PV}/${P}-full.tar.bz2"
-
-LICENSE="BSD-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-IUSE="+sbcl cmucl gcl ecl clisp clozurecl X emacs gmp"
-REQUIRED_USE="^^ ( sbcl cmucl gcl ecl clisp clozurecl )
-	gmp? ( ^^ ( sbcl clozurecl ) )"
-RDEPEND="sbcl? ( dev-lisp/sbcl:= )
-	cmucl? ( dev-lisp/cmucl:= )
-	gcl? ( dev-lisp/gcl:= )
-	ecl? ( dev-lisp/ecl:= )
-	clisp? ( dev-lisp/clisp:= )
-	clozurecl? ( dev-lisp/clozurecl:= )
-	X? ( x11-libs/libXpm x11-libs/libICE )
-	emacs? ( >=app-editors/emacs-23.1:* )
-	gmp? ( dev-libs/gmp:= )"
-DEPEND="${RDEPEND}"
-
-# necessary for clisp and gcl
-RESTRICT="strip"
-
-src_configure() {
-	local LISP GMP
-	use sbcl && LISP="sbcl --dynamic-space-size 4096"
-	use cmucl && LISP=lisp
-	use gcl && LISP=gcl
-	use ecl && LISP=ecl
-	use clisp && LISP=clisp
-	use clozurecl && LISP=ccl
-
-	if use sbcl || use clozurecl
-	then GMP=$(use_with gmp)
-	else GMP=''
-	fi
-
-	# aldor is not yet in portage
-	econf --disable-aldor --with-lisp="${LISP}" $(use_with X x) ${GMP}
-}
-
-src_test() {
-	emake -j1 all-input
-}
-
-src_install() {
-	emake -j1 DESTDIR="${D}" install
-	dodoc README.rst FAQ
-
-	if use emacs; then
-		sed -e "s|(setq load-path (cons (quote \"/usr/$(get_libdir)/fricas/emacs\") load-path)) ||" \
-			-i "${D}"/usr/bin/efricas \
-			|| die "sed efricas failed"
-		elisp-install ${PN} "${D}"/usr/$(get_libdir)/${PN}/emacs/*.el
-		elisp-make-site-file 64${PN}-gentoo.el
-	else
-		rm "${D}"/usr/bin/efricas || die "rm efricas failed"
-	fi
-	rm -r "${D}"/usr/$(get_libdir)/${PN}/emacs || die "rm -r emacs failed"
-}
-
-pkg_postinst() {
-	use emacs && elisp-site-regen
-}
-
-pkg_postrm() {
-	use emacs && elisp-site-regen
-}
diff --git a/sci-mathematics/fricas/fricas-1.3.11-r2.ebuild b/sci-mathematics/fricas/fricas-1.3.11-r2.ebuild
deleted file mode 100644
index f661206cab77..000000000000
--- a/sci-mathematics/fricas/fricas-1.3.11-r2.ebuild
+++ /dev/null
@@ -1,100 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-VIRTUALX_REQUIRED="doc"
-inherit virtualx elisp-common
-
-DESCRIPTION="FriCAS is a fork of Axiom computer algebra system"
-HOMEPAGE="https://fricas.sourceforge.net/
-	https://github.com/fricas/fricas
-	https://fricas.github.io/"
-SRC_URI="https://downloads.sourceforge.net/${PN}/${PV}/${P}-full.tar.bz2"
-
-LICENSE="BSD-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-IUSE="+sbcl cmucl gcl ecl clisp clozurecl X emacs gmp doc"
-REQUIRED_USE="^^ ( sbcl cmucl gcl ecl clisp clozurecl )
-	gmp? ( ^^ ( sbcl clozurecl ) )"
-RDEPEND="sbcl? ( dev-lisp/sbcl:= )
-	cmucl? ( dev-lisp/cmucl:= )
-	gcl? ( dev-lisp/gcl:= )
-	ecl? ( dev-lisp/ecl:= )
-	clisp? ( dev-lisp/clisp:= )
-	clozurecl? ( dev-lisp/clozurecl:= )
-	X? ( x11-libs/libXpm x11-libs/libICE )
-	emacs? ( >=app-editors/emacs-23.1:* )
-	gmp? ( dev-libs/gmp:= )"
-DEPEND="${RDEPEND}
-	doc? ( dev-texlive/texlive-basic
-		dev-texlive/texlive-latex
-		dev-texlive/texlive-latexrecommended
-		dev-texlive/texlive-latexextra
-		dev-texlive/texlive-mathscience
-		dev-tex/pgf )"
-
-# necessary for clisp and gcl
-RESTRICT="strip"
-
-PATCHES=( "${FILESDIR}"/${P}-doc.patch )
-
-src_configure() {
-	local LISP GMP
-	use sbcl && LISP="sbcl --dynamic-space-size 4096"
-	use cmucl && LISP=lisp
-	use gcl && LISP=gcl
-	use ecl && LISP=ecl
-	use clisp && LISP=clisp
-	use clozurecl && LISP=ccl
-
-	if use sbcl || use clozurecl
-	then GMP=$(use_with gmp)
-	else GMP=''
-	fi
-
-	# aldor is not yet in portage
-	econf --disable-aldor --with-lisp="${LISP}" $(use_with X x) ${GMP}
-}
-
-src_compile() {
-	default
-	if use doc; then
-		pushd src/doc > /dev/null || die "pushd src/doc failed"
-		virtx emake book
-		popd > /dev/null
-	fi
-}
-
-src_test() {
-	emake -j1 all-input
-}
-
-src_install() {
-	emake -j1 DESTDIR="${D}" install
-	dodoc README.rst FAQ
-
-	if use emacs; then
-		sed -e "s|(setq load-path (cons (quote \"/usr/$(get_libdir)/fricas/emacs\") load-path)) ||" \
-			-i "${D}"/usr/bin/efricas \
-			|| die "sed efricas failed"
-		elisp-install ${PN} "${D}"/usr/$(get_libdir)/${PN}/emacs/*.el
-		elisp-make-site-file 64${PN}-gentoo.el
-	else
-		rm "${D}"/usr/bin/efricas || die "rm efricas failed"
-	fi
-	rm -r "${D}"/usr/$(get_libdir)/${PN}/emacs || die "rm -r emacs failed"
-
-	if use doc; then
-		dodoc src/doc/book.pdf
-	fi
-}
-
-pkg_postinst() {
-	use emacs && elisp-site-regen
-}
-
-pkg_postrm() {
-	use emacs && elisp-site-regen
-}