net-vpn/networkmanager-vpnc: disable legacy libnm-glib compat

Disable libnm-glib, libnm-glib-vpn and libnm-util usage, as they are
all gone with newer NetworkManager.
This also disables libnm-gtk usage, which requires libnm-glib in turn
as well, and is also gone with newer nm-applet.
Depend on new libnma package instead of nm-applet, as this is what
is needed here.

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

1 files changed, 51 insertions, 0 deletions

diff --git a/net-vpn/networkmanager-vpnc/networkmanager-vpnc-1.2.6-r2.ebuild b/net-vpn/networkmanager-vpnc/networkmanager-vpnc-1.2.6-r2.ebuild
new file mode 100644
index 000000000000..1bcda328837e
--- /dev/null
+++ b/net-vpn/networkmanager-vpnc/networkmanager-vpnc-1.2.6-r2.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME_ORG_MODULE="NetworkManager-${PN##*-}"
+
+inherit gnome2
+
+DESCRIPTION="NetworkManager VPNC plugin"
+HOMEPAGE="https://wiki.gnome.org/Projects/NetworkManager"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="gtk test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=net-misc/networkmanager-1.2.0:=
+	>=dev-libs/dbus-glib-0.74
+	>=dev-libs/glib-2.32:2
+	>=net-vpn/vpnc-0.5.3_p550
+	gtk? (
+		>=x11-libs/gtk+-3.4:3
+		>=net-libs/libnma-1.2.0
+		>=app-crypt/libsecret-0.18
+	)
+"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	dev-util/intltool
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# Test will fail if the machine doesn't have a particular locale installed
+	# https://bugzilla.gnome.org/show_bug.cgi?id=742708
+	sed '/test_non_utf8_import (plugin/ d' \
+		-i properties/tests/test-import-export.c || die "sed failed"
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-more-warnings \
+		--disable-static \
+		--with-dist-version=Gentoo \
+		$(use_with gtk gnome) \
+		--without-libnm-glib
+}