sci-libs/indilib: add 2.0.8

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 86 insertions, 0 deletions

diff --git a/sci-libs/indilib/Manifest b/sci-libs/indilib/Manifest
index 7650417975ef..faf6a9284aaf 100644
--- a/sci-libs/indilib/Manifest
+++ b/sci-libs/indilib/Manifest
@@ -1 +1,2 @@
 DIST indilib-2.0.7.tar.gz 2843758 BLAKE2B dee94a40d4b3c5c4d994d945a3608a41765af14c4937d475bdf80dca5d5847b814e0d9a1060f39b15b109916dee45f1876ce8edd29588e209276e3b1bf6f3dd7 SHA512 292c0a5b8f07b24c42ea9424be19012c97317206b837d8601ec4d771fa35c314bf00712509f8199ee3da193ea12f0c3e90036a49deece304dc256cdeba60810d
+DIST indilib-2.0.8.tar.gz 2851129 BLAKE2B 061ed06bbb122e5579d881ff76d84e6629045eb9972da68fb0c66554f453e7a0660c0017858b8626af70a114bf099c3f7397c6789f41ed99335bde0de767fb95 SHA512 a9b4c5efe9841c024a7ccc271b2de6626ee442d3543f621822522950cc7549def9de111e66e6d183e0a63bead6d1e211fa6025463f9ca4bad30b7a457c5f66b9
diff --git a/sci-libs/indilib/indilib-2.0.8.ebuild b/sci-libs/indilib/indilib-2.0.8.ebuild
new file mode 100644
index 000000000000..79e844a4015a
--- /dev/null
+++ b/sci-libs/indilib/indilib-2.0.8.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic udev
+
+DESCRIPTION="INDI Astronomical Control Protocol library"
+HOMEPAGE="https://www.indilib.org/"
+SRC_URI="https://github.com/${PN}/${PN/lib/}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${P/lib/}"
+
+LICENSE="BSD GPL-2+ LGPL-2+ LGPL-2.1+"
+SLOT="0/1"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="ogg rtlsdr test websocket"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-cpp/cpp-httplib:=
+	dev-cpp/nlohmann_json
+	dev-libs/libev
+	media-libs/libjpeg-turbo:=
+	net-misc/curl
+	sci-libs/cfitsio:=
+	sci-libs/fftw:3.0=
+	sci-libs/gsl:=
+	sci-libs/libnova:=
+	sys-libs/zlib
+	virtual/libusb:1
+	ogg? (
+		media-libs/libogg
+		media-libs/libtheora
+	)
+	rtlsdr? ( net-wireless/rtl-sdr )
+	websocket? ( dev-libs/boost:= )
+"
+DEPEND="${RDEPEND}
+	kernel_linux? ( sys-kernel/linux-headers )
+	test? ( >=dev-cpp/gtest-1.8.0 )
+	websocket? ( dev-cpp/websocketpp )
+"
+
+src_configure() {
+	# -Werror=odr
+	# https://bugs.gentoo.org/878525
+	# https://github.com/indilib/indi/issues/2023
+	filter-lto
+
+	local mycmakeargs=(
+		-DINDI_SYSTEM_HTTPLIB=ON
+		-DINDI_SYSTEM_JSONLIB=ON
+		-DINDI_BUILD_QT5_CLIENT=OFF
+		-DINDI_BUILD_SHARED=ON
+		-DINDI_BUILD_STATIC=OFF
+		-DINDI_BUILD_XISF=OFF # not packaged
+		-DUDEVRULES_INSTALL_DIR="${EPREFIX}$(get_udevdir)"/rules.d
+		$(cmake_use_find_package ogg OggTheora)
+		$(cmake_use_find_package rtlsdr RTLSDR)
+		-DINDI_BUILD_UNITTESTS=$(usex test)
+		-DINDI_BUILD_INTEGTESTS=$(usex test)
+		-DINDI_BUILD_WEBSOCKET=$(usex websocket)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	# Unit tests
+	BUILD_DIR="${BUILD_DIR}"/test cmake_src_test
+
+	# Integration tests
+	# They fail in parallel because they try to bind to the same port more
+	# than once.
+	BUILD_DIR="${BUILD_DIR}"/integs cmake_src_test -j1
+}
+
+pkg_postinst() {
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}